Re: Bug#143590: autoconf 2.53 causes ncpfs to not build from source

[Raja R Harinath]

Hi,

Ben Pfaff <address@hidden> writes:

> Hi.  I'm the maintainer of the Debian GNU/Linux package for
> Autoconf.  The following bug report was recently filed.  I don't
> think it's a bug that I introduced, and it isn't obvious to me
> that it's a bug in the submitter's configure.in, so I thought I'd
> forward it upstream.
>
> Thanks,
>
> Ben.
> From: Petr Vandrovec <address@hidden>
> Subject: Bug#143590: autoconf 2.53 causes ncpfs to not build from source
[snip]
> dnl stripped down configure.ac from ncpfs
> dnl Process this file with autoconf to produce a configure script.
> AC_PREREQ(2.50)
> AC_INIT([[ncpfs]],[[2.2.0.19.1]],address@hidden)
> AC_REVISION([[2.2.0.19.1]])
>
> AC_PROG_CC
> AC_CHECK_HEADER(net/if.h,
>   [ncp_net_if_h="#include <net/if.h>"],
>   AC_CHECK_HEADER(linux/if.h,
>     [ncp_net_if_h="#include <linux/if.h>"],
>     [ncp_net_if_h="/* No interfaces support... */"
>      AC_DEFINE(NO_NET_IF_SUPPORT, 1, [neither net/if.h nor linux/if.h was 
> found, so ipx_* will not build...])
>      AC_MSG_WARN(Neither <net/if.h> nor <linux/if.h> does exist, only partial 
> make configured)]
>   )
> )

You have to quote the nested AC_CHECK_HEADER too.

  AC_CHECK_HEADER(net/if.h,
    [ncp_net_if_h="#include <net/if.h>"],
    [AC_CHECK_HEADER(linux/if.h,
      [ncp_net_if_h="#include <linux/if.h>"],
      [ncp_net_if_h="/* No interfaces support... */"
       AC_DEFINE(NO_NET_IF_SUPPORT, 1, [neither net/if.h nor linux/if.h was 
found, so ipx_* will not build...])
       AC_MSG_WARN(Neither <net/if.h> nor <linux/if.h> does exist, only partial 
make configured)]
    )]
  )

- Hari
-- 
Raja R Harinath ------------------------------ address@hidden
"When all else fails, read the instructions."      -- Cahn's Axiom
"Our policy is, when in doubt, do the right thing."   -- Roy L Ash