bug#44229: 27.1; Can not set tabulated-list-format with variable

[Stephen Berman]

On Mon, 26 Oct 2020 06:52:13 +0100 dalanicolai@gmail.com wrote:

> I would like to make the tabulated-list-format customizable, but the
> format (width) can not be set using a variable.
> To reproduce evaluate the following code:
>
> ```
> (defvar col1-width 4)
> (defvar col2-width 10)
>
> (define-derived-mode tabular-bug-demo-mode
>   tabulated-list-mode "tab-bug"
>   "Major mode for Tab-bug."
>   (setq-local tabulated-list-format [("Col1" 4 nil)
>                                      ("Col2" 10 nil)])
>   (tabulated-list-init-header))
>
> (let ((buf (switch-to-buffer "tablist-bug-demo")))
>   (with-current-buffer buf
>     (tabular-bug-demo-mode)
>     (setq-local tabulated-list-entries (list (list nil ["1" "so
> unfortunately this"])
>                                              (list nil ["2" "does not
> work"])
>                                              (list nil ["3" "when using
> variables"])))
>     (tabulated-list-print)))
> ```
>
> The code above should work correctly. However when you try to use the
> variable defined in the first two lines for the width within the
> definition of the tabulated-list-format then no tabular list is printed
> but instead Emacs shows an error that the width is not a number or
> marker (number-or-marker-p).
>
> I guess this is not the desired behavior?

Using the literal vector notation is like using a quoted list.
It works if you use this:

(setq-local tabulated-list-format `[("Col1" ,col1-width nil)
                                    ("Col2" ,col2-width nil)])

or alternatively this:

(setq-local tabulated-list-format (vector (list "Col1" col1-width nil)
                                          (list "Col2" col2-width nil)))

Steve Berman