Re: new module 'wcrtomb'

[Bruno Haible]

This function too is buggy on Solaris and Tru64: It may return 0 instead of a 
positive
number or an error indicator. Workaround implemented as follows:


2008-12-21  Bruno Haible  <address@hidden>

        Work around a wcrtomb() bug on Solaris 10 and OSF/1 5.1.
        * lib/wchar.in.h (wcrtomb): Override if REPLACE_WCRTOMB is set.
        * m4/wcrtomb.m4 (gl_FUNC_WCRTOMB): Test the return value of wcrtomb
        with NULL destination argument in various locales. Set REPLACE_WCRTOMB
        if not correct.
        * m4/wchar.m4 (gl_WCHAR_H_DEFAULTS): Initialize REPLACE_WCRTOMB.
        * modules/wchar (Makefile.am): Substitute REPLACE_WCRTOMB.
        * modules/wcrtomb (Files): Add m4/locale-fr.m4, m4/locale-ja.m4,
        m4/locale-zh.m4, m4/codeset.m4.
        * doc/posix-functions/wcrtomb.texi: Document the bug.

--- lib/wchar.in.h.orig 2008-12-21 21:52:26.000000000 +0100
+++ lib/wchar.in.h      2008-12-21 21:31:43.000000000 +0100
@@ -207,7 +207,11 @@
 
 /* Convert a wide character to a multibyte character.  */
 #if @GNULIB_WCRTOMB@
-# if address@hidden@
+# if @REPLACE_WCRTOMB@
+#  undef wcrtomb
+#  define wcrtomb rpl_wcrtomb
+# endif
+# if address@hidden@ || @REPLACE_WCRTOMB@
 extern size_t wcrtomb (char *s, wchar_t wc, mbstate_t *ps);
 # endif
 #elif defined GNULIB_POSIXCHECK
--- m4/wcrtomb.m4.orig  2008-12-21 21:52:26.000000000 +0100
+++ m4/wcrtomb.m4       2008-12-21 21:45:27.000000000 +0100
@@ -1,4 +1,4 @@
-# wcrtomb.m4 serial 1
+# wcrtomb.m4 serial 2
 dnl Copyright (C) 2008 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -12,6 +12,70 @@
   AC_CHECK_FUNCS_ONCE([wcrtomb])
   if test $ac_cv_func_wcrtomb = no; then
     HAVE_WCRTOMB=0
+  else
+
+    dnl On OSF/1 5.1 and Solaris 10, wcrtomb (NULL, 0, NULL) sometimes
+    dnl returns 0 instead of 1.
+    AC_REQUIRE([AC_PROG_CC])
+    AC_REQUIRE([gt_LOCALE_FR])
+    AC_REQUIRE([gt_LOCALE_FR_UTF8])
+    AC_REQUIRE([gt_LOCALE_JA])
+    AC_REQUIRE([gt_LOCALE_ZH_CN])
+    AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+    AC_CACHE_CHECK([whether wcrtomb return value is correct],
+      [gl_cv_func_wcrtomb_retval],
+      [
+        dnl Initial guess, used when cross-compiling or when no suitable locale
+        dnl is present.
+changequote(,)dnl
+        case "$host_os" in
+                           # Guess no on OSF/1 and Solaris.
+          osf* | solaris*) gl_cv_func_wcrtomb_retval="guessing no" ;;
+                           # Guess yes otherwise.
+          *)               gl_cv_func_wcrtomb_retval="guessing yes" ;;
+        esac
+changequote([,])dnl
+        if test $LOCALE_FR != none || test $LOCALE_FR_UTF8 != none || test 
$LOCALE_JA != none || test $LOCALE_ZH_CN != none; then
+          AC_TRY_RUN([
+#include <locale.h>
+#include <stdio.h>
+#include <string.h>
+#include <wchar.h>
+int main ()
+{
+  if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
+    {
+      if (wcrtomb (NULL, 0, NULL) != 1)
+        return 1;
+    }
+  if (setlocale (LC_ALL, "$LOCALE_FR_UTF8") != NULL)
+    {
+      if (wcrtomb (NULL, 0, NULL) != 1)
+        return 1;
+    }
+  if (setlocale (LC_ALL, "$LOCALE_JA") != NULL)
+    {
+      if (wcrtomb (NULL, 0, NULL) != 1)
+        return 1;
+    }
+  if (setlocale (LC_ALL, "$LOCALE_ZH_CN") != NULL)
+    {
+      if (wcrtomb (NULL, 0, NULL) != 1)
+        return 1;
+    }
+  return 0;
+}],
+            [gl_cv_func_wcrtomb_retval=yes],
+            [gl_cv_func_wcrtomb_retval=no],
+            [])
+        fi
+      ])
+    case "$gl_cv_func_wcrtomb_retval" in
+      *yes) ;;
+      *) REPLACE_WCRTOMB=1 ;;
+    esac
+  fi
+  if test $HAVE_WCRTOMB = 0 || test $REPLACE_WCRTOMB = 1; then
     gl_REPLACE_WCHAR_H
     AC_LIBOBJ([wcrtomb])
     gl_PREREQ_WCRTOMB
--- m4/wchar.m4.orig    2008-12-21 21:52:26.000000000 +0100
+++ m4/wchar.m4 2008-12-21 21:32:29.000000000 +0100
@@ -7,7 +7,7 @@
 
 dnl Written by Eric Blake.
 
-# wchar.m4 serial 18
+# wchar.m4 serial 19
 
 AC_DEFUN([gl_WCHAR_H],
 [
@@ -87,6 +87,7 @@
   REPLACE_MBRTOWC=0;   AC_SUBST([REPLACE_MBRTOWC])
   REPLACE_MBSRTOWCS=0; AC_SUBST([REPLACE_MBSRTOWCS])
   REPLACE_MBSNRTOWCS=0;AC_SUBST([REPLACE_MBSNRTOWCS])
+  REPLACE_WCRTOMB=0;   AC_SUBST([REPLACE_WCRTOMB])
   REPLACE_WCWIDTH=0;   AC_SUBST([REPLACE_WCWIDTH])
   WCHAR_H='';          AC_SUBST([WCHAR_H])
 ])
--- modules/wchar.orig  2008-12-21 21:52:26.000000000 +0100
+++ modules/wchar       2008-12-21 21:32:46.000000000 +0100
@@ -51,6 +51,7 @@
              -e 's|@''REPLACE_MBRTOWC''@|$(REPLACE_MBRTOWC)|g' \
              -e 's|@''REPLACE_MBSRTOWCS''@|$(REPLACE_MBSRTOWCS)|g' \
              -e 's|@''REPLACE_MBSNRTOWCS''@|$(REPLACE_MBSNRTOWCS)|g' \
+             -e 's|@''REPLACE_WCRTOMB''@|$(REPLACE_WCRTOMB)|g' \
              -e 's|@''REPLACE_WCWIDTH''@|$(REPLACE_WCWIDTH)|g' \
              -e '/definition of GL_LINK_WARNING/r $(LINK_WARNING_H)' \
            < $(srcdir)/wchar.in.h; \
--- modules/wcrtomb.orig        2008-12-21 21:52:26.000000000 +0100
+++ modules/wcrtomb     2008-12-21 21:37:47.000000000 +0100
@@ -5,6 +5,10 @@
 lib/wcrtomb.c
 m4/wcrtomb.m4
 m4/mbstate_t.m4
+m4/locale-fr.m4
+m4/locale-ja.m4
+m4/locale-zh.m4
+m4/codeset.m4
 
 Depends-on:
 wchar
--- doc/posix-functions/wcrtomb.texi.orig       2008-12-21 21:52:26.000000000 
+0100
+++ doc/posix-functions/wcrtomb.texi    2008-12-21 21:49:51.000000000 +0100
@@ -11,6 +11,9 @@
 @item
 This function is missing on some platforms:
 HP-UX 11.00, IRIX 6.5, Solaris 2.6, mingw, Interix 3.5.
address@hidden
+This function returns 0 when the first argument is NULL in some locales on 
some platforms:
+OSF/1 5.1, Solaris 10.
 @end itemize
 
 Portability problems not fixed by Gnulib: