[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
[PATCH] More uses of AS_HELP_STRING in automake macros. (was: Re: [PATCH
From: |
Stefano Lattarini |
Subject: |
[PATCH] More uses of AS_HELP_STRING in automake macros. (was: Re: [PATCH] {master} More uses of AS_HELP_STRING in automake macros.) |
Date: |
Tue, 14 Dec 2010 10:43:25 +0100 |
User-agent: |
KMail/1.13.3 (Linux/2.6.30-2-686; KDE/4.4.4; i686; ; ) |
On Monday 13 December 2010, Stefano Lattarini wrote:
> On Monday 13 December 2010, Ralf Wildenhues wrote:
> > Hi Stefano,
> >
> > * Stefano Lattarini wrote on Sun, Dec 12, 2010 at 02:47:35PM CET:
> > > * m4/depend.m4 (AM_DEP_TRACK): Use `AS_HELP_STRING' to format
> > > the help message added to the generated configure.
> > > * m4/dmalloc.m4 (AM_WITH_DMALLOC): Likewise.
> > > * m4/lispdir.m4 (AM_PATH_LISPDIR): Likewise.
> > > * m4/maintainer.m4 (AM_MAINTAINER_MODE): Likewise.
> > > * m4/multi.m4 (AM_ENABLE_MULTILIB): Likewise.
> > > * tests/help-depend.test: Updated.
> > > * tests/help-depend2.test: Likewise.
> > > * tests/help-maintainer.test: Likewise.
> > >
> > > Also, bumped all serial numbers of the modified m4 files.
> >
> > Did you check that the configure --help output was still right?
> >
> Apparently not enough; excerpt:
>
> --enable-dependency-tracking
> do not reject slow dependency extractors
> --disable-dependency-tracking
> speeds up one-time build
>
> This IMHO also shows that tests need to be tightened (without being
> made too strict). I will propose an amended patch soonish.
>
OK, I've split the patch in two parts: the first part (for maint) improves
the tests on automake-generated portions of configure help screens, the
second part (for master) introduces more uses of `AS_HELP_STRING' in the
automake macros, and should not require any updating or tightening of the
tests *once the first part is applied and merged*.
Attached is the second patch (for master). Ok to apply?
Thanks,
Stefano
From 17a5424d366a58c3604325e663202a45d1f9464b Mon Sep 17 00:00:00 2001
From: Stefano Lattarini <address@hidden>
Date: Sun, 12 Dec 2010 14:17:41 +0100
Subject: [PATCH] More uses of AS_HELP_STRING in automake macros.
* m4/depend.m4 (AM_DEP_TRACK): Use `AS_HELP_STRING' to format
the help message added to the generated configure.
* m4/dmalloc.m4 (AM_WITH_DMALLOC): Likewise.
* m4/lispdir.m4 (AM_PATH_LISPDIR): Likewise.
* m4/maintainer.m4 (AM_MAINTAINER_MODE): Likewise.
* m4/multi.m4 (AM_ENABLE_MULTILIB): Likewise.
Also, bumped all serial numbers of the modified m4 files.
---
ChangeLog | 11 +++++++++++
m4/depend.m4 | 12 ++++++++----
m4/dmalloc.m4 | 7 ++++---
m4/lispdir.m4 | 5 +++--
m4/maintainer.m4 | 11 ++++++-----
m4/multi.m4 | 8 +++++---
6 files changed, 37 insertions(+), 17 deletions(-)
diff --git a/ChangeLog b/ChangeLog
index d61bbf5..b05fa10 100644
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,14 @@
+2010-12-14 Stefano Lattarini <address@hidden>
+
+ More uses of AS_HELP_STRING in automake macros.
+ * m4/depend.m4 (AM_DEP_TRACK): Use `AS_HELP_STRING' to format
+ the help message added to the generated configure.
+ * m4/dmalloc.m4 (AM_WITH_DMALLOC): Likewise.
+ * m4/lispdir.m4 (AM_PATH_LISPDIR): Likewise.
+ * m4/maintainer.m4 (AM_MAINTAINER_MODE): Likewise.
+ * m4/multi.m4 (AM_ENABLE_MULTILIB): Likewise.
+ Also, bumped all serial numbers of the modified m4 files.
+
2010-12-13 Stefano Lattarini <address@hidden>
Libobj tests: refer to automake bug tracker for limitations.
diff --git a/m4/depend.m4 b/m4/depend.m4
index 652c4c0..714bc9c 100644
--- a/m4/depend.m4
+++ b/m4/depend.m4
@@ -6,7 +6,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 11
+# serial 12
# There are a few dirty hacks below to avoid letting `AC_PROG_CC' be
# written in clear, in which case automake, when reading aclocal.m4,
@@ -169,9 +169,13 @@ AC_SUBST([DEPDIR], ["${am__leading_dot}deps"])dnl
# AM_DEP_TRACK
# ------------
AC_DEFUN([AM_DEP_TRACK],
-[AC_ARG_ENABLE(dependency-tracking,
-[ --disable-dependency-tracking speeds up one-time build
- --enable-dependency-tracking do not reject slow dependency extractors])
+[AC_ARG_ENABLE([dependency-tracking], [dnl
+AS_HELP_STRING(
+ [--enable-dependency-tracking],
+ [do not reject slow dependency extractors])
+AS_HELP_STRING(
+ [--disable-dependency-tracking],
+ [speeds up one-time build])])
if test "x$enable_dependency_tracking" != xno; then
am_depcomp="$ac_aux_dir/depcomp"
AMDEPBACKSLASH='\'
diff --git a/m4/dmalloc.m4 b/m4/dmalloc.m4
index aea5f9d..5d48a24 100644
--- a/m4/dmalloc.m4
+++ b/m4/dmalloc.m4
@@ -10,12 +10,13 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 4
+# serial 5
AC_DEFUN([AM_WITH_DMALLOC],
[AC_MSG_CHECKING([if malloc debugging is wanted])
-AC_ARG_WITH(dmalloc,
-[ --with-dmalloc use dmalloc, as in http://www.dmalloc.com],
+AC_ARG_WITH([dmalloc],
+[AS_HELP_STRING([--with-dmalloc],
+ [use dmalloc, as in http://www.dmalloc.com])],
[if test "$withval" = yes; then
AC_MSG_RESULT(yes)
AC_DEFINE(WITH_DMALLOC,1,
diff --git a/m4/lispdir.m4 b/m4/lispdir.m4
index 62c2daf..bc1c831 100644
--- a/m4/lispdir.m4
+++ b/m4/lispdir.m4
@@ -10,7 +10,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 10
+# serial 11
# AM_PATH_LISPDIR
# ---------------
@@ -23,7 +23,8 @@ AC_DEFUN([AM_PATH_LISPDIR],
AC_ARG_VAR([EMACS], [the Emacs editor command])
AC_ARG_VAR([EMACSLOADPATH], [the Emacs library search path])
AC_ARG_WITH([lispdir],
- [ --with-lispdir override the default lisp directory],
+ [AS_HELP_STRING([--with-lispdir],
+ [override the default lisp directory])],
[ lispdir="$withval"
AC_MSG_CHECKING([where .elc files should go])
AC_MSG_RESULT([$lispdir])],
diff --git a/m4/maintainer.m4 b/m4/maintainer.m4
index 0b54e67..0d0bf7f 100644
--- a/m4/maintainer.m4
+++ b/m4/maintainer.m4
@@ -8,7 +8,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 5
+# serial 6
# AM_MAINTAINER_MODE([DEFAULT-MODE])
# ----------------------------------
@@ -25,10 +25,11 @@ AC_DEFUN([AM_MAINTAINER_MODE],
AC_MSG_CHECKING([whether to am_maintainer_other maintainer-specific portions
of Makefiles])
dnl maintainer-mode's default is 'disable' unless 'enable' is passed
AC_ARG_ENABLE([maintainer-mode],
-[ --][am_maintainer_other][-maintainer-mode am_maintainer_other make rules
and dependencies not useful
- (and sometimes confusing) to the casual installer],
- [USE_MAINTAINER_MODE=$enableval],
- [USE_MAINTAINER_MODE=]m4_if(am_maintainer_other, [enable], [no], [yes]))
+ [AS_HELP_STRING([--]am_maintainer_other[-maintainer-mode],
+ am_maintainer_other[ make rules and dependencies not useful
+ (and sometimes confusing) to the casual installer])],
+ [USE_MAINTAINER_MODE=$enableval],
+ [USE_MAINTAINER_MODE=]m4_if(am_maintainer_other, [enable], [no], [yes]))
AC_MSG_RESULT([$USE_MAINTAINER_MODE])
AM_CONDITIONAL([MAINTAINER_MODE], [test $USE_MAINTAINER_MODE = yes])
MAINT=$MAINTAINER_MODE_TRUE
diff --git a/m4/multi.m4 b/m4/multi.m4
index 9841767..dce3675 100644
--- a/m4/multi.m4
+++ b/m4/multi.m4
@@ -6,15 +6,17 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# serial 6
+# serial 7
# AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
# ---------------------------------------------------
# Add --enable-multilib to configure.
AC_DEFUN([AM_ENABLE_MULTILIB],
[# Default to --enable-multilib
-AC_ARG_ENABLE(multilib,
-[ --enable-multilib build many library versions (default)],
+AC_ARG_ENABLE([multilib],
+[AS_HELP_STRING(
+ [--enable-multilib],
+ [build many library versions (default)])],
[case "$enableval" in
yes) multilib=yes ;;
no) multilib=no ;;
--
1.7.1