Re: module request: longlong

[Sam Steingold]

> * Ben Pfaff <address@hidden> [2008-07-12 20:57:11 -0700]:
>
> Sam Steingold <address@hidden> writes:
>
>> Hello?  is anyone there?  do you only talk to each other?
>
> You would probably get better results by proposing a patch or by
> asking a particular person.

OK - I am both proposing a patch AND asking a particular person (Bruno Haible).


2008-07-13  Sam Steingold  <address@hidden>

        Add sigsegv module.
        * modules/sigsegv, m4/sigsegv.m4: New files.


===========================================================
--- MODULES.html.sh     13 Jul 2008 13:38:33 -0400      1.260
+++ MODULES.html.sh     13 Jul 2008 13:53:32 -0400      
@@ -1744,6 +1744,7 @@ func_all_modules ()
   func_module fatal-signal
   func_module raise
   func_module strsignal
+  func_module sigsegv
   func_end_table
 
   element="Command-line arguments"
===========================================================

2 files are attached:

Description:
Check for presence of libsigsegv.

Files:
m4/sigsegv.m4

configure.ac:
AC_REQUIRE([gl_SIGSEGV])

License:
GPL

Maintainer:
Bruno Haible

dnl -*- Autoconf -*-
dnl Copyright (C) 2002-2008 Free Software Foundation, Inc.
dnl This file is free software, distributed under the terms of the GNU
dnl General Public License.  As a special exception to the GNU General
dnl Public License, this file may be distributed as part of a program
dnl that contains a configuration script generated by Autoconf, under
dnl the same distribution terms as the rest of that program.

dnl From Bruno Haible, Sam Steingold.

AC_PREREQ(2.61)

AC_DEFUN([gl_SIGSEGV], [dnl
  dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  AC_REQUIRE([AC_LIB_RPATH])

  dnl Search for libsigsegv and define LIBSIGSEGV, LTLIBSIGSEGV and INCSIGSEGV
  dnl accordingly.
  AC_LIB_LINKFLAGS_BODY([sigsegv])

  dnl Add $INCSIGSEGV to CPPFLAGS before performing the following checks,
  dnl because if the user has installed libsigsegv and not disabled its use
  dnl via --without-libsigsegv-prefix, he wants to use it.
  gl_save_CPPFLAGS="$CPPFLAGS"
  AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCSIGSEGV])

  AC_CACHE_CHECK(for libsigsegv, gl_cv_lib_sigsegv, [dnl
    gl_cv_lib_sigsegv="no, consider installing GNU libsigsegv"
    gl_save_LIBS="$LIBS"
    LIBS="$LIBS $LIBSIGSEGV"
    AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sigsegv.h>],
      [sigsegv_deinstall_handler();])], [gl_cv_lib_sigsegv=yes])
    LIBS="$gl_save_LIBS"
  ])
  if test "$gl_cv_lib_sigsegv" = yes; then
    AC_DEFINE(HAVE_SIGSEGV, 1, [Define if you have the libsigsegv library.])
    AC_MSG_CHECKING([how to link with libsigsegv])
    AC_MSG_RESULT([$LIBSIGSEGV])
  else
    dnl If $LIBSIGSEGV didn't lead to a usable library, we don't need
    dnl $INCSIGSEGV either.
    CPPFLAGS="$gl_save_CPPFLAGS"
    LIBSIGSEGV=
    LTLIBSIGSEGV=
  fi
  AC_SUBST(LIBSIGSEGV)
  AC_SUBST(LTLIBSIGSEGV)
])

>>> * Sam Steingold <address@hidden> [2008-07-03 10:53:43 -0400]:
>>>
>>> longlong.m4 is available via many modules, but not alone.
>>> it would be nice if a longlong module were availbale.
>>> offering one single file: longlong.m4
>
> That is pretty easy, so I went ahead and wrote up a patch.
> Please try out the following and see if it does what you want:
>
> commit a012b399fc9ec00d3f27ffcfd25729053791d42f
> Author: Ben Pfaff <address@hidden>
> Date:   Sat Jul 12 20:56:44 2008 -0700
>
>     New module 'longlong'.

looks good, but I don't see this in the cvs yet.


-- 
Sam Steingold (http://sds.podval.org/) on Fedora release 9 (Sulphur)
http://dhimmi.com http://ffii.org http://truepeace.org
http://jihadwatch.org http://camera.org http://openvotingconsortium.org
Whom computers would destroy, they must first drive mad.