Re: [Fwd: libtool AC_ARG_WITH and autoconf 2.59]

[Howard Chu]

Stepan Kasal wrote:
> Hello,
>
> On Wed, Aug 24, 2005 at 08:17:40PM -0700, Howard Chu wrote:
> > reading the autoconf 2.59 document to see if there's a macro to control
> > this behavior,
>
> no there is no documented way to change this.  I think I could relatively
> easily design a hack which would merge the two groups again, but there
> would be no guarantee that the hack won't break with future version.

Was there any particular benefit to splitting them apart in the first 
place? It seems pretty simple to combine them back; replace 
HELP_ENABLE/HELP_WITH with a single HELP_OPTIONS and the problem is 
gone. See the attached diff.
> > but in the meantime one fix would be to change libtool's
> > AC_ARG_WITH invocations into AC_ARG_ENABLE instead.
>
> Well, such a change would affect the users, if they are accustomed to
> the current option.

Right, this really isn't an acceptable workaround.

--
  -- Howard Chu
  Chief Architect, Symas Corp.  http://www.symas.com
  Director, Highland Sun        http://highlandsun.com/hyc
  OpenLDAP Core Team            http://www.openldap.org/project/

--- general.m4.O        2004-10-01 18:09:15.000000000 -0700
+++ general.m4  2005-08-25 03:22:47.000000000 -0700
@@ -84,10 +84,8 @@
 #   Handling `configure --help'.
 # - HELP_CANON
 #   Help msg for AC_CANONICAL_*
-# - HELP_ENABLE
-#   Help msg from AC_ARG_ENABLE.
-# - HELP_WITH
-#   Help msg from AC_ARG_WITH.
+# - HELP_OPTIONS
+#   Help msg from AC_ARG_ENABLE or AC_ARG_WITH.
 # - HELP_VAR
 #   Help msg from AC_ARG_VAR.
 # - HELP_VAR_END
@@ -135,8 +133,7 @@
 
 m4_define([_m4_divert(HELP_BEGIN)],     100)
 m4_define([_m4_divert(HELP_CANON)],     101)
-m4_define([_m4_divert(HELP_ENABLE)],    102)
-m4_define([_m4_divert(HELP_WITH)],      103)
+m4_define([_m4_divert(HELP_OPTIONS)],   102)
 m4_define([_m4_divert(HELP_VAR)],       104)
 m4_define([_m4_divert(HELP_VAR_END)],   105)
 m4_define([_m4_divert(HELP_END)],       106)
@@ -964,12 +961,10 @@
 dnl   Support for cross compilation (--build, --host and --target).
 dnl   Display only in long --help.
 dnl
-dnl - HELP_ENABLE
+dnl - HELP_OPTIONS
 dnl   which starts with the trailer of the HELP_BEGIN, HELP_CANON section,
 dnl   then implements the header of the non generic options.
 dnl
-dnl - HELP_WITH
-dnl
 dnl - HELP_VAR
 dnl
 dnl - HELP_VAR_END
@@ -977,17 +972,19 @@
 dnl - HELP_END
 dnl   initialized below, in which we dump the trailer (handling of the
 dnl   recursion for instance).
-m4_divert_push([HELP_ENABLE])dnl
+m4_divert_push([HELP_OPTIONS])dnl
 _ACEOF
 fi
 
 if test -n "$ac_init_help"; then
-m4_ifset([AC_PACKAGE_STRING],
-[  case $ac_init_help in
-     short | recursive ) echo "Configuration of AC_PACKAGE_STRING:";;
-   esac])
   cat <<\_ACEOF
-m4_divert_pop([HELP_ENABLE])dnl
+
+Optional Features and Packages:
+  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
+  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]
+  --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
+  --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)
+m4_divert_pop([HELP_OPTIONS])dnl
 m4_divert_push([HELP_END])dnl
 m4_ifset([AC_PACKAGE_BUGREPORT], [
 Report bugs to <AC_PACKAGE_BUGREPORT>.])
@@ -1288,11 +1285,7 @@
 # AC_ARG_ENABLE(FEATURE, HELP-STRING, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 # ------------------------------------------------------------------------
 AC_DEFUN([AC_ARG_ENABLE],
-[m4_divert_once([HELP_ENABLE], [[
-Optional Features:
-  --disable-FEATURE       do not include FEATURE (same as --enable-FEATURE=no)
-  --enable-FEATURE[=ARG]  include FEATURE [ARG=yes]]])dnl
-m4_divert_once([HELP_ENABLE], [$2])dnl
+[m4_divert_once([HELP_OPTIONS], [$2])dnl
 # Check whether --enable-$1 or --disable-$1 was given.
 if test "[${enable_]m4_bpatsubst([$1], -, _)+set}" = set; then
   enableval="[$enable_]m4_bpatsubst([$1], -, _)"
@@ -1316,11 +1309,7 @@
 # AC_ARG_WITH(PACKAGE, HELP-STRING, ACTION-IF-TRUE, [ACTION-IF-FALSE])
 # --------------------------------------------------------------------
 AC_DEFUN([AC_ARG_WITH],
-[m4_divert_once([HELP_WITH], [[
-Optional Packages:
-  --with-PACKAGE[=ARG]    use PACKAGE [ARG=yes]
-  --without-PACKAGE       do not use PACKAGE (same as --with-PACKAGE=no)]])
-m4_divert_once([HELP_WITH], [$2])dnl
+[m4_divert_once([HELP_OPTIONS], [$2])dnl
 # Check whether --with-$1 or --without-$1 was given.
 if test "[${with_]m4_bpatsubst([$1], -, _)+set}" = set; then
   withval="[$with_]m4_bpatsubst([$1], -, _)"