Re: MKDIR_P discovered by configure but not substituted in the Makefile

[Bruno Haible]

Eric Blake wrote:
> > automake (GNU automake) 1.9.6
> 
> There's your problem. It's time for an upgrade ...

Upgrading autoconf instead of automake would also help. James' problem
  - can be reproduced with automake 1.9.6, autoconf 2.61,
  - is corrected      with automake 1.9.6, autoconf 2.62 .. 2.65,
  - is corrected      with automake 1.10,  autoconf 2.60 .. 2.65.

The reason is that the definition of AC_PROG_MKDIR_P in autoconf 2.62 has
this piece of code:

  dnl status.m4 does special magic for MKDIR_P instead of AC_SUBST,
  dnl to get relative names right.  However, also AC_SUBST here so
  dnl that Automake versions before 1.10 will pick it up (they do not
  dnl trace AC_SUBST_TRACE).
  dnl FIXME: Remove this once we drop support for Automake < 1.10.
  AC_SUBST([MKDIR_P])dnl

but autoconf 2.61 does not have it. I'm applying this fix to gnulib:


2010-02-20  Bruno Haible  <address@hidden>

        Restore support for automake 1.9.6 with autoconf 2.61.
        * m4/gnulib-common.m4 (AC_PROG_MKDIR_P): Ensure MKDIR_P is AC_SUBSTed.
        Reported by James Youngman <address@hidden>.

--- m4/gnulib-common.m4.orig    Sun Feb 21 03:27:01 2010
+++ m4/gnulib-common.m4 Sun Feb 21 03:26:48 2010
@@ -1,4 +1,4 @@
-# gnulib-common.m4 serial 12
+# gnulib-common.m4 serial 13
 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -61,9 +61,16 @@
 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 
 # AC_PROG_MKDIR_P
-# is a backport of autoconf-2.60's AC_PROG_MKDIR_P.
-# Remove this macro when we can assume autoconf >= 2.60.
-m4_ifdef([AC_PROG_MKDIR_P], [], [
+# is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
+# for interoperability with automake-1.9.6 from autoconf-2.62.
+# Remove this macro when we can assume autoconf >= 2.62 or
+# autoconf >= 2.60 && automake >= 1.10.
+m4_ifdef([AC_PROG_MKDIR_P], [
+  dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
+  m4_define([AC_PROG_MKDIR_P],
+    m4_defn([AC_PROG_MKDIR_P])[
+    AC_SUBST([MKDIR_P])])], [
+  dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
      MKDIR_P='$(mkdir_p)'