[Top][All Lists]
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
Re: problem with #include_next<stdint.h> in /usr/include/idn-int.h
|
From: |
Paul Eggert |
|
Subject: |
Re: problem with #include_next<stdint.h> in /usr/include/idn-int.h |
|
Date: |
Wed, 20 Jun 2007 22:05:31 -0700 |
|
User-agent: |
Gnus/5.110006 (No Gnus v0.6) Emacs/21.4 (gnu/linux) |
Bruno Haible <address@hidden> writes:
> Although I cannot reproduce the original problem (tried gcc 3.3.1 and 4.2.0),
I ran into a similar problem a couple of days ago with Sun Studio 12
on GNU/Linux. That compiler supports #include_next but is not GCC.
It gets into recursive inclusion loops, for example:
cc -I. -g -c allocsa.c
"///opt/sun12/sunstudio12/prod/include/cc/time.h", line 6: too many open
files: <time.h>
"./time.h", line 28: too many open files:
"///opt/sun12/sunstudio12/prod/include/cc/time.h"
"///opt/sun12/sunstudio12/prod/include/cc/stdlib.h", line 6: too many open
files: <stdlib.h>
"./unistd.h", line 26: too many open files:
"///opt/sun12/sunstudio12/prod/include/cc/unistd.h"
"./unistd.h", line 35: too many open files: <stdio.h>
"./unistd.h", line 39: too many open files: <stdlib.h>
"./unistd.h", line 136: too many open files: <stdlib.h>
"allocsa.c", line 74: warning: implicit function declaration: malloc
"allocsa.c", line 128: warning: implicit function declaration: free
cc: acomp failed for allocsa.c
In the past we've solved those problems with hacks like "#if (__GNUC__
|| 60000000 <= __DECC_VER)" but this really should be done the "right"
way, by using include_next if available and by testing for
include_next at 'configure' time.
I installed the following patch to do this. There is a similar patch
for modules I don't maintain, which I'll send shortly in a separate
email. With these two patches, coreutils builds on GNU/Linux with Sun
Studio 12. I hope the patch also solves Simon's problem.
In this patch I also took the liberty of adding "all" to the
maintainer list for the unistd and sys_stat modules since the
maintenance in practice seems to be distributed.
2007-06-20 Paul Eggert <address@hidden>
* m4/include_next.m4 (gl_INCLUDE_NEXT): Define and AC_SUBST
INCLUDE_NEXT.
(gl_CHECK_NEXT_HEADERS): New macro.
* m4/fcntl_h.m4 (gl_FCNTL_H): use gl_CHECK_NEXT_HEADERS instead of
the obsolescent gl_ABSOLUTE_HEADER.
* m4/float_h.m4 (gl_FLOAT_H): Likewise.
* m4/inttypes.m4 (gl_INTTYPES_H): Likewise.
* m4/math_h.m4 (gl_MATH_H): Likewise.
* m4/search_h.m4 (gl_SEARCH_H): Likewise.
* m4/signal_h.m4 (gl_SIGNAL_H): Likewise.
* m4/stdint.m4 (gl_STDINT_H): Likewise.
* m4/stdio_h.m4 (gl_STDIO_H): Likewise.
* m4/stdlib_h.m4 (gl_STDLIB_H): Likewise.
* m4/string_h.m4 (gl_HEADER_STRING_H_BODY): Likewise.
* m4/sys_stat_h.m4 (gl_HEADER_SYS_STAT_H): Likewise.
* m4/sys_time_h.m4 (gl_HEADER_SYS_TIME_H_BODY): Likewise.
* m4/time_h.m4 (gl_HEADER_TIME_H_BODY): Likewise.
* m4/unistd_h.m4 (gl_UNISTD_H): Likewise.
* m4/wchar.m4 (gl_WCHAR_H): Likewise.
* m4/wctype.m4 (gl_WCTYPE_H): Likewise.
* m4/inttypes.m4 (gl_INTTYPES_H): Define
_GL_JUST_INCLUDE_SYSTEM_INTTYPES_H to avoid the problem of unclean
builds, since ABSOLUTE_INTTYPES_H is no longer being defined.
* m4/stdint.m4 (gl_STDINT_H): Likewise, for
_GL_JUST_INCLUDE_SYSTEM_STDINT_H.
* lib/fcntl_.h: Use @INCLUDE_NEXT@ @NEXT_foo_H@
rather than @HAVE_INCLUDE_NEXT@ and @address@hidden
* lib/float_.h: Likewise.
* lib/inttypes_.h: Likewise.
* lib/math_.h: Likewise.
* lib/search_.h: Likewise.
* lib/signal_.h: Likewise.
* lib/stdint_.h: Likewise.
* lib/stdio_.h: Likewise.
* lib/stdlib_.h: Likewise.
* lib/string_.h: Likewise.
* lib/sys_stat_.h: Likewise.
* lib/sys_time_.h: Likewise.
* lib/time_.h: Likewise.
* lib/unistd_.h: Likewise.
* lib/wchar_.h: Likewise.
* lib/wctype_.h: Likewise.
* modules/fcntl (Depends-on): Depend on absolute-header, not
include_next.
(Makefile): Substitute INCLUDE_NEXT and NEXT_foo_H, not
HAVE_INCLUDE_NEXT and ABSOLUTE_foo_H.
* modules/float: Likewise.
* modules/inttypes: Likewise.
* modules/math: Likewise.
* modules/search: Likewise.
* modules/signal: Likewise.
* modules/stdint: Likewise.
* modules/stdio: Likewise.
* modules/stdlib: Likewise.
* modules/string: Likewise.
* modules/sys_stat: Likewise.
* modules/sys_time: Likewise.
* modules/time: Likewise.
* modules/unistd: Likewise.
* modules/wchar: Likewise.
* modules/wctype: Likewise.
* modules/sys_stat: Change maintainer to "all".
* modules/unistd: Likewise.
Index: m4/include_next.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/include_next.m4,v
retrieving revision 1.1
diff -u -p -r1.1 include_next.m4
--- m4/include_next.m4 18 Apr 2006 17:20:47 -0000 1.1
+++ m4/include_next.m4 21 Jun 2007 04:39:05 -0000
@@ -1,19 +1,79 @@
-# include_next.m4 serial 1
-dnl Copyright (C) 2006 Free Software Foundation, Inc.
+# include_next.m4 serial 2
+dnl Copyright (C) 2006, 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
-dnl From Derek Price.
+dnl From Paul Eggert and Derek Price.
AC_DEFUN([gl_INCLUDE_NEXT],
-[AC_CACHE_CHECK([whether the preprocessor supports include_next],
-[gl_cv_have_include_next],
-[AC_PREPROC_IFELSE([#include_next <stddef.h>],
- [gl_cv_have_include_next=yes],
- [gl_cv_have_include_next=no])])
-if test $gl_cv_have_include_next = yes; then
- AC_DEFINE([HAVE_INCLUDE_NEXT], 1,
- [Define if your compiler supports the #include_next directive.])
-fi
+[
+ AC_LANG_PREPROC_REQUIRE()
+ AC_CACHE_CHECK([whether the preprocessor supports include_next],
+ [gl_cv_have_include_next],
+ [AC_PREPROC_IFELSE([#include_next <stddef.h>],
+ [gl_cv_have_include_next=yes],
+ [gl_cv_have_include_next=no])])
+ if test $gl_cv_have_include_next = yes; then
+
+ dnl FIXME: Remove HAVE_INCLUDE_NEXT and update everything that uses it
+ dnl to use @INCLUDE_NEXT@ instead.
+ AC_DEFINE([HAVE_INCLUDE_NEXT], 1,
+ [Define if your compiler supports the #include_next directive.])
+
+ INCLUDE_NEXT=include_next
+ else
+ INCLUDE_NEXT=include
+ fi
+ AC_SUBST([INCLUDE_NEXT])
+])
+
+# gl_CHECK_NEXT_HEADERS(HEADER1 HEADER2 ...)
+# ------------------------------------------
+# For each arg foo.h, if #include_next works, define NEXT_FOO_H to be
+# '<foo.h>'; otherwise define it to be
+# '"///usr/include/foo.h"', or whatever other absolute file name is suitable.
+# That way, a header file with the following line:
+# address@hidden@ @NEXT_FOO_H@
+# behaves (after sed substitution) as if it contained
+# #include_next <foo.h>
+# even if the compiler does not support include_next.
+# The three "///" are to pacify Sun C 5.8, which otherwise would say
+# "warning: #include of /usr/include/... may be non-portable".
+# Use `""', not `<>', so that the /// cannot be confused with a C99 comment.
+AC_DEFUN([gl_CHECK_NEXT_HEADERS],
+[
+ AC_REQUIRE([gl_INCLUDE_NEXT])
+ AC_CHECK_HEADERS_ONCE([$1])
+
+ AC_FOREACH([gl_HEADER_NAME], [$1],
+ [AS_VAR_PUSHDEF([gl_next_header],
+ [gl_cv_next_]m4_quote(m4_defn([gl_HEADER_NAME])))
+ AS_VAR_SET([gl_next_header], ['<'gl_HEADER_NAME'>'])
+ if test $gl_cv_have_include_next = no; then
+ AC_CACHE_CHECK(
+ [absolute name of <]m4_quote(m4_defn([gl_HEADER_NAME]))[>],
+ m4_quote(m4_defn([gl_next_header])),
+ [if test
AS_VAR_GET([ac_cv_header_]m4_quote(m4_defn([gl_HEADER_NAME]))) = yes; then
+ AC_LANG_CONFTEST(
+ [AC_LANG_SOURCE(
+ [[#include <]]m4_dquote(m4_defn([gl_HEADER_NAME]))[[>]]
+ )])
+ dnl eval is necessary to expand ac_cpp.
+ dnl Ultrix and Pyramid sh refuse to redirect output of eval,
+ dnl so use subshell.
+ AS_VAR_SET([gl_next_header],
+ ['"'`(eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
+ sed -n '\#/]m4_quote(m4_defn([gl_HEADER_NAME]))[#{
+ s#.*"\(.*/]m4_quote(m4_defn([gl_HEADER_NAME]))[\)".*#\1#
+ s#^/[^/]#//&#
+ p
+ q
+ }'`'"'])
+ fi])
+ fi
+ AC_SUBST(
+ AS_TR_CPP([NEXT_]m4_quote(m4_defn([gl_HEADER_NAME]))),
+ [AS_VAR_GET([gl_next_header])])
+ AS_VAR_POPDEF([gl_next_header])])
])
Index: m4/fcntl_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/fcntl_h.m4,v
retrieving revision 1.4
diff -u -p -r1.4 fcntl_h.m4
--- m4/fcntl_h.m4 25 Nov 2006 19:29:08 -0000 1.4
+++ m4/fcntl_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,5 +1,5 @@
# Configure fcntl.h.
-dnl Copyright (C) 2006 Free Software Foundation, Inc.
+dnl Copyright (C) 2006, 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
@@ -73,9 +73,7 @@ AC_DEFUN([gl_FCNTL_H],
AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOFOLLOW], [$ac_val],
[Define to 1 if O_NOFOLLOW works.])
- gl_ABSOLUTE_HEADER([fcntl.h])
- ABSOLUTE_FCNTL_H=\"$gl_cv_absolute_fcntl_h\"
- AC_SUBST([ABSOLUTE_FCNTL_H])
+ gl_CHECK_NEXT_HEADERS([fcntl.h])
FCNTL_H='fcntl.h'
AC_SUBST([FCNTL_H])
])
Index: m4/float_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/float_h.m4,v
retrieving revision 1.1
diff -u -p -r1.1 float_h.m4
--- m4/float_h.m4 19 May 2007 20:21:41 -0000 1.1
+++ m4/float_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# float_h.m4 serial 1
+# float_h.m4 serial 2
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -12,9 +12,7 @@ AC_DEFUN([gl_FLOAT_H],
case "$host_os" in
beos*)
FLOAT_H=float.h
- gl_ABSOLUTE_HEADER([float.h])
- ABSOLUTE_FLOAT_H=\"$gl_cv_absolute_float_h\"
- AC_SUBST([ABSOLUTE_FLOAT_H])
+ gl_CHECK_NEXT_HEADERS([float.h])
;;
esac
AC_SUBST([FLOAT_H])
Index: m4/inttypes.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/inttypes.m4,v
retrieving revision 1.18
diff -u -p -r1.18 inttypes.m4
--- m4/inttypes.m4 18 Feb 2007 04:28:27 -0000 1.18
+++ m4/inttypes.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# inttypes.m4 serial 8
+# inttypes.m4 serial 9
dnl Copyright (C) 2006-2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -37,7 +37,8 @@ AC_DEFUN([gl_INTTYPES_H],
#define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
#define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
#define __STDC_FORMAT_MACROS 1 /* to make it work also in C++ mode */
-#include ABSOLUTE_INTTYPES_H
+#define _GL_JUST_INCLUDE_SYSTEM_INTTYPES_H /* work if build isn't clean */
+#include <inttypes.h>
/* No need to duplicate the tests of stdint.m4; they are subsumed by
$gl_cv_header_working_stdint_h = yes. */
@@ -141,14 +142,7 @@ const char *l = /* implicit string conca
else
AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])
- dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
- if test $ac_cv_header_inttypes_h = yes; then
- gl_ABSOLUTE_HEADER([inttypes.h])
- ABSOLUTE_INTTYPES_H=\"$gl_cv_absolute_inttypes_h\"
- else
- ABSOLUTE_INTTYPES_H=\"no/such/file/inttypes.h\"
- fi
- AC_SUBST([ABSOLUTE_INTTYPES_H])
+ gl_CHECK_NEXT_HEADERS([inttypes.h])
PRIPTR_PREFIX=
if test -n "$STDINT_H"; then
Index: m4/math_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/math_h.m4,v
retrieving revision 1.7
diff -u -p -r1.7 math_h.m4
--- m4/math_h.m4 6 Apr 2007 20:55:44 -0000 1.7
+++ m4/math_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# math_h.m4 serial 4
+# math_h.m4 serial 5
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,9 +7,7 @@ dnl with or without modifications, as lo
AC_DEFUN([gl_MATH_H],
[
AC_REQUIRE([gl_MATH_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([math.h])
- ABSOLUTE_MATH_H=\"$gl_cv_absolute_math_h\"
- AC_SUBST([ABSOLUTE_MATH_H])
+ gl_CHECK_NEXT_HEADERS([math.h])
])
AC_DEFUN([gl_MATH_MODULE_INDICATOR],
Index: m4/search_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/search_h.m4,v
retrieving revision 1.1
diff -u -p -r1.1 search_h.m4
--- m4/search_h.m4 25 Mar 2007 02:45:24 -0000 1.1
+++ m4/search_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# search_h.m4 serial 1
+# search_h.m4 serial 2
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,16 +7,13 @@ dnl with or without modifications, as lo
AC_DEFUN([gl_SEARCH_H],
[
AC_REQUIRE([gl_SEARCH_H_DEFAULTS])
- AC_CHECK_HEADERS_ONCE([search.h])
+ gl_CHECK_NEXT_HEADERS([search.h])
if test $ac_cv_header_search_h = yes; then
HAVE_SEARCH_H=1
- gl_ABSOLUTE_HEADER([search.h])
- ABSOLUTE_SEARCH_H=\"$gl_cv_absolute_search_h\"
else
HAVE_SEARCH_H=0
fi
AC_SUBST([HAVE_SEARCH_H])
- AC_SUBST([ABSOLUTE_SEARCH_H])
])
AC_DEFUN([gl_SEARCH_MODULE_INDICATOR],
Index: m4/signal_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/signal_h.m4,v
retrieving revision 1.2
diff -u -p -r1.2 signal_h.m4
--- m4/signal_h.m4 1 May 2007 19:20:18 -0000 1.2
+++ m4/signal_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# signal_h.m4 serial 2
+# signal_h.m4 serial 3
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,9 +7,7 @@ dnl with or without modifications, as lo
AC_DEFUN([gl_SIGNAL_H],
[
AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([signal.h])
- ABSOLUTE_SIGNAL_H=\"$gl_cv_absolute_signal_h\"
- AC_SUBST([ABSOLUTE_SIGNAL_H])
+ gl_CHECK_NEXT_HEADERS([signal.h])
])
AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
Index: m4/stdint.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/stdint.m4,v
retrieving revision 1.32
diff -u -p -r1.32 stdint.m4
--- m4/stdint.m4 7 Jun 2007 13:33:15 -0000 1.32
+++ m4/stdint.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# stdint.m4 serial 26
+# stdint.m4 serial 27
dnl Copyright (C) 2001-2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -45,22 +45,15 @@ AC_DEFUN([gl_STDINT_H],
fi
AC_SUBST([HAVE_SYS_TYPES_H])
- dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
+ gl_CHECK_NEXT_HEADERS([stdint.h])
if test $ac_cv_header_stdint_h = yes; then
- gl_ABSOLUTE_HEADER([stdint.h])
- ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
HAVE_STDINT_H=1
else
- ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
HAVE_STDINT_H=0
fi
- AC_SUBST([ABSOLUTE_STDINT_H])
AC_SUBST([HAVE_STDINT_H])
- dnl Now see whether we need a substitute <stdint.h>. Use
- dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
- dnl a "config.status --recheck" if a stdint.h has been
- dnl created in the build directory.
+ dnl Now see whether we need a substitute <stdint.h>.
if test $ac_cv_header_stdint_h = yes; then
AC_CACHE_CHECK([whether stdint.h conforms to C99],
[gl_cv_header_working_stdint_h],
@@ -70,7 +63,8 @@ AC_DEFUN([gl_STDINT_H],
[
#define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
#define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
-#include ABSOLUTE_STDINT_H
+#define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
+#include <stdint.h>
#ifdef INT8_MAX
int8_t a1 = INT8_MAX;
int8_t a1min = INT8_MIN;
Index: m4/stdio_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/stdio_h.m4,v
retrieving revision 1.16
diff -u -p -r1.16 stdio_h.m4
--- m4/stdio_h.m4 28 May 2007 15:13:36 -0000 1.16
+++ m4/stdio_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# stdio_h.m4 serial 6
+# stdio_h.m4 serial 7
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,9 +7,7 @@ dnl with or without modifications, as lo
AC_DEFUN([gl_STDIO_H],
[
AC_REQUIRE([gl_STDIO_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([stdio.h])
- ABSOLUTE_STDIO_H=\"$gl_cv_absolute_stdio_h\"
- AC_SUBST([ABSOLUTE_STDIO_H])
+ gl_CHECK_NEXT_HEADERS([stdio.h])
])
AC_DEFUN([gl_STDIO_MODULE_INDICATOR],
Index: m4/stdlib_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/stdlib_h.m4,v
retrieving revision 1.2
diff -u -p -r1.2 stdlib_h.m4
--- m4/stdlib_h.m4 19 Feb 2007 00:08:40 -0000 1.2
+++ m4/stdlib_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# stdlib_h.m4 serial 1
+# stdlib_h.m4 serial 2
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -7,9 +7,7 @@ dnl with or without modifications, as lo
AC_DEFUN([gl_STDLIB_H],
[
AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([stdlib.h])
- ABSOLUTE_STDLIB_H=\"$gl_cv_absolute_stdlib_h\"
- AC_SUBST([ABSOLUTE_STDLIB_H])
+ gl_CHECK_NEXT_HEADERS([stdlib.h])
])
AC_DEFUN([gl_STDLIB_MODULE_INDICATOR],
Index: m4/string_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/string_h.m4,v
retrieving revision 1.22
diff -u -p -r1.22 string_h.m4
--- m4/string_h.m4 11 Jun 2007 00:29:30 -0000 1.22
+++ m4/string_h.m4 21 Jun 2007 04:39:05 -0000
@@ -18,9 +18,7 @@ AC_DEFUN([gl_HEADER_STRING_H_BODY],
[
AC_REQUIRE([AC_C_RESTRICT])
AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([string.h])
- ABSOLUTE_STRING_H=\"$gl_cv_absolute_string_h\"
- AC_SUBST([ABSOLUTE_STRING_H])
+ gl_CHECK_NEXT_HEADERS([string.h])
])
AC_DEFUN([gl_STRING_MODULE_INDICATOR],
Index: m4/sys_stat_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/sys_stat_h.m4,v
retrieving revision 1.7
diff -u -p -r1.7 sys_stat_h.m4
--- m4/sys_stat_h.m4 1 May 2007 18:14:44 -0000 1.7
+++ m4/sys_stat_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# sys_stat_h.m4 serial 5 -*- Autoconf -*-
+# sys_stat_h.m4 serial 6 -*- Autoconf -*-
dnl Copyright (C) 2006-2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -42,9 +42,7 @@ AC_DEFUN([gl_HEADER_SYS_STAT_H],
dnl Check for broken stat macros.
AC_REQUIRE([AC_HEADER_STAT])
- gl_ABSOLUTE_HEADER([sys/stat.h])
- ABSOLUTE_SYS_STAT_H=\"$gl_cv_absolute_sys_stat_h\"
- AC_SUBST([ABSOLUTE_SYS_STAT_H])
+ gl_CHECK_NEXT_HEADERS([sys/stat.h])
SYS_STAT_H='sys/stat.h'
AC_SUBST([SYS_STAT_H])
]) # gl_HEADER_SYS_STAT_H
Index: m4/sys_time_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/sys_time_h.m4,v
retrieving revision 1.5
diff -u -p -r1.5 sys_time_h.m4
--- m4/sys_time_h.m4 4 Mar 2007 23:41:27 -0000 1.5
+++ m4/sys_time_h.m4 21 Jun 2007 04:39:05 -0000
@@ -18,17 +18,13 @@ AC_DEFUN([gl_HEADER_SYS_TIME_H],
AC_DEFUN([gl_HEADER_SYS_TIME_H_BODY],
[
AC_REQUIRE([AC_C_RESTRICT])
- AC_CHECK_HEADERS_ONCE([sys/time.h])
+ gl_CHECK_NEXT_HEADERS([sys/time.h])
if test $ac_cv_header_sys_time_h = yes; then
- gl_ABSOLUTE_HEADER([sys/time.h])
- ABSOLUTE_SYS_TIME_H=\"$gl_cv_absolute_sys_time_h\"
HAVE_SYS_TIME_H=1
else
- ABSOLUTE_SYS_TIME_H=\"no/such/file/sys/time.h\"
HAVE_SYS_TIME_H=0
fi
- AC_SUBST([ABSOLUTE_SYS_TIME_H])
AC_SUBST([HAVE_SYS_TIME_H])
AC_CACHE_CHECK([for struct timeval], [gl_cv_sys_struct_timeval],
Index: m4/time_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/time_h.m4,v
retrieving revision 1.1
diff -u -p -r1.1 time_h.m4
--- m4/time_h.m4 12 Feb 2007 18:49:19 -0000 1.1
+++ m4/time_h.m4 21 Jun 2007 04:39:05 -0000
@@ -20,9 +20,7 @@ AC_DEFUN([gl_HEADER_TIME_H_BODY],
[
AC_REQUIRE([AC_C_RESTRICT])
AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
- gl_ABSOLUTE_HEADER([time.h])
- ABSOLUTE_TIME_H=\"$gl_cv_absolute_time_h\"
- AC_SUBST([ABSOLUTE_TIME_H])
+ gl_CHECK_NEXT_HEADERS([time.h])
AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
])
Index: m4/unistd_h.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/unistd_h.m4,v
retrieving revision 1.8
diff -u -p -r1.8 unistd_h.m4
--- m4/unistd_h.m4 16 Jun 2007 06:10:45 -0000 1.8
+++ m4/unistd_h.m4 21 Jun 2007 04:39:05 -0000
@@ -1,4 +1,4 @@
-# unistd_h.m4 serial 8
+# unistd_h.m4 serial 9
dnl Copyright (C) 2006-2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -12,16 +12,15 @@ AC_DEFUN([gl_UNISTD_H],
dnl once only, before all statements that occur in other macros.
AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
+ gl_CHECK_NEXT_HEADERS([unistd.h])
+
AC_CHECK_HEADERS_ONCE([unistd.h])
if test $ac_cv_header_unistd_h = yes; then
HAVE_UNISTD_H=1
- gl_ABSOLUTE_HEADER([unistd.h])
- ABSOLUTE_UNISTD_H=\"$gl_cv_absolute_unistd_h\"
else
HAVE_UNISTD_H=0
fi
AC_SUBST([HAVE_UNISTD_H])
- AC_SUBST([ABSOLUTE_UNISTD_H])
])
AC_DEFUN([gl_UNISTD_MODULE_INDICATOR],
Index: m4/wchar.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/wchar.m4,v
retrieving revision 1.2
diff -u -p -r1.2 wchar.m4
--- m4/wchar.m4 7 Jun 2007 13:33:15 -0000 1.2
+++ m4/wchar.m4 21 Jun 2007 04:39:05 -0000
@@ -7,7 +7,7 @@ dnl with or without modifications, as lo
dnl Written by Eric Blake.
-# wchar.m4 serial 2
+# wchar.m4 serial 3
AC_DEFUN([gl_WCHAR_H],
[
@@ -29,10 +29,8 @@ wchar_t w;]],
HAVE_WCHAR_H=0
fi
AC_SUBST([HAVE_WCHAR_H])
- gl_ABSOLUTE_HEADER([wchar.h])
- ABSOLUTE_WCHAR_H=\"$gl_cv_absolute_wchar_h\"
+ gl_CHECK_NEXT_HEADERS([wchar.h])
WCHAR_H=wchar.h
fi
- AC_SUBST([ABSOLUTE_WCHAR_H])
AC_SUBST([WCHAR_H])
])
Index: m4/wctype.m4
===================================================================
RCS file: /cvsroot/gnulib/gnulib/m4/wctype.m4,v
retrieving revision 1.9
diff -u -p -r1.9 wctype.m4
--- m4/wctype.m4 1 May 2007 18:21:31 -0000 1.9
+++ m4/wctype.m4 21 Jun 2007 04:39:05 -0000
@@ -32,16 +32,13 @@ AC_DEFUN([gl_WCTYPE_H],
if test $ac_cv_func_iswcntrl = yes; then
WCTYPE_H=
fi
- dnl Compute ABSOLUTE_WCTYPE_H even if WCTYPE_H is empty,
+ dnl Compute NEXT_WCTYPE_H even if WCTYPE_H is empty,
dnl for the benefit of builds from non-distclean directories.
- gl_ABSOLUTE_HEADER([wctype.h])
- ABSOLUTE_WCTYPE_H=\"$gl_cv_absolute_wctype_h\"
+ gl_CHECK_NEXT_HEADERS([wctype.h])
HAVE_WCTYPE_H=1
else
- ABSOLUTE_WCTYPE_H=\"no/such/file/wctype.h\"
HAVE_WCTYPE_H=0
fi
- AC_SUBST([ABSOLUTE_WCTYPE_H])
AC_SUBST([HAVE_WCTYPE_H])
AC_SUBST([WCTYPE_H])
])
Index: lib/fcntl_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/fcntl_.h,v
retrieving revision 1.5
diff -u -p -r1.5 fcntl_.h
--- lib/fcntl_.h 30 May 2007 02:16:51 -0000 1.5
+++ lib/fcntl_.h 21 Jun 2007 04:39:05 -0000
@@ -24,11 +24,7 @@
#include <sys/stat.h>
#include <unistd.h>
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <fcntl.h>
-#else
-# include @ABSOLUTE_FCNTL_H@
-#endif
address@hidden@ @NEXT_FCNTL_H@
#ifndef _GL_FCNTL_H
#define _GL_FCNTL_H
Index: lib/float_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/float_.h,v
retrieving revision 1.3
diff -u -p -r1.3 float_.h
--- lib/float_.h 30 May 2007 02:16:52 -0000 1.3
+++ lib/float_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#ifndef _GL_FLOAT_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <float.h>
-#else
-# include @ABSOLUTE_FLOAT_H@
-#endif
address@hidden@ @NEXT_FLOAT_H@
#ifndef _GL_FLOAT_H
#define _GL_FLOAT_H
Index: lib/inttypes_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/inttypes_.h,v
retrieving revision 1.12
diff -u -p -r1.12 inttypes_.h
--- lib/inttypes_.h 30 May 2007 02:16:52 -0000 1.12
+++ lib/inttypes_.h 21 Jun 2007 04:39:05 -0000
@@ -25,17 +25,13 @@
has not been included yet or if this file includes gnulib stdint.h
which in turn includes this file.
The include_next requires a split double-inclusion guard. */
-#if ! defined INTTYPES_H || defined _GL_JUST_INCLUDE_ABSOLUTE_INTTYPES_H
+#if ! defined INTTYPES_H || defined _GL_JUST_INCLUDE_SYSTEM_INTTYPES_H
# if @HAVE_INTTYPES_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <inttypes.h>
-# else
-# include @ABSOLUTE_INTTYPES_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_INTTYPES_H@
# endif
#endif
-#if ! defined INTTYPES_H && ! defined _GL_JUST_INCLUDE_ABSOLUTE_INTTYPES_H
+#if ! defined INTTYPES_H && ! defined _GL_JUST_INCLUDE_SYSTEM_INTTYPES_H
#define INTTYPES_H
/* Include <stdint.h> or the gnulib replacement. */
@@ -1097,4 +1093,4 @@ extern uintmax_t strtoumax (const char *
}
#endif
-#endif /* INTTYPES_H */
+#endif /* !defined INTTYPES_H && !defined _GL_JUST_INCLUDE_SYSTEM_INTTYPES_H */
Index: lib/math_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/math_.h,v
retrieving revision 1.13
diff -u -p -r1.13 math_.h
--- lib/math_.h 30 May 2007 02:16:52 -0000 1.13
+++ lib/math_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#ifndef _GL_MATH_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <math.h>
-#else
-# include @ABSOLUTE_MATH_H@
-#endif
address@hidden@ @NEXT_MATH_H@
#ifndef _GL_MATH_H
#define _GL_MATH_H
Index: lib/search_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/search_.h,v
retrieving revision 1.3
diff -u -p -r1.3 search_.h
--- lib/search_.h 30 May 2007 02:16:52 -0000 1.3
+++ lib/search_.h 21 Jun 2007 04:39:05 -0000
@@ -20,11 +20,7 @@
/* The include_next requires a split double-inclusion guard. */
#if @HAVE_SEARCH_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <search.h>
-# else
-# include @ABSOLUTE_SEARCH_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_SEARCH_H@
#endif
#ifndef _GL_SEARCH_H
Index: lib/signal_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/signal_.h,v
retrieving revision 1.4
diff -u -p -r1.4 signal_.h
--- lib/signal_.h 30 May 2007 02:16:52 -0000 1.4
+++ lib/signal_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#if defined __need_sig_atomic_t || defined __need_sigset_t
/* Special invocation convention inside glibc header files. */
-# if @HAVE_INCLUDE_NEXT@
-# include_next <signal.h>
-# else
-# include @ABSOLUTE_SIGNAL_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_SIGNAL_H@
#else
/* Normal invocation convention. */
@@ -31,11 +27,7 @@
#ifndef _GL_SIGNAL_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <signal.h>
-#else
-# include @ABSOLUTE_SIGNAL_H@
-#endif
address@hidden@ @NEXT_SIGNAL_H@
#ifndef _GL_SIGNAL_H
#define _GL_SIGNAL_H
Index: lib/stdint_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/stdint_.h,v
retrieving revision 1.42
diff -u -p -r1.42 stdint_.h
--- lib/stdint_.h 30 May 2007 02:16:52 -0000 1.42
+++ lib/stdint_.h 21 Jun 2007 04:39:05 -0000
@@ -43,14 +43,10 @@
in <inttypes.h> would reinclude us, skipping our contents because
_GL_STDINT_H is defined.
The include_next requires a split double-inclusion guard. */
-# if @HAVE_INCLUDE_NEXT@
-# include_next <stdint.h>
-# else
-# include @ABSOLUTE_STDINT_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_STDINT_H@
#endif
-#ifndef _GL_STDINT_H
+#if ! defined _GL_STDINT_H && ! defined _GL_JUST_INCLUDE_SYSTEM_STDINT_H
#define _GL_STDINT_H
/* <sys/types.h> defines some of the stdint.h types as well, on glibc,
@@ -58,7 +54,7 @@
AIX 5.2 <sys/types.h> isn't needed and causes troubles.
MacOS X 10.4.6 <sys/types.h> includes <stdint.h> (which is us), but
relies on the system <stdint.h> definitions, so include
- <sys/types.h> after @address@hidden */
+ <sys/types.h> after @address@hidden */
#if @HAVE_SYS_TYPES_H@ && ! defined _AIX
# include <sys/types.h>
#endif
@@ -509,4 +505,4 @@
#endif /* !defined __cplusplus || defined __STDC_CONSTANT_MACROS */
#endif /* _GL_STDINT_H */
-#endif /* _GL_STDINT_H */
+#endif /* !defined _GL_STDINT_H && !defined _GL_JUST_INCLUDE_SYSTEM_STDINT_H */
Index: lib/stdio_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/stdio_.h,v
retrieving revision 1.31
diff -u -p -r1.31 stdio_.h
--- lib/stdio_.h 30 May 2007 02:16:52 -0000 1.31
+++ lib/stdio_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#if defined __need_FILE || defined __need___FILE
/* Special invocation convention inside glibc header files. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <stdio.h>
-#else
-# include @ABSOLUTE_STDIO_H@
-#endif
address@hidden@ @NEXT_STDIO_H@
#else
/* Normal invocation convention. */
@@ -31,11 +27,7 @@
#ifndef _GL_STDIO_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <stdio.h>
-#else
-# include @ABSOLUTE_STDIO_H@
-#endif
address@hidden@ @NEXT_STDIO_H@
#ifndef _GL_STDIO_H
#define _GL_STDIO_H
Index: lib/stdlib_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/stdlib_.h,v
retrieving revision 1.12
diff -u -p -r1.12 stdlib_.h
--- lib/stdlib_.h 30 May 2007 02:16:52 -0000 1.12
+++ lib/stdlib_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#if defined __need_malloc_and_calloc
/* Special invocation convention inside glibc header files. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <stdlib.h>
-#else
-# include @ABSOLUTE_STDLIB_H@
-#endif
address@hidden@ @NEXT_STDLIB_H@
#else
/* Normal invocation convention. */
@@ -31,11 +27,7 @@
#ifndef _GL_STDLIB_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <stdlib.h>
-#else
-# include @ABSOLUTE_STDLIB_H@
-#endif
address@hidden@ @NEXT_STDLIB_H@
#ifndef _GL_STDLIB_H
#define _GL_STDLIB_H
Index: lib/string_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/string_.h,v
retrieving revision 1.34
diff -u -p -r1.34 string_.h
--- lib/string_.h 11 Jun 2007 00:29:30 -0000 1.34
+++ lib/string_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
#ifndef _GL_STRING_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <string.h>
-#else
-# include @ABSOLUTE_STRING_H@
-#endif
address@hidden@ @NEXT_STRING_H@
#ifndef _GL_STRING_H
#define _GL_STRING_H
Index: lib/sys_stat_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/sys_stat_.h,v
retrieving revision 1.4
diff -u -p -r1.4 sys_stat_.h
--- lib/sys_stat_.h 30 May 2007 02:16:52 -0000 1.4
+++ lib/sys_stat_.h 21 Jun 2007 04:39:05 -0000
@@ -24,11 +24,7 @@
#ifndef _GL_SYS_STAT_H
/* The include_next requires a split double-inclusion guard. */
-#if @HAVE_INCLUDE_NEXT@
-# include_next <sys/stat.h>
-#else
-# include @ABSOLUTE_SYS_STAT_H@
-#endif
address@hidden@ @NEXT_SYS_STAT_H@
#ifndef _GL_SYS_STAT_H
#define _GL_SYS_STAT_H
Index: lib/sys_time_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/sys_time_.h,v
retrieving revision 1.6
diff -u -p -r1.6 sys_time_.h
--- lib/sys_time_.h 30 May 2007 02:16:52 -0000 1.6
+++ lib/sys_time_.h 21 Jun 2007 04:39:05 -0000
@@ -22,11 +22,7 @@
/* The include_next requires a split double-inclusion guard. */
#if @HAVE_SYS_TIME_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <sys/time.h>
-# else
-# include @ABSOLUTE_SYS_TIME_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_SYS_TIME_H@
#else
# include <time.h>
#endif
Index: lib/time_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/time_.h,v
retrieving revision 1.6
diff -u -p -r1.6 time_.h
--- lib/time_.h 30 May 2007 02:16:53 -0000 1.6
+++ lib/time_.h 21 Jun 2007 04:39:05 -0000
@@ -21,11 +21,7 @@
symbols. */
#if defined __need_time_t || defined __need_clock_t || defined __need_timespec
-# if @HAVE_INCLUDE_NEXT@
-# include_next <time.h>
-# else
-# include @ABSOLUTE_TIME_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_TIME_H@
#else
/* Normal invocation convention. */
@@ -33,11 +29,7 @@
# if ! defined _GL_TIME_H
/* The include_next requires a split double-inclusion guard. */
-# if @HAVE_INCLUDE_NEXT@
-# include_next <time.h>
-# else
-# include @ABSOLUTE_TIME_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_TIME_H@
# if ! defined _GL_TIME_H
# define _GL_TIME_H
Index: lib/unistd_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/unistd_.h,v
retrieving revision 1.12
diff -u -p -r1.12 unistd_.h
--- lib/unistd_.h 16 Jun 2007 06:10:45 -0000 1.12
+++ lib/unistd_.h 21 Jun 2007 04:39:05 -0000
@@ -19,11 +19,7 @@
/* The include_next requires a split double-inclusion guard. */
#if @HAVE_UNISTD_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <unistd.h>
-# else
-# include @ABSOLUTE_UNISTD_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_UNISTD_H@
#endif
#ifndef _GL_UNISTD_H
Index: lib/wchar_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/wchar_.h,v
retrieving revision 1.6
diff -u -p -r1.6 wchar_.h
--- lib/wchar_.h 7 Jun 2007 13:33:15 -0000 1.6
+++ lib/wchar_.h 21 Jun 2007 04:39:05 -0000
@@ -39,11 +39,7 @@
Some builds of uClibc lack it. */
/* The include_next requires a split double-inclusion guard. */
#if @HAVE_WCHAR_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <wchar.h>
-# else
-# include @ABSOLUTE_WCHAR_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_WCHAR_H@
#endif
#ifndef _GL_WCHAR_H
Index: lib/wctype_.h
===================================================================
RCS file: /cvsroot/gnulib/gnulib/lib/wctype_.h,v
retrieving revision 1.13
diff -u -p -r1.13 wctype_.h
--- lib/wctype_.h 30 May 2007 02:16:53 -0000 1.13
+++ lib/wctype_.h 21 Jun 2007 04:39:05 -0000
@@ -44,11 +44,7 @@
BeOS 5 has the functions but no <wctype.h>. */
/* The include_next requires a split double-inclusion guard. */
#if @HAVE_WCTYPE_H@
-# if @HAVE_INCLUDE_NEXT@
-# include_next <wctype.h>
-# else
-# include @ABSOLUTE_WCTYPE_H@
-# endif
+# @INCLUDE_NEXT@ @NEXT_WCTYPE_H@
#endif
#ifndef _GL_WCTYPE_H
Index: modules/fcntl
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/fcntl,v
retrieving revision 1.8
diff -u -p -r1.8 fcntl
--- modules/fcntl 17 May 2007 06:14:30 -0000 1.8
+++ modules/fcntl 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/fcntl_.h
m4/fcntl_h.m4
Depends-on:
-absolute-header
+include_next
unistd
configure.ac:
@@ -20,8 +20,8 @@ BUILT_SOURCES += $(FCNTL_H)
fcntl.h: fcntl_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
- sed -e 's|@''ABSOLUTE_FCNTL_H''@|$(ABSOLUTE_FCNTL_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_FCNTL_H''@|$(NEXT_FCNTL_H)|g' \
< $(srcdir)/fcntl_.h; \
} > address@hidden
mv address@hidden $@
Index: modules/float
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/float,v
retrieving revision 1.1
diff -u -p -r1.1 float
--- modules/float 19 May 2007 20:21:42 -0000 1.1
+++ modules/float 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/float_.h
m4/float_h.m4
Depends-on:
-absolute-header
+include_next
configure.ac:
gl_FLOAT_H
@@ -19,8 +19,8 @@ BUILT_SOURCES += $(FLOAT_H)
float.h: float_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_FLOAT_H''@|$(ABSOLUTE_FLOAT_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_FLOAT_H''@|$(NEXT_FLOAT_H)|g' \
< $(srcdir)/float_.h; \
} > address@hidden
mv address@hidden $@
Index: modules/inttypes
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/inttypes,v
retrieving revision 1.20
diff -u -p -r1.20 inttypes
--- modules/inttypes 17 May 2007 06:14:30 -0000 1.20
+++ modules/inttypes 21 Jun 2007 04:39:05 -0000
@@ -7,7 +7,7 @@ m4/inttypes-pri.m4
m4/inttypes.m4
Depends-on:
-absolute-header
+include_next
link-warning
stdint
@@ -23,8 +23,8 @@ inttypes.h: inttypes_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
sed -e 's/@''HAVE_INTTYPES_H''@/$(HAVE_INTTYPES_H)/g' \
- -e 's|@''ABSOLUTE_INTTYPES_H''@|$(ABSOLUTE_INTTYPES_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_INTTYPES_H''@|$(NEXT_INTTYPES_H)|g' \
-e 's/@''PRI_MACROS_BROKEN''@/$(PRI_MACROS_BROKEN)/g' \
-e 's/@''HAVE_LONG_LONG_INT''@/$(HAVE_LONG_LONG_INT)/g' \
-e
's/@''HAVE_UNSIGNED_LONG_LONG_INT''@/$(HAVE_UNSIGNED_LONG_LONG_INT)/g' \
Index: modules/math
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/math,v
retrieving revision 1.8
diff -u -p -r1.8 math
--- modules/math 17 May 2007 06:14:30 -0000 1.8
+++ modules/math 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/math_.h
m4/math_h.m4
Depends-on:
-absolute-header
+include_next
link-warning
configure.ac:
@@ -20,8 +20,8 @@ BUILT_SOURCES += math.h
math.h: math_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_MATH_H''@|$(ABSOLUTE_MATH_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_MATH_H''@|$(NEXT_MATH_H)|g' \
-e 's|@''GNULIB_FREXP''@|$(GNULIB_FREXP)|g' \
-e 's|@''GNULIB_FREXPL''@|$(GNULIB_FREXPL)|g' \
-e 's|@''GNULIB_LDEXPL''@|$(GNULIB_LDEXPL)|g' \
Index: modules/search
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/search,v
retrieving revision 1.2
diff -u -p -r1.2 search
--- modules/search 17 May 2007 06:14:30 -0000 1.2
+++ modules/search 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/search_.h
m4/search_h.m4
Depends-on:
-absolute-header
+include_next
link-warning
configure.ac:
@@ -21,8 +21,8 @@ search.h: search_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
sed -e 's|@''HAVE_SEARCH_H''@|$(HAVE_SEARCH_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
- -e 's|@''ABSOLUTE_SEARCH_H''@|$(ABSOLUTE_SEARCH_H)|g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_SEARCH_H''@|$(NEXT_SEARCH_H)|g' \
-e 's|@''GNULIB_TSEARCH''@|$(GNULIB_TSEARCH)|g' \
-e 's|@''HAVE_TSEARCH''@|$(HAVE_TSEARCH)|g' \
-e '/definition of GL_LINK_WARNING/r $(LINK_WARNING_H)' \
Index: modules/signal
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/signal,v
retrieving revision 1.3
diff -u -p -r1.3 signal
--- modules/signal 17 May 2007 06:14:30 -0000 1.3
+++ modules/signal 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/signal_.h
m4/signal_h.m4
Depends-on:
-absolute-header
+include_next
link-warning
configure.ac:
@@ -20,8 +20,8 @@ BUILT_SOURCES += signal.h
signal.h: signal_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_SIGNAL_H''@|$(ABSOLUTE_SIGNAL_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_SIGNAL_H''@|$(NEXT_SIGNAL_H)|g' \
-e 's|@''GNULIB_SIGPROCMASK''@|$(GNULIB_SIGPROCMASK)|g' \
-e
's|@''HAVE_POSIX_SIGNALBLOCKING''@|$(HAVE_POSIX_SIGNALBLOCKING)|g' \
-e 's|@''HAVE_SIGSET_T''@|$(HAVE_SIGSET_T)|g' \
Index: modules/stdint
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/stdint,v
retrieving revision 1.20
diff -u -p -r1.20 stdint
--- modules/stdint 17 May 2007 06:14:30 -0000 1.20
+++ modules/stdint 21 Jun 2007 04:39:05 -0000
@@ -13,7 +13,7 @@ m4/longlong.m4
m4/ulonglong.m4
Depends-on:
-absolute-header
+include_next
wchar
configure.ac:
@@ -28,8 +28,8 @@ stdint.h: stdint_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
sed -e 's/@''HAVE_STDINT_H''@/$(HAVE_STDINT_H)/g' \
- -e 's|@''ABSOLUTE_STDINT_H''@|$(ABSOLUTE_STDINT_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_STDINT_H''@|$(NEXT_STDINT_H)|g' \
-e 's/@''HAVE_SYS_TYPES_H''@/$(HAVE_SYS_TYPES_H)/g' \
-e 's/@''HAVE_INTTYPES_H''@/$(HAVE_INTTYPES_H)/g' \
-e 's/@''HAVE_SYS_INTTYPES_H''@/$(HAVE_SYS_INTTYPES_H)/g' \
Index: modules/stdio
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/stdio,v
retrieving revision 1.18
diff -u -p -r1.18 stdio
--- modules/stdio 28 May 2007 15:13:36 -0000 1.18
+++ modules/stdio 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/stdio_.h
m4/stdio_h.m4
Depends-on:
-absolute-header
+include_next
link-warning
configure.ac:
@@ -20,8 +20,8 @@ BUILT_SOURCES += stdio.h
stdio.h: stdio_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_STDIO_H''@|$(ABSOLUTE_STDIO_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_STDIO_H''@|$(NEXT_STDIO_H)|g' \
-e 's|@''GNULIB_FPRINTF_POSIX''@|$(GNULIB_FPRINTF_POSIX)|g' \
-e 's|@''GNULIB_PRINTF_POSIX''@|$(GNULIB_PRINTF_POSIX)|g' \
-e 's|@''GNULIB_SNPRINTF''@|$(GNULIB_SNPRINTF)|g' \
Index: modules/stdlib
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/stdlib,v
retrieving revision 1.4
diff -u -p -r1.4 stdlib
--- modules/stdlib 17 May 2007 06:14:30 -0000 1.4
+++ modules/stdlib 21 Jun 2007 04:39:05 -0000
@@ -21,8 +21,8 @@ BUILT_SOURCES += stdlib.h
stdlib.h: stdlib_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_STDLIB_H''@|$(ABSOLUTE_STDLIB_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_STDLIB_H''@|$(NEXT_STDLIB_H)|g' \
-e 's|@''GNULIB_GETSUBOPT''@|$(GNULIB_GETSUBOPT)|g' \
-e 's|@''GNULIB_MKDTEMP''@|$(GNULIB_MKDTEMP)|g' \
-e 's|@''GNULIB_MKSTEMP''@|$(GNULIB_MKSTEMP)|g' \
Index: modules/string
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/string,v
retrieving revision 1.22
diff -u -p -r1.22 string
--- modules/string 11 Jun 2007 00:29:30 -0000 1.22
+++ modules/string 21 Jun 2007 04:39:05 -0000
@@ -6,8 +6,8 @@ lib/string_.h
m4/string_h.m4
Depends-on:
-absolute-header
extensions
+include_next
link-warning
configure.ac:
@@ -21,8 +21,8 @@ BUILT_SOURCES += string.h
string.h: string_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@''ABSOLUTE_STRING_H''@|$(ABSOLUTE_STRING_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_STRING_H''@|$(NEXT_STRING_H)|g' \
-e 's|@''GNULIB_MBSLEN''@|$(GNULIB_MBSLEN)|g' \
-e 's|@''GNULIB_MBSNLEN''@|$(GNULIB_MBSNLEN)|g' \
-e 's|@''GNULIB_MBSCHR''@|$(GNULIB_MBSCHR)|g' \
Index: modules/sys_stat
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/sys_stat,v
retrieving revision 1.15
diff -u -p -r1.15 sys_stat
--- modules/sys_stat 17 May 2007 15:56:06 -0000 1.15
+++ modules/sys_stat 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/sys_stat_.h
m4/sys_stat_h.m4
Depends-on:
-absolute-header
+include_next
configure.ac:
gl_HEADER_SYS_STAT_H
@@ -21,8 +21,8 @@ sys/stat.h: sys_stat_.h
@MKDIR_P@ sys
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
- sed -e 's|@''ABSOLUTE_SYS_STAT_H''@|$(ABSOLUTE_SYS_STAT_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_SYS_STAT_H''@|$(NEXT_SYS_STAT_H)|g' \
-e 's|@''HAVE_IO_H''@|$(HAVE_IO_H)|g' \
-e 's|@''HAVE_LSTAT''@|$(HAVE_LSTAT)|g' \
-e 's|@''HAVE_DECL_MKDIR''@|$(HAVE_DECL_MKDIR)|g' \
@@ -39,4 +39,4 @@ License:
LGPL
Maintainer:
-Eric Blake
+all
Index: modules/sys_time
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/sys_time,v
retrieving revision 1.8
diff -u -p -r1.8 sys_time
--- modules/sys_time 17 May 2007 06:14:30 -0000 1.8
+++ modules/sys_time 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/sys_time_.h
m4/sys_time_h.m4
Depends-on:
-absolute-header
+include_next
configure.ac:
gl_HEADER_SYS_TIME_H
@@ -22,8 +22,8 @@ sys/time.h: sys_time_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
sed -e 's/@''HAVE_SYS_TIME_H''@/$(HAVE_SYS_TIME_H)/g' \
- -e 's|@''ABSOLUTE_SYS_TIME_H''@|$(ABSOLUTE_SYS_TIME_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_SYS_TIME_H''@|$(NEXT_SYS_TIME_H)|g' \
-e 's/@''REPLACE_GETTIMEOFDAY''@/$(REPLACE_GETTIMEOFDAY)/g' \
-e 's/@''HAVE_STRUCT_TIMEVAL''@/$(HAVE_STRUCT_TIMEVAL)/g' \
< $(srcdir)/sys_time_.h; \
Index: modules/time
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/time,v
retrieving revision 1.5
diff -u -p -r1.5 time
--- modules/time 17 May 2007 06:14:30 -0000 1.5
+++ modules/time 21 Jun 2007 04:39:05 -0000
@@ -6,8 +6,8 @@ lib/time_.h
m4/time_h.m4
Depends-on:
-absolute-header
extensions
+include_next
configure.ac:
gl_HEADER_TIME_H
@@ -20,8 +20,8 @@ BUILT_SOURCES += time.h
time.h: time_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */' && \
- sed -e 's|@ABSOLUTE_TIME_H''@|$(ABSOLUTE_TIME_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@NEXT_TIME_H''@|$(NEXT_TIME_H)|g' \
-e 's|@REPLACE_LOCALTIME_R''@|$(REPLACE_LOCALTIME_R)|g' \
-e 's|@REPLACE_NANOSLEEP''@|$(REPLACE_NANOSLEEP)|g' \
-e 's|@REPLACE_STRPTIME''@|$(REPLACE_STRPTIME)|g' \
Index: modules/unistd
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/unistd,v
retrieving revision 1.11
diff -u -p -r1.11 unistd
--- modules/unistd 16 Jun 2007 06:10:45 -0000 1.11
+++ modules/unistd 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ m4/unistd_h.m4
lib/unistd_.h
Depends-on:
-absolute-header
+include_next
link-warning
configure.ac:
@@ -21,8 +21,8 @@ unistd.h: unistd_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
sed -e 's|@''HAVE_UNISTD_H''@|$(HAVE_UNISTD_H)|g' \
- -e 's|@''ABSOLUTE_UNISTD_H''@|$(ABSOLUTE_UNISTD_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_UNISTD_H''@|$(NEXT_UNISTD_H)|g' \
-e 's|@''GNULIB_CHOWN''@|$(GNULIB_CHOWN)|g' \
-e 's|@''GNULIB_DUP2''@|$(GNULIB_DUP2)|g' \
-e 's|@''GNULIB_FCHDIR''@|$(GNULIB_FCHDIR)|g' \
@@ -55,4 +55,4 @@ License:
LGPL
Maintainer:
-Simon Josefsson
+all
Index: modules/wchar
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/wchar,v
retrieving revision 1.3
diff -u -p -r1.3 wchar
--- modules/wchar 7 Jun 2007 13:33:15 -0000 1.3
+++ modules/wchar 21 Jun 2007 04:39:05 -0000
@@ -6,7 +6,7 @@ lib/wchar_.h
m4/wchar.m4
Depends-on:
-absolute-header
+include_next
configure.ac:
gl_WCHAR_H
@@ -19,8 +19,8 @@ BUILT_SOURCES += $(WCHAR_H)
wchar.h: wchar_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
- sed -e 's|@''ABSOLUTE_WCHAR_H''@|$(ABSOLUTE_WCHAR_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ sed -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_WCHAR_H''@|$(NEXT_WCHAR_H)|g' \
-e 's/@''HAVE_WCHAR_H''@/$(HAVE_WCHAR_H)/g' \
< $(srcdir)/wchar_.h; \
} > address@hidden
Index: modules/wctype
===================================================================
RCS file: /cvsroot/gnulib/gnulib/modules/wctype,v
retrieving revision 1.7
diff -u -p -r1.7 wctype
--- modules/wctype 17 May 2007 06:14:30 -0000 1.7
+++ modules/wctype 21 Jun 2007 04:39:05 -0000
@@ -7,7 +7,7 @@ m4/wctype.m4
m4/wint_t.m4
Depends-on:
-absolute-header
+include_next
configure.ac:
gl_WCTYPE_H
@@ -21,8 +21,8 @@ wctype.h: wctype_.h
rm -f address@hidden $@
{ echo '/* DO NOT EDIT! GENERATED AUTOMATICALLY! */'; \
sed -e 's/@''HAVE_WCTYPE_H''@/$(HAVE_WCTYPE_H)/g' \
- -e 's|@''ABSOLUTE_WCTYPE_H''@|$(ABSOLUTE_WCTYPE_H)|g' \
- -e 's/@''HAVE_INCLUDE_NEXT''@/$(HAVE_INCLUDE_NEXT)/g' \
+ -e 's/@''INCLUDE_NEXT''@/$(INCLUDE_NEXT)/g' \
+ -e 's|@''NEXT_WCTYPE_H''@|$(NEXT_WCTYPE_H)|g' \
-e 's/@''HAVE_ISWCNTRL''@/$(HAVE_ISWCNTRL)/g' \
-e 's/@''HAVE_WINT_T''@/$(HAVE_WINT_T)/g' \
< $(srcdir)/wctype_.h; \
- Re: problem with #include_next<stdint.h> in /usr/include/idn-int.h, Simon Josefsson, 2007/06/20
- proposed changes to fchdir, iconv_open, locale, netinet_in, sys_select, sys_socket, sysexits, Paul Eggert, 2007/06/21
- Re: proposed changes to fchdir, iconv_open, locale, netinet_in, sys_select, sys_socket, sysexits, Bruno Haible, 2007/06/21
- Re: proposed changes to fchdir, iconv_open, locale, netinet_in, sys_select, sys_socket, sysexits, Paul Eggert, 2007/06/21