[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete
From: |
Juri Linkov |
Subject: |
bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete |
Date: |
Wed, 25 Mar 2020 00:16:52 +0200 |
User-agent: |
Gnus/5.13 (Gnus v5.13) Emacs/28.0.50 (x86_64-pc-linux-gnu) |
>> Maybe it's not working since vc-dir-refresh already doesn't use
>> vc-run-delayed to run vc-dir-refresh-files and vc-dir-update.
>
> I don't know if that's the way to determine this. Doing both calls in the
> callback is a good approach which is easy for vc-dir-refresh to
> take. dired-vc-next-action couldn't do that, so vc-run-delayed could be
> the next best option. Or not, of course.
Actually, vc-run-delayed can't be used because it's fired when the first
vc-process finishes, but vc-dir runs at least 4 processes in sequence.
So the only available callback is in vc-dir-refresh, and only when
`more-to-come' is nil.
> Here's a slight modification: create both the hook and a function inside
> the vc-dir package (let's call it vc-dir-mark-files) which will accept a
> list of file names and mark them. dired-vc-next-action will then call it
> from the hook.
All this works fine with the patch below. The only part of the patch
that I don't like is too much code in the first part of vc-dir-mark-files
that just resolves discrepancy between Dired and VC-Dir:
dired-get-marked-files returns directory names without the trailing slash,
but vc-dir-fileinfo->name returns directories with the trailing slash.
diff --git a/lisp/dired-aux.el b/lisp/dired-aux.el
index 6f50a3da6c..af4d29b556 100644
--- a/lisp/dired-aux.el
+++ b/lisp/dired-aux.el
@@ -3050,6 +3050,33 @@ dired-show-file-type
(backward-delete-char 1))
(message "%s" (buffer-string)))))
+
+(declare-function vc-dir-mark-files "vc-dir")
+
+;;;###autoload
+(defun dired-vc-next-action (verbose)
+ "Do the next version control operation on marked files/directories.
+When only files are marked then call `vc-next-action' with the
+same value of the VERBOSE argument.
+When also directories are marked then call `vc-dir' and mark
+the same files/directories in the VC-Dir buffer that were marked
+in the Dired buffer."
+ (interactive "P")
+ (let ((mark-files
+ (let ((marked-files (dired-get-marked-files nil nil nil nil t)))
+ (when (cl-some #'file-directory-p marked-files)
+ marked-files))))
+ (if mark-files
+ (let ((transient-hook (make-symbol "vc-dir-mark-files")))
+ (fset transient-hook
+ (lambda ()
+ (remove-hook 'vc-dir-refresh-hook transient-hook t)
+ (vc-dir-mark-files mark-files)))
+ (vc-dir-root)
+ (add-hook 'vc-dir-refresh-hook transient-hook nil t))
+ (vc-next-action verbose))))
+
+
(provide 'dired-aux)
;; Local Variables:
diff --git a/lisp/dired.el b/lisp/dired.el
index 438f5e7d8b..51aaf6b01d 100644
--- a/lisp/dired.el
+++ b/lisp/dired.el
@@ -1865,6 +1870,7 @@ dired-mode-map
(define-key map "\177" 'dired-unmark-backward)
(define-key map [remap undo] 'dired-undo)
(define-key map [remap advertised-undo] 'dired-undo)
+ (define-key map [remap vc-next-action] 'dired-vc-next-action)
;; thumbnail manipulation (image-dired)
(define-key map "\C-td" 'image-dired-display-thumbs)
(define-key map "\C-tt" 'image-dired-tag-files)
diff --git a/lisp/vc/vc-dir.el b/lisp/vc/vc-dir.el
index 38b4937e85..43d4a7843c 100644
--- a/lisp/vc/vc-dir.el
+++ b/lisp/vc/vc-dir.el
@@ -771,6 +771,28 @@ vc-dir-toggle-mark
(interactive "e")
(vc-dir-at-event e (vc-dir-mark-unmark 'vc-dir-toggle-mark-file)))
+(defun vc-dir-mark-files (mark-files)
+ (let* ((backend (vc-responsible-backend default-directory))
+ (rootdir (vc-call-backend backend 'root default-directory)))
+ (when (listp mark-files)
+ (setq mark-files (mapcar (lambda (file)
+ (file-relative-name
+ (if (file-directory-p file)
+ (file-name-as-directory file)
+ file)
+ rootdir))
+ mark-files)))
+ (vc-dir-unmark-all-files t)
+ (ewoc-map
+ (lambda (filearg)
+ (when (cond ((consp mark-files)
+ (member (vc-dir-fileinfo->name filearg) mark-files))
+ ((eq mark-files 'registered)
+ (memq (vc-dir-fileinfo->state filearg) '(edited added
removed))))
+ (setf (vc-dir-fileinfo->marked filearg) t)
+ t))
+ vc-ewoc)))
+
(defun vc-dir-clean-files ()
"Delete the marked files, or the current file if no marks.
The files will not be marked as deleted in the version control
@@ -1193,7 +1215,8 @@ vc-dir-refresh
(if remaining
(vc-dir-refresh-files
(mapcar 'vc-dir-fileinfo->name remaining))
- (setq mode-line-process nil))))))))))))
+ (setq mode-line-process nil)
+ (run-hooks 'vc-dir-refresh-hook))))))))))))
(defun vc-dir-show-fileentry (file)
"Insert an entry for a specific file into the current *VC-dir* listing.
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/09
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/11
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/11
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/12
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/13
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/14
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/15
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/15
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/16
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete,
Juri Linkov <=
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/29
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Dmitry Gutov, 2020/03/30
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/24
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Drew Adams, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Drew Adams, 2020/03/25
- bug#34949: 27.0.50; Docstring of `vc-deduce-fileset' incomplete, Juri Linkov, 2020/03/26