bug#20626: Wishlist: M-x shell-command-on-rectangle-region

[Juri Linkov]

> Sorry, I was wrong.  I realized now that query-replace has quite
> a different requirement.  query-replace needs rectangular boundaries
> to limit the search for replacements, whereas shell-command-on-region
> should extract the rectangular region as strings and replace it with
> the result of the command.  Here is a working prototype that demonstrates
> its possible implementation:
>
> (define-advice shell-command-on-region
>     (:around (orig-fun start end command
>                        &optional output-buffer replace
>                        error-buffer display-error-buffer))
>   (if (and (boundp 'rectangle-mark-mode) rectangle-mark-mode)
>       (let ((input (mapconcat 'identity (delete-extract-rectangle start end) 
> "\n"))
>             output)
>         (with-temp-buffer
>           (insert input)
>           (call-process-region (point-min) (point-max)
>                                shell-file-name t t
>                                nil shell-command-switch
>                                command)
>           (setq output (split-string (buffer-string) "\n")))
>         (goto-char start)
>         (insert-rectangle output))
>     (funcall orig-fun start end command
>              output-buffer replace
>              error-buffer display-error-buffer)))
>
> This is another case to take into account when designing the interface,
> i.e. in this case the list of boundaries in the arg START is not necessary,
> and I have no idea how to avoid `(if (and (boundp 'rectangle-mark-mode)
> rectangle-mark-mode))'

For example, the command ‘kill-ring-save’ has the signature

  kill-ring-save (beg end &optional region)

with an additional boolean arg for the region.

And ‘rectangle--extract-region’ contains a condition
that checks for ‘rectangle-mark-mode’.

Combining these two prerequisites we could do a similar thing in
‘shell-command-on-region’ by adding a new arg and using it in the
function body:

diff --git a/lisp/simple.el b/lisp/simple.el
index 1868077..d022504 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -3274,7 +3278,8 @@
 
 (defun shell-command-on-region (start end command
                                      &optional output-buffer replace
-                                     error-buffer display-error-buffer)
+                                     error-buffer display-error-buffer
+                                     region)
   "Execute string COMMAND in inferior shell with region as input.
 Normally display output (if any) in temp buffer `*Shell Command Output*';
 Prefix arg means replace the region with it.  Return the exit code of
@@ -3337,7 +3342,8 @@ (defun shell-command-on-region (start end command
                       current-prefix-arg
                       current-prefix-arg
                       shell-command-default-error-buffer
-                      t)))
+                      t
+                      rectangle-mark-mode)))
   (let ((error-file
         (if error-buffer
             (make-temp-file
@@ -3346,6 +3352,18 @@ (defun shell-command-on-region (start end command
                                    temporary-file-directory)))
           nil))
        exit-status)
+    (if region
+        (let ((input (mapconcat 'identity (delete-extract-rectangle start end) 
"\n"))
+              output)
+          (with-temp-buffer
+            (insert input)
+            (call-process-region (point-min) (point-max)
+                                 shell-file-name t t
+                                 nil shell-command-switch
+                                 command)
+            (setq output (split-string (buffer-string) "\n")))
+          (goto-char start)
+          (insert-rectangle output))
     (if (or replace
            (and output-buffer
                 (not (or (bufferp output-buffer) (stringp output-buffer)))))
@@ -3435,7 +3453,7 @@ (defun shell-command-on-region (start end command
                              exit-status output))))
            ;; Don't kill: there might be useful info in the undo-log.
            ;; (kill-buffer buffer)
-           ))))
+           )))))
 
     (when (and error-file (file-exists-p error-file))
       (if (< 0 (nth 7 (file-attributes error-file)))