[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
FYI: Fixing some cases of underquoting
From: |
Pavel Roskin |
Subject: |
FYI: Fixing some cases of underquoting |
Date: |
Sat, 11 Nov 2000 02:03:11 -0500 (EST) |
Hello!
None of the fixes contained in this patch affect the output of autoconf or
autoheader, but most of them are bad examples of using macros as arguments
to other macros without proper quoting.
ChangeLog:
* acfunctions.m4 (AC_CHECK_FUNCS): Add missing m4 quotes.
(AC_FUNC_GETPGRP): Likewise.
* acspecific.m4 (AC_AIX): Likewise.
* m4/init.m4 (AM_INIT_AUTOMAKE): Likewise.
* m4/missing.m4 (AM_MISSING_PROG): Likewise.
* m4/sanity.m4 (AM_SANITY_CHECK): Likewise.
Regards,
Pavel Roskin
_______________________________
Index: acfunctions.m4
--- acfunctions.m4 Sat Nov 11 01:05:49 2000
+++ acfunctions.m4 Sat Nov 11 01:39:45 2000
@@ -84,7 +84,7 @@
for ac_func in $1
do
AC_CHECK_FUNC($ac_func,
- [AC_DEFINE_UNQUOTED(AC_TR_CPP(HAVE_$ac_func)) $2],
+ [AC_DEFINE_UNQUOTED([AC_TR_CPP([HAVE_$ac_func])]) $2],
[$3])dnl
done
])
@@ -629,7 +629,7 @@
exit (s>>8);
}
}], ac_cv_func_getpgrp_void=yes, ac_cv_func_getpgrp_void=no,
- AC_MSG_ERROR([cannot check getpgrp if cross compiling]))
+ [AC_MSG_ERROR([cannot check getpgrp if cross compiling])])
])
if test $ac_cv_func_getpgrp_void = yes; then
AC_DEFINE(GETPGRP_VOID, 1,
Index: acspecific.m4
--- acspecific.m4 Sat Nov 11 01:05:49 2000
+++ acspecific.m4 Sat Nov 11 01:26:42 2000
@@ -1637,7 +1637,7 @@
],
[AC_MSG_RESULT([yes])
AC_DEFINE(_ALL_SOURCE)],
-AC_MSG_RESULT([no]))
+[AC_MSG_RESULT([no])])
])# AC_AIX
Index: m4/init.m4
--- m4/init.m4 Sat Jan 29 05:30:15 2000
+++ m4/init.m4 Sat Nov 11 01:16:40 2000
@@ -18,8 +18,8 @@
AC_MSG_ERROR([source directory already configured; run "make distclean"
there first])
fi
ifelse([$3],,
-AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
-AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
+[AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
+AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])
AC_REQUIRE([AM_SANITY_CHECK])
AC_REQUIRE([AC_ARG_PROGRAM])
dnl FIXME This is truly gross.
Index: m4/missing.m4
--- m4/missing.m4 Sat Oct 14 22:01:18 2000
+++ m4/missing.m4 Sat Nov 11 01:55:17 2000
@@ -4,15 +4,15 @@
dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
dnl The program must properly implement --version.
AC_DEFUN(AM_MISSING_PROG,
-[AC_MSG_CHECKING(for working $2)
+[AC_MSG_CHECKING([for working $2])
# Run test in a subshell; some versions of sh will print an error if
# an executable is not found, even if stderr is redirected.
# Redirect stdin to placate older versions of autoconf. Sigh.
if ($2 --version) < /dev/null > /dev/null 2>&1; then
$1=$2
- AC_MSG_RESULT(found)
+ AC_MSG_RESULT([found])
else
$1="$SHELL $3/missing $2"
- AC_MSG_RESULT(missing)
+ AC_MSG_RESULT([missing])
fi
AC_SUBST($1)])
Index: m4/sanity.m4
--- m4/sanity.m4 Sat Jan 29 05:30:15 2000
+++ m4/sanity.m4 Sat Nov 11 01:55:36 2000
@@ -39,4 +39,4 @@
Check your system clock])
fi
rm -f conftest*
-AC_MSG_RESULT(yes)])
+AC_MSG_RESULT([yes])])
_______________________________
- FYI: Fixing some cases of underquoting,
Pavel Roskin <=