[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
acl.m4: patch required to work around Darwin 8.7.0 bug
From: |
Jim Meyering |
Subject: |
acl.m4: patch required to work around Darwin 8.7.0 bug |
Date: |
Tue, 26 Sep 2006 12:30:12 +0200 |
With this change, coreutils (bootstrapped from CVS) passes "make check"
on Darwin 8.7.0. In case you missed it, details are here:
http://article.gmane.org/gmane.comp.gnu.core-utils.bugs/8263
2006-09-26 Jim Meyering <address@hidden>
* acl.m4 (AC_FUNC_ACL): Disable ACL support altogether
when we detect Darwin 8.7.0's acl_get_file bug.
Rearrange to perform the new (below) run-test while $LIBS
contains any acl-related library. Set USE_ACL at the end.
(gl_ACL_GET_FILE): New function.
Index: m4/acl.m4
===================================================================
RCS file: /sources/gnulib/gnulib/m4/acl.m4,v
retrieving revision 1.7
diff -u -r1.7 acl.m4
--- m4/acl.m4 21 Aug 2006 21:46:31 -0000 1.7
+++ m4/acl.m4 26 Sep 2006 10:27:00 -0000
@@ -5,7 +5,7 @@
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
-# Written by Paul Eggert.
+# Written by Paul Eggert and Jim Meyering.
AC_DEFUN([AC_FUNC_ACL],
[
@@ -13,22 +13,50 @@
dnl Prerequisites of lib/acl.c.
AC_CHECK_HEADERS(sys/acl.h)
- if test "$ac_cv_header_sys_acl_h" = yes; then
- use_acl=1
- else
- use_acl=0
- fi
- AC_DEFINE_UNQUOTED(USE_ACL, $use_acl,
- [Define if you want access control list support.])
AC_CHECK_FUNCS(acl)
ac_save_LIBS="$LIBS"
- AC_SEARCH_LIBS(acl_get_file, acl,
- [test "$ac_cv_search_acl_get_file" = "none required" ||
- LIB_ACL=$ac_cv_search_acl_get_file])
- AC_SUBST(LIB_ACL)
- AC_CHECK_HEADERS(acl/libacl.h)
- AC_CHECK_FUNCS(acl_get_file acl_get_fd acl_set_file acl_set_fd \
- acl_free acl_from_mode acl_from_text acl_to_text \
- acl_delete_def_file acl_entries acl_extended_file)
+ AC_SEARCH_LIBS(acl_get_file, acl,
+ [test "$ac_cv_search_acl_get_file" = "none required" ||
+ LIB_ACL=$ac_cv_search_acl_get_file])
+ AC_SUBST(LIB_ACL)
+ AC_CHECK_HEADERS(acl/libacl.h)
+ AC_CHECK_FUNCS(acl_get_file acl_get_fd acl_set_file acl_set_fd \
+ acl_free acl_from_mode acl_from_text acl_to_text \
+ acl_delete_def_file acl_entries acl_extended_file)
+ if test "$ac_cv_header_sys_acl_h" = yes; then
+ use_acl=1
+ if test "$ac_cv_func_acl_get_file" = yes; then
+ # If we detect the acl_get_file bug, disable ACL support altogether.
+ gl_ACL_GET_FILE( , [use_acl=0])
+ fi
+ else
+ use_acl=0
+ fi
LIBS="$ac_save_LIBS"
+ AC_DEFINE_UNQUOTED(USE_ACL, $use_acl,
+ [Define if you want access control list support.])
+])
+
+# gl_ACL_GET_FILE(IF-WORKS, IF-NOT)
+# -------------------------------------
+# If `acl_get_file' works (does not have a particular bug),
+# run IF-WORKS, otherwise, IF-NOT.
+# This tests for a Darwin 8.7.0 bug, whereby acl_get_file returns NULL,
+# but sets errno = ENOENT for an existing file or directory.
+AC_DEFUN([gl_ACL_GET_FILE],
+[
+ AC_CACHE_CHECK([for working acl_get_file], gl_cv_func_working_acl_get_file,
+ [AC_RUN_IFELSE(
+ [AC_LANG_PROGRAM(
+ [[#include <sys/types.h>
+ #include <sys/acl.h>
+ #include <errno.h>
+ ]],
+ [[return !! (!acl_get_file (".", ACL_TYPE_ACCESS)
+ || errno == ENOENT);]])],
+ [gl_cv_func_working_acl_get_file=yes],
+ [gl_cv_func_working_acl_get_file=no],
+ [gl_cv_func_working_acl_get_file=cross-compiling])])
+
+ AS_IF([test $gl_cv_func_working_acl_get_file = yes], [$1], [$2])
])
[Prev in Thread] |
Current Thread |
[Next in Thread] |
- acl.m4: patch required to work around Darwin 8.7.0 bug,
Jim Meyering <=