FYI: AS_ERROR

[Akim Demaille]

Pavel, this morning the test suite started failing for me, and I
suppose it's due to some recent changes on my system (typically I
might have changed compiler and preprocessor, I didn't check).  Could
you give it a look?

src/ace/tests % ./debug-26.sh                                    nostromo 11:52
=========================================
Testing suite for autoconf, version 2.49c
=========================================
testing AC_PROG_CPP without warnings
     26. ./compile.at:47...
./compile.at:65: autoconf --autoconf-dir .. -l $at_srcdir
./compile.at:65: autoheader --autoconf-dir .. -l $at_srcdir
./compile.at:65: top_srcdir=$top_srcdir ./configure
--- empty       Tue Dec 12 11:52:49 2000
+++ stderr      Tue Dec 12 11:52:53 2000
@@ -0,0 +1 @@
+configure: error: C preprocessor "./mycpp" fails sanity check
checking how to run the C preprocessor... ./mycpp
Exit code was 1, expected 0
     26. ./compile.at:47: FAILED near `compile.at:65'

=========================================
Testing suite for autoconf, version 2.49c
=========================================
src/ace/tests % cat config.lo                                    nostromo 11:52
cat: config.lo: Aucun fichier ou répertoire de ce type
src/ace/tests % cat config.log                                   nostromo Err 1
This file contains any messages produced by compilers while
running configure, to aid debugging if configure makes a mistake.

It was created by configure 2.49c, executed with
 > ./configure 

## ---------- ##
## Platform.  ##
## ---------- ##

hostname = nostromo
uname -m = i686
uname -r = 2.2.17
uname -s = Linux
uname -v = #1 Sat Sep 9 12:42:22 EST 2000

/usr/bin/uname -p = 
/bin/uname -X     = 

/bin/arch              = i686
/usr/bin/arch -k       = 
/usr/convex/getsysinfo = 
hostinfo               = 
/bin/machine           = 
/usr/bin/oslevel       = 
/bin/universe          = 

PATH = 
/home/lrde/prof/akim/src/ace/tests:/home/lrde/prof/akim/src/ace:/home/lrde/prof/akim/bin:/home/lrde/prof/akim/bin:/usr/bin:/bin:/usr/bin/X11:/usr/games:/usr/X11R6/bin:/usr/local/kde/bin

## ------------ ##
## Core tests.  ##
## ------------ ##

configure:908: checking how to run the C preprocessor
configure:997: ./mycpp  conftest.c >/dev/null 2>conftest.err
configure:1042: result: ./mycpp
configure:1045: error: C preprocessor "./mycpp" fails sanity check
configure: exit 1






Here is the patch I'm installing.

Index: ChangeLog
from  Akim Demaille  <address@hidden>

        AS_ERROR was not properly saving data in the log file.

        * sh.m4 (AS_WARN, AS_ERROR): Use AS_MESSAGE.
        (_AS_ECHO): Fix quotation.
        (AS_MESSAGE): Use `as_me'.
        * acgeneral.m4: More banners in the log.
        (_AC_INIT_DEFAULTS): Compute as_me before using it.

Index: acgeneral.m4
===================================================================
RCS file: /cvs/autoconf/acgeneral.m4,v
retrieving revision 1.645
diff -u -u -r1.645 acgeneral.m4
--- acgeneral.m4 2000/12/06 14:05:46 1.645
+++ acgeneral.m4 2000/12/12 10:47:27
@@ -739,6 +739,14 @@
 
 AS_SHELL_SANITIZE
 
+# Name of the host.
+# hostname on some systems (SVR3.2, Linux) returns a bogus exit status,
+# so uname gets run too.
+ac_hostname=`(hostname || uname -n) 2>/dev/null | sed 1q`
+
+# Name of the executable.
+as_me=`echo "$[0]" | sed 's,.*/,,'`
+
 cat >config.log << EOF
 This file contains any messages produced by compilers while
 running configure, to aid debugging if configure makes a mistake.
@@ -746,9 +754,13 @@
 It was created by $as_me m4_ifset([AC_PACKAGE_STRING],
                             [(AC_PACKAGE_STRING) ])AC_ACVERSION, executed with
  > $[0] address@hidden
+
 
-on `(hostname || uname -n) 2>/dev/null | sed 1q`:
+## ---------- ##
+## Platform.  ##
+## ---------- ##
 
+hostname = $ac_hostname
 uname -m = `(uname -m) 2>/dev/null || echo unknown`
 uname -r = `(uname -r) 2>/dev/null || echo unknown`
 uname -s = `(uname -s) 2>/dev/null || echo unknown`
@@ -766,6 +778,11 @@
 /bin/universe          = `(/bin/universe) 2>/dev/null`
 
 PATH = $PATH
+
+## ------------ ##
+## Core tests.  ##
+## ------------ ##
+
 EOF
 
 _AC_INIT_DEFAULTS_FDS
@@ -783,14 +800,6 @@
 # only ac_max_sed_lines should be used.
 : ${ac_max_here_lines=38}
 
-# Name of the host.
-# hostname on some systems (SVR3.2, Linux) returns a bogus exit status,
-# so uname gets run too.
-ac_hostname=`(hostname || uname -n) 2>/dev/null | sed 1q`
-
-# Name of the executable.
-as_me=`echo "$[0]" | sed 's,.*/,,'`
-
 # Avoid depending upon Character Ranges.
 ac_cr_az='abcdefghijklmnopqrstuvwxyz'
 ac_cr_AZ='ABCDEFGHIJKLMNOPQRSTUVWXYZ'
@@ -3721,7 +3730,6 @@
 #
 # If there are arguments given to AC_OUTPUT, dispatch them to the
 # proper modern macros.
-
 AU_DEFUN([AC_OUTPUT],
 [m4_ifvaln([$1],
            [AC_CONFIG_FILES([$1])])dnl
@@ -3763,13 +3771,23 @@
 AC_OUTPUT_COMMANDS_PRE()dnl
 
 # Save into config.log some information that might help in debugging.
-echo >&AS_MESSAGE_LOG_FD
-echo "Cache variables:" >&AS_MESSAGE_LOG_FD
-_AC_CACHE_DUMP | sed 's/^/| /' >&AS_MESSAGE_LOG_FD
-echo >&AS_MESSAGE_LOG_FD
-echo "confdefs.h:" >&AS_MESSAGE_LOG_FD
-sed '/^$/d;s/^/| /' confdefs.h >&AS_MESSAGE_LOG_FD
+cat <<_ACEOF >&AS_MESSAGE_LOG_FD
+
+## ----------------- ##
+## Cache variables.  ##
+## ----------------- ##
 
+_ACEOF
+_AC_CACHE_DUMP >&AS_MESSAGE_LOG_FD
+cat <<_ACEOF >&AS_MESSAGE_LOG_FD
+
+## ------------ ##
+## confdefs.h.  ##
+## ------------ ##
+
+_ACEOF
+sed '/^$/d' confdefs.h >&AS_MESSAGE_LOG_FD
+
 : ${CONFIG_STATUS=./config.status}
 ac_clean_files_save=$ac_clean_files
 ac_clean_files="$ac_clean_files $CONFIG_STATUS"
@@ -3807,7 +3825,9 @@
 _AC_INIT_DEFAULTS_FDS
 cat >&AS_MESSAGE_LOG_FD << EOF
 
-----------------------------------------------------------------------
+## ----------------------- ##
+## Running config.status.  ##
+## ----------------------- ##
 
 This file was extended by $as_me m4_ifset([AC_PACKAGE_STRING],
                             [(AC_PACKAGE_STRING) ])AC_ACVERSION, executed with
Index: m4sh.m4
===================================================================
RCS file: /cvs/autoconf/m4sh.m4,v
retrieving revision 1.18
diff -u -u -r1.18 m4sh.m4
--- m4sh.m4 2000/12/06 08:58:42 1.18
+++ m4sh.m4 2000/12/12 10:47:28
@@ -180,7 +180,7 @@
 
 
 # _AS_ECHO_UNQUOTED(STRING, [FD = AS_MESSAGE_FD])
-# ---------------------------------------------------
+# -----------------------------------------------
 # Perform shell expansions on STRING and echo the string to FD.
 m4_define([_AS_ECHO_UNQUOTED],
 [echo "$1" >&m4_default([$2], [AS_MESSAGE_FD])])
@@ -205,37 +205,30 @@
 # ----------------------------------
 # Protect STRING from backquote expansion, echo the result to FD.
 m4_define([_AS_ECHO],
-[_AS_ECHO_UNQUOTED([_AS_QUOTE([$1])], $2)])
+[_AS_ECHO_UNQUOTED([_AS_QUOTE([$1])], [$2])])
 
 
 # AS_MESSAGE(STRING, [FD = AS_MESSAGE_FD])
-# --------------------------------------------
+# ----------------------------------------
 m4_define([AS_MESSAGE],
 [m4_ifset([AS_MESSAGE_LOG_FD],
           [{ _AS_ECHO([$as_me:__oline__: $1], [AS_MESSAGE_LOG_FD])
-_AS_ECHO($@);}],
-          [_AS_ECHO($@)])[]dnl
+_AS_ECHO([$as_me: $1], [$2]);}],
+          [_AS_ECHO([$as_me: $1], [$2])])[]dnl
 ])
 
 
 # AS_WARN(PROBLEM)
 # ----------------
 m4_define([AS_WARN],
-[m4_ifset([AS_MESSAGE_LOG_FD],
-          [{ _AS_ECHO([$as_me:__oline__: WARNING: $1], [AS_MESSAGE_LOG_FD])
-_AS_ECHO([$as_me: warning: $1], 2); }],
-          [_AS_ECHO([$as_me: warning: $1], 2)])[]dnl
-])# AS_WARN
+[AS_MESSAGE([WARNING: $1], [2])])# AS_WARN
 
 
 # AS_ERROR(ERROR, [EXIT-STATUS = 1])
 # ----------------------------------
 m4_define([AS_ERROR],
-[{m4_ifset([AC_LOG_FD],
-           [_AS_ECHO([$as_me:__oline__: error: $1], [AS_MESSAGE_LOG_FD])
-])[]dnl
-  _AS_ECHO([$as_me: error: $1], 2)
-  AS_EXIT([$2]); }[]dnl
+[{ AS_MESSAGE([error: $1], [2])
+   AS_EXIT([$2]); }
 ])# AS_ERROR