Re: [Bug-gnulib] more merges from coreutils

[Paul Eggert]

Bruno Haible <address@hidden> writes:

>>      * lib/fnmatch.c, lib/fnmatch_loop.c
>
> These changes should be moved to glibc also, I think?

Yes, that's the plan for these and several other changes.  I want to
get gnulib nailed down first, though.

> I don't find gl_AC_TYPE_UINT32_T in gnulib. Could you please add it and
> make module md5 depend on it?

Sorry about that.  I installed this patch:

2004-08-09  Paul Eggert  <address@hidden>

        * modules/md5 (Files): Add m4/uint32_t.m4.
        * m4/uint32_t.m4: New file.

Index: modules/md5
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/md5,v
retrieving revision 1.4
diff -p -u -r1.4 md5
--- modules/md5 11 Feb 2003 11:28:10 -0000      1.4
+++ modules/md5 9 Aug 2004 17:57:11 -0000
@@ -5,6 +5,7 @@ Files:
 lib/md5.h
 lib/md5.c
 m4/md5.m4
+m4/uint32_t.m4
 
 Depends-on:
 unlocked-io
--- /dev/null   2003-03-18 13:55:57 -0800
+++ gnulib/m4/uint32_t.m4       2004-08-09 09:15:16 -0700
@@ -0,0 +1,60 @@
+# uint32_t.m4 serial 2
+
+# Copyright (C) 2004 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2, or (at your option)
+# any later version.
+
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software Foundation,
+# Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
+
+# Written by Paul Eggert.
+
+AC_DEFUN([gl_AC_TYPE_UINT32_T],
+[
+  AC_CACHE_CHECK([for uint32_t], gl_cv_c_uint32_t,
+    [gl_cv_c_uint32_t=no
+     for ac_type in "uint32_t" "unsigned int" \
+        "unsigned long int" "unsigned short int"; do
+       AC_COMPILE_IFELSE(
+        [AC_LANG_BOOL_COMPILE_TRY(
+           [AC_INCLUDES_DEFAULT],
+           [[(uint32_t) -1 == 4294967295U]])],
+        [gl_cv_c_uint32_t=$ac_type])
+       test $gl_cv_c_uint32_t != no && break
+     done])
+  case $gl_cv_c_uint32_t in
+  no|uint32_t) ;;
+  *)
+    AC_DEFINE_UNQUOTED(uint32_t, $gl_cv_c_uint32_t,
+      [Define to the type of a unsigned integer type of width exactly 32 bits
+       if such a type exists and the standard includes do not define it.])
+    ;;
+  esac
+
+  AC_CACHE_CHECK([for UINT32_MAX], gl_cv_c_uint32_max,
+    [AC_COMPILE_IFELSE(
+       [AC_LANG_BOOL_COMPILE_TRY(
+         [AC_INCLUDES_DEFAULT],
+         [[UINT32_MAX == 4294967295U]])],
+       [gl_cv_c_uint32_max=yes],
+       [gl_cv_c_uint32_max=no])])
+  case $gl_cv_c_uint32_max,$gl_cv_c_uint32_t in
+  yes,*) ;;
+  *,no) ;;
+  *)
+    AC_DEFINE(UINT32_MAX, 4294967295U,
+      [Define to its maximum value if an unsigned integer type of width
+       exactly 32 bits exists and the standard includes do not define
+       UINT32_MAX.])
+    ;;
+  esac
+])