[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
bug#41868: [PATCH] Add project-clean-up command
From: |
Philip K. |
Subject: |
bug#41868: [PATCH] Add project-clean-up command |
Date: |
Mon, 15 Jun 2020 23:50:29 +0200 |
Dmitry Gutov <dgutov@yandex.ru> writes:
> On 15.06.2020 21:18, Philip K. wrote:
>
> > +(defcustom project-spare-buffers-regexps
> > + '("\\*Help\\*")
>
> Perhaps also call this project-buffer-spare-conditions? Or something
> like that. Point is, no tie the name to regexps, for easy extension into
> having functions in that list as well.
Renamed it an implemented support for predicates too.
> > + "List of regular expressions to be ignored by `project-clean-up'."
>
> Forgotten reference to the previous name.
There was also some superfluous code from an attempt to reimplement
yes-or-no-p with a third option I removed. Also fixed an inconsistency,
where the prompt would tell the user that more buffers would be killed
that would actually be, depending on the value of
project-buffer-spare-conditions.
(naively) Hoping everything it ok this time.
--
Philip K.
>From 20ab9f1f8fe603e8ea8fe24a7d0e1fdd60be08bb Mon Sep 17 00:00:00 2001
From: Philip K <philip@warpmail.net>
Date: Fri, 12 Jun 2020 23:37:51 +0200
Subject: [PATCH] Add project-kill-buffers command
---
lisp/progmodes/project.el | 41 +++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
diff --git a/lisp/progmodes/project.el b/lisp/progmodes/project.el
index f3df44fa7b..50155e55dd 100644
--- a/lisp/progmodes/project.el
+++ b/lisp/progmodes/project.el
@@ -744,6 +744,47 @@ project-compile
(default-directory (project-root pr)))
(compile command comint)))
+(defcustom project-spare-buffers-conditions
+ '("\\*Help\\*")
+ "List of conditions to be ignored by `project-kill-buffers'.
+If a condition is a string, it will be interpreted as a regular
+expression. If the buffer name matches the regular expresion, the
+buffer will not be killed. If a contition is a function, it will
+be called with the buffer object. If it returns a non-nil value,
+the buffer will not be killed."
+ :type '(repeat (choice regexp function))
+ :version "28.1")
+
+(defun project--buffer-list (pr)
+ "Return a list of all buffers in project PR."
+ (let ((root (project-root pr)) bufs)
+ (dolist (buf (buffer-list))
+ (let ((filename (or (buffer-file-name buf)
+ (buffer-local-value 'default-directory buf))))
+ (when (and filename (file-in-directory-p filename root))
+ (push buf bufs))))
+ (nreverse bufs)))
+
+;;;###autoload
+(defun project-kill-buffers ()
+ "Kill all live buffers of a project.
+Certain buffers may be ignored, depending on the value of
+`project-spare-buffers-conditions'."
+ (interactive)
+ (let* ((pr (project-current t)) bufs)
+ (dolist (buf (project--buffer-list pr))
+ (unless (seq-some
+ (lambda (c)
+ (cond ((stringp c)
+ (string-match-p c (buffer-name buf)))
+ ((functionp c)
+ (funcall c buf))))
+ project-spare-buffers-conditions)
+ (push buf bufs)))
+ (when (yes-or-no-p (format "Kill %d buffers in %s? "
+ (length bufs) (project-root pr)))
+ (mapc #'kill-buffer bufs))))
+
;;; Project list
--
2.20.1
- bug#41868: [PATCH] Add project-clean-up command, Philip K., 2020/06/15
- bug#41868: [PATCH] Add project-clean-up command, Basil L. Contovounesios, 2020/06/15
- bug#41868: [PATCH] Add project-clean-up command, Dmitry Gutov, 2020/06/15
- bug#41868: [PATCH] Add project-clean-up command,
Philip K. <=
- bug#41868: [PATCH] Add project-clean-up command, Dmitry Gutov, 2020/06/16
- bug#41868: [PATCH] Add project-clean-up command, Basil L. Contovounesios, 2020/06/16
- bug#41868: [PATCH] Add project-clean-up command, Eli Zaretskii, 2020/06/16
- bug#41868: [PATCH] Add project-clean-up command, Philip K., 2020/06/16
- bug#41868: [PATCH] Add project-clean-up command, Dmitry Gutov, 2020/06/17
- bug#41868: [PATCH] Add project-clean-up command, Philip K., 2020/06/18
- bug#41868: [PATCH] Add project-clean-up command, Dmitry Gutov, 2020/06/18
- bug#41868: [PATCH] Add project-clean-up command, Philip K., 2020/06/18
- bug#41868: [PATCH] Add project-clean-up command, Dmitry Gutov, 2020/06/18
- bug#41868: [PATCH] Add project-clean-up command, Juri Linkov, 2020/06/18