FYI: AM_PROG_REGEX was broken

[Pavel Roskin]

Hello!

I have checked (manually) all Automake *.m4 files for underquoting.
AM_PROG_REGEX was actually broken. Now it's fixed.

Maybe I'll run the Automake macros through the Autoconf testsuite some
day.

I also scanned for other cases where quoting is desired. Whenever you have
a free-form message somebody can add a comma and break it, so I added
quotes in all AC_MSG_* for all agruments other than single words.

Regards,
Pavel Roskin

_________________________
Index: m4/ccstdc.m4
--- m4/ccstdc.m4        Wed Aug  2 04:59:16 2000
+++ m4/ccstdc.m4        Thu Nov 23 20:50:35 2000
@@ -30,7 +30,7 @@
 dnl FIXME: can't do this because then AC_AIX won't work due to a
 dnl circular dependency.
 dnl AC_BEFORE([$0], [AC_PROG_CPP])
-AC_MSG_CHECKING(for ${CC-cc} option to accept ANSI C)
+AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 [am_cv_prog_cc_stdc=no
 ac_save_CC="$CC"
@@ -83,7 +83,7 @@
 if test -z "$am_cv_prog_cc_stdc"; then
   AC_MSG_RESULT([none needed])
 else
-  AC_MSG_RESULT($am_cv_prog_cc_stdc)
+  AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 fi
 case "x$am_cv_prog_cc_stdc" in
   x|xno) ;;
Index: m4/dmalloc.m4
--- m4/dmalloc.m4       Wed Aug  2 04:59:16 2000
+++ m4/dmalloc.m4       Thu Nov 23 20:51:46 2000
@@ -6,7 +6,7 @@
 # serial 1

 AC_DEFUN([AM_WITH_DMALLOC],
-[AC_MSG_CHECKING(if malloc debugging is wanted)
+[AC_MSG_CHECKING([if malloc debugging is wanted])
 AC_ARG_WITH(dmalloc,
 [  --with-dmalloc          use dmalloc, as in
                           http://www.dmalloc.com/dmalloc.tar.gz],
Index: m4/lispdir.m4
--- m4/lispdir.m4       Wed Aug  2 04:59:16 2000
+++ m4/lispdir.m4       Thu Nov 23 20:52:13 2000
@@ -11,7 +11,7 @@
   [   --with-lispdir            Override the default lisp directory ],
   [ lispdir="$withval"
     AC_MSG_CHECKING([where .elc files should go])
-    AC_MSG_RESULT($lispdir)],
+    AC_MSG_RESULT([$lispdir])],
   [
   # If set to t, that means we are running in a shell under Emacs.
   # If you have an Emacs named "t", then use the full path.
Index: m4/maintainer.m4
--- m4/maintainer.m4    Wed Aug  2 04:59:16 2000
+++ m4/maintainer.m4    Thu Nov 23 20:52:48 2000
@@ -11,8 +11,8 @@
                           (and sometimes confusing) to the casual installer],
       USE_MAINTAINER_MODE=$enableval,
       USE_MAINTAINER_MODE=no)
-  AC_MSG_RESULT($USE_MAINTAINER_MODE)
-  AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
+  AC_MSG_RESULT([$USE_MAINTAINER_MODE])
+  AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
   MAINT=$MAINTAINER_MODE_TRUE
   AC_SUBST(MAINT)dnl
 ]
Index: m4/multi.m4
--- m4/multi.m4 Sat Aug 26 16:52:57 2000
+++ m4/multi.m4 Thu Nov 23 20:53:03 2000
@@ -8,7 +8,7 @@
 [case "${enableval}" in
   yes) multilib=yes ;;
   no)  multilib=no ;;
-  *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
+  *)   AC_MSG_ERROR([bad value ${enableval} for multilib option]) ;;
  esac], [multilib=yes])

 # We may get other options which we are undocumented:
Index: m4/python.m4
--- m4/python.m4        Wed Aug  2 04:59:16 2000
+++ m4/python.m4        Thu Nov 23 20:53:24 2000
@@ -99,5 +99,5 @@

   dnl All done.

-  AC_MSG_RESULT(looks good)
+  AC_MSG_RESULT([looks good])
 ])
Index: m4/regex.m4
--- m4/regex.m4 Wed Aug  2 04:59:16 2000
+++ m4/regex.m4 Thu Nov 23 20:46:52 2000
@@ -15,7 +15,7 @@
 # will result in a smaller executable file.

 AC_DEFUN([AM_WITH_REGEX],
-[AC_MSG_CHECKING(which of GNU rx or gawk's regex is wanted)
+[AC_MSG_CHECKING([which of GNU rx or gawk's regex is wanted])
 AC_ARG_WITH(regex,
 [  --without-regex         use GNU rx in lieu of gawk's regex for matching],
 [test "$withval" = yes && am_with_regex=1],
@@ -24,8 +24,8 @@
   AC_MSG_RESULT(regex)
   AC_DEFINE(WITH_REGEX,1,[Define if using GNU regex])
   AC_CACHE_CHECK([for GNU regex in libc], am_cv_gnu_regex,
-    AC_TRY_LINK([], [extern int re_max_failures; re_max_failures = 1],
-               am_cv_gnu_regex=yes, am_cv_gnu_regex=no))
+    [AC_TRY_LINK([], [extern int re_max_failures; re_max_failures = 1],
+               am_cv_gnu_regex=yes, am_cv_gnu_regex=no)])
   if test $am_cv_gnu_regex = no; then
     LIBOBJS="$LIBOBJS regex.$ac_objext"
   fi
Index: m4/strtod.m4
--- m4/strtod.m4        Mon Oct 16 05:01:36 2000
+++ m4/strtod.m4        Thu Nov 23 20:54:09 2000
@@ -63,7 +63,7 @@
   AC_CHECK_FUNCS(pow)
   if test $ac_cv_func_pow = no; then
     AC_CHECK_LIB(m, pow, [am_cv_func_strtod_needs_libm=yes],
-                [AC_MSG_WARN(can't find library containing definition of pow)])
+                [AC_MSG_WARN([can't find library containing definition of 
pow])])
   fi
 fi
 ])
_________________________