round: fix for NetBSD

[Bruno Haible]

On NetBSD 3.0/x86, the round() function exists but yields 1.0 (instead of 0.0)
for x = 1/2 - 2^-54. This is noticed by test-round2.

This patch fixes it by testing for this bug in the autoconf macro.

2007-11-11  Bruno Haible  <address@hidden>

        * m4/round.m4 (gl_FUNC_ROUND): Test against NetBSD 3.0 bug.
        * doc/functions/round.texi: Mention the NetBSD 3.0 bug.

*** doc/functions/round.texi.orig       2007-11-11 15:10:10.000000000 +0100
--- doc/functions/round.texi    2007-11-11 14:52:32.000000000 +0100
***************
*** 11,16 ****
--- 11,19 ----
  @item
  This function is missing on some platforms:
  FreeBSD 5.2.1, OpenBSD 3.8, AIX 5.1, IRIX 6.5, OSF/1 4.0, Solaris 9, Interix 
3.5.
+ @item
+ This functions returns a wrong result for x = 1/2 - 2^-54 on some platforms:
+ NetBSD 3.0.
  @end itemize
  
  Portability problems not fixed by Gnulib:
*** m4/round.m4.orig    2007-11-11 15:10:11.000000000 +0100
--- m4/round.m4 2007-11-11 14:52:39.000000000 +0100
***************
*** 1,4 ****
! # round.m4 serial 4
  dnl Copyright (C) 2007 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
--- 1,4 ----
! # round.m4 serial 5
  dnl Copyright (C) 2007 Free Software Foundation, Inc.
  dnl This file is free software; the Free Software Foundation
  dnl gives unlimited permission to copy and/or distribute it,
***************
*** 13,18 ****
--- 13,56 ----
    if test "$ac_cv_have_decl_round" = yes; then
      gl_CHECK_MATH_LIB([ROUND_LIBM], [x = round (x);])
    fi
+   if test "$ac_cv_have_decl_round" = yes && test "$ROUND_LIBM" != missing; 
then
+     dnl Test whether round() produces correct results. On NetBSD 3.0, for
+     dnl x = 1/2 - 2^-54, the system's round() returns a wrong result.
+     AC_REQUIRE([AC_PROG_CC])
+     AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+     AC_CACHE_CHECK([whether round works], [gl_cv_func_round_works],
+       [
+         save_LIBS="$LIBS"
+         LIBS="$LIBS $ROUND_LIBM"
+         AC_TRY_RUN([
+ #include <float.h>
+ #include <math.h>
+ int main()
+ {
+   /* 2^DBL_MANT_DIG.  */
+   static const double TWO_MANT_DIG =
+     /* Assume DBL_MANT_DIG <= 5 * 31.
+        Use the identity
+        n = floor(n/5) + floor((n+1)/5) + ... + floor((n+4)/5).  */
+     (double) (1U << (DBL_MANT_DIG / 5))
+     * (double) (1U << ((DBL_MANT_DIG + 1) / 5))
+     * (double) (1U << ((DBL_MANT_DIG + 2) / 5))
+     * (double) (1U << ((DBL_MANT_DIG + 3) / 5))
+     * (double) (1U << ((DBL_MANT_DIG + 4) / 5));
+   volatile double x = 0.5 - 0.5 / TWO_MANT_DIG;
+   exit (x < 0.5 && round (x) != 0.0);
+ }], [gl_cv_func_round_works=yes], [gl_cv_func_round_works=no],
+         [case "$host_os" in
+            netbsd*) gl_cv_func_round_works="guessing no";;
+            *)       gl_cv_func_round_works="guessing yes";;
+          esac
+         ])
+         LIBS="$save_LIBS"
+       ])
+     case "$gl_cv_func_round_works" in
+       *no) ROUND_LIBM=missing ;;
+     esac
+   fi
    if test "$ac_cv_have_decl_round" != yes || test "$ROUND_LIBM" = missing; 
then
      REPLACE_ROUND=1
      AC_LIBOBJ([round])