Re: [Autoconf] Re: Dependency tracking not working on macOS

[suzuki toshiya]

The error caused by "packageheaders" command defined in your configure.ac
(included in https://www.alberta-fem.de/Downloads/alberta-3.0.0.tar.gz ) ?

#
# Should come last to make sure we can already use the Makefiles.
#
AC_CONFIG_COMMANDS([packageheaders],
#AC_CONFIG_COMMANDS_POST(
[${RM} -rf include
for m in `find . -name Makefile`
do
#       my_top_srcdir=`cd ${srcdir}; pwd`
#       my_top_builddir=`pwd`
        AS_IF(
           [${FGREP} -q nodist_pkginclude_HEADERS ${m}],
              [d=`AS_DIRNAME(["${m}"])`
              ${MAKE-make} -C "${d}" DESTDIR="" 
INSTALL_HEADER="${ac_abs_top_srcdir}/install-pkgheader.sh" 
includedir="${ac_abs_top_builddir}/include" install-nodist_pkgincludeHEADERS],
           [${FGREP} -q pkginclude_HEADERS ${m}],
              [d=`AS_DIRNAME(["${m}"])`
              ${MAKE-make} -C "${d}" DESTDIR="" 
INSTALL_HEADER="${ac_abs_top_srcdir}/install-pkgheader.sh" 
includedir="${ac_abs_top_builddir}/include" install-pkgincludeHEADERS],
           [])
done])

-----------------------------------------------------------

Also I found your configure.ac (included in 
https://www.alberta-fem.de/Downloads/alberta-3.0.0.tar.gz ),
something like this, it can break TMPDIR?

AC_CONFIG_COMMANDS([dof_free_bit.h],
[AS_TMPDIR([alberta])
TMPDIR=${tmp}
TARGET_NEW=${TMPDIR}/dof_free_bit.h
TARGET=alberta/src/Common/dof_free_bit.h
${SHELL} ${srcdir}/mkdoffreemasks.sh ${BITS} 1 > ${TARGET_NEW}
if test -f ${TARGET} && cmp ${TARGET} ${TARGET_NEW} > /dev/null 2>&1 ; then
    AC_MSG_NOTICE([${TARGET} is unchanged])
else
    AC_MSG_NOTICE([Creating ${TARGET}])
    mv -f ${TARGET_NEW} ${TARGET}
fi
rm -rf ${TMPDIR}],
[BITS=$(( ${ac_cv_sizeof_long} * 8 ))])


On 2022/10/28 7:46, Christoph Grüninger wrote:
> Hi,
> with your help I figured out, that there is really an issue with the
> temp directory.
>
> > config.status: executing libtool commands
> > config.status: executing packageheaders commands
> > make: TMPDIR value 
> > /var/folders/lr/5gw1xrv53h1b_9mjjvs2k1dr0000gn/T//albertaiwcZfY: No such file 
> > or directory
> > make: using default temporary directory '/var/tmp/'
> > make: Entering directory 
> > '/Users/gitlab/builds/alberta-fem/alberta3/alberta_util/src'
> >   /usr/local/bin/gmkdir -p 
> > '/Users/gitlab/builds/alberta-fem/alberta3/include/alberta'
> >   /Users/gitlab/builds/alberta-fem/alberta3/install-pkgheader.sh alberta_util.h 
> > alberta_util_inlines.h 
> > '/Users/gitlab/builds/alberta-fem/alberta3/include/alberta'
> > make: Leaving directory 
> > '/Users/gitlab/builds/alberta-fem/alberta3/alberta_util/src'
>
> The sub folder "albertaiwcZfY" (or in general <projectname><random
> string>) is not there. Any hint what might be causing this problem? Any
> idea of how to debug it further?
>
> Bye
> Christoph