Re: fix bug in glibc 2.7 macro implementation of strtok_r.

[Bruno Haible]

Ben Pfaff wrote:
> This works around a bug in the glibc 2.7 macro implementation of
> strtok_r described here:
> http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.

Thanks. I've done the following modifications to your patch:
  - Choose a macro name that is more similar to the current gnulib idioms.
    For a long time already, HAVE_<some negative connotation> is deprecated;
    we use HAVE_* macros to denote positive features.
  - Prepare not only for undefining the macro, but also for replacing it
    (although it's not used yet).
  - Change the test so that it detects the broken macro also when configuring
    without -O and compiling with -O later.
  - Provide a better cross-compilation default for the test.
  - Fix the quoting style: The general rule is that both arguments to
    AC_LANG_PROGRAM must be doubly quoted: [[ ... ]].
  - In the documentation, list specifically the affected glibc version.

Committed as follows:


2009-09-06  Ben Pfaff  <address@hidden>
            Bruno Haible  <address@hidden>

        Work around a glibc bug in strtok_r.
        * lib/string.in.h (strtok_r): Replace if REPLACE_STRTOK_R is set.
        Undefine if UNDEFINE_STRTOK_R is set.
        * lib/strtok_r.c (strtok_r, __strtok_r) [!_LIBC]: Don't undefine.
        * m4/string_h.m4 (gl_HEADER_STRING_H_DEFAULTS): Initialize
        REPLACE_STRTOK_R and UNDEFINE_STRTOK_R.
        * m4/strtok_r.m4 (gl_FUNC_STRTOK_R): Check against the glibc bug.
        * modules/string (Makefile.am): Substitute REPLACE_STRTOK_R,
        UNDEFINE_STRTOK_R.
        * doc/posix-functions/strtok_r.texi: Mention the glibc 2.7 bug.

--- doc/posix-functions/strtok_r.texi.orig      2009-09-06 17:17:03.000000000 
+0200
+++ doc/posix-functions/strtok_r.texi   2009-09-06 16:48:37.000000000 +0200
@@ -11,6 +11,10 @@
 @item
 This function is missing on some platforms:
 mingw.
address@hidden
+This function crashes when invoked from code compiled with optimization enabled
+on some platforms:
+glibc 2.7.
 @end itemize
 
 Portability problems not fixed by Gnulib:
--- lib/string.in.h.orig        2009-09-06 17:17:03.000000000 +0200
+++ lib/string.in.h     2009-09-06 16:55:35.000000000 +0200
@@ -399,7 +399,13 @@
 
    See also strsep().  */
 #if @GNULIB_STRTOK_R@
-# if ! @HAVE_DECL_STRTOK_R@
+# if @REPLACE_STRTOK_R@
+#  undef strtok_r
+#  define strtok_r rpl_strtok_r
+# elif @UNDEFINE_STRTOK_R@
+#  undef strtok_r
+# endif
+# if ! @HAVE_DECL_STRTOK_R@ || @REPLACE_STRTOK_R@
 extern char *strtok_r (char *restrict s, char const *restrict delim,
                       char **restrict save_ptr);
 # endif
--- lib/strtok_r.c.orig 2009-09-06 17:18:39.000000000 +0200
+++ lib/strtok_r.c      2009-09-06 16:45:07.000000000 +0200
@@ -1,5 +1,5 @@
 /* Reentrant string tokenizer.  Generic version.
-   Copyright (C) 1991,1996-1999,2001,2004,2007 Free Software Foundation, Inc.
+   Copyright (C) 1991,1996-1999,2001,2004,2007,2009 Free Software Foundation, 
Inc.
    This file is part of the GNU C Library.
 
    This program is free software: you can redistribute it and/or modify
@@ -21,10 +21,10 @@
 
 #include <string.h>
 
-#undef strtok_r
-#undef __strtok_r
-
-#ifndef _LIBC
+#ifdef _LIBC
+# undef strtok_r
+# undef __strtok_r
+#else
 # define __strtok_r strtok_r
 # define __rawmemchr strchr
 #endif
--- m4/string_h.m4.orig 2009-09-06 17:17:03.000000000 +0200
+++ m4/string_h.m4      2009-09-06 16:56:27.000000000 +0200
@@ -5,7 +5,7 @@
 # gives unlimited permission to copy and/or distribute it,
 # with or without modifications, as long as this notice is preserved.
 
-# serial 7
+# serial 8
 
 # Written by Paul Eggert.
 
@@ -91,4 +91,6 @@
   REPLACE_STRCASESTR=0;                AC_SUBST([REPLACE_STRCASESTR])
   REPLACE_STRERROR=0;          AC_SUBST([REPLACE_STRERROR])
   REPLACE_STRSIGNAL=0;         AC_SUBST([REPLACE_STRSIGNAL])
+  REPLACE_STRTOK_R=0;          AC_SUBST([REPLACE_STRTOK_R])
+  UNDEFINE_STRTOK_R=0;         AC_SUBST([UNDEFINE_STRTOK_R])
 ])
--- m4/strtok_r.m4.orig 2009-09-06 17:17:03.000000000 +0200
+++ m4/strtok_r.m4      2009-09-06 17:16:36.000000000 +0200
@@ -1,4 +1,4 @@
-# strtok_r.m4 serial 8
+# strtok_r.m4 serial 9
 dnl Copyright (C) 2002, 2003, 2004, 2007, 2009 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -10,7 +10,55 @@
   AC_REQUIRE([AC_C_RESTRICT])
 
   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
-  AC_REPLACE_FUNCS([strtok_r])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CHECK_FUNCS([strtok_r])
+  if test $ac_cv_func_strtok_r = yes; then
+    dnl glibc 2.7 has a bug in strtok_r that causes a segmentation fault
+    dnl when the second argument to strtok_r is a constant string that has
+    dnl exactly one byte and compiling with optimization.  This bug is, for
+    dnl example, present in the glibc 2.7-18 package in Debian "lenny".
+    dnl See <http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614>.
+    AC_CACHE_CHECK([whether strtok_r works], [gl_cv_func_strtok_r_works],
+      [AC_RUN_IFELSE(
+         [AC_LANG_PROGRAM([[
+              #ifndef __OPTIMIZE__
+              # define __OPTIMIZE__ 1
+              #endif
+              #undef __OPTIMIZE_SIZE__
+              #undef __NO_INLINE__
+              #include <stdio.h>
+              #include <string.h>
+            ]],
+            [[char delimiters[] = "xxxxxxxx";
+              char *save_ptr = (char *) 0xd0d0;
+              strtok_r (delimiters, "x", &save_ptr);
+              strtok_r (NULL, "x", &save_ptr);
+              return 0;
+            ]])
+         ],
+         [gl_cv_func_strtok_r_works=yes],
+         [gl_cv_func_strtok_r_works=no],
+         [
+changequote(,)dnl
+          case "$host_os" in
+                    # Guess no on glibc systems.
+            *-gnu*) gl_cv_func_strtok_r_works="guessing no";;
+            *)      gl_cv_func_strtok_r_works="guessing yes";;
+          esac
+changequote([,])dnl
+         ])
+      ])
+    case "$gl_cv_func_strtok_r_works" in
+      *no)
+        dnl We could set REPLACE_STRTOK_R=1 and AC_LIBOBJ([strtok_r]) here,
+        dnl but it's only the macro version in <bits/string2.h> which is wrong.
+        dnl The code compiled into libc is fine.
+        UNDEFINE_STRTOK_R=1
+        ;;
+    esac
+  else
+    AC_LIBOBJ([strtok_r])
+  fi
   AC_CHECK_DECLS_ONCE([strtok_r])
   if test $ac_cv_have_decl_strtok_r = no; then
     HAVE_DECL_STRTOK_R=0
--- modules/string.orig 2009-09-06 17:17:03.000000000 +0200
+++ modules/string      2009-09-06 17:12:56.000000000 +0200
@@ -83,6 +83,8 @@
              -e 's|@''REPLACE_STRSTR''@|$(REPLACE_STRSTR)|g' \
              -e 's|@''REPLACE_STRERROR''@|$(REPLACE_STRERROR)|g' \
              -e 's|@''REPLACE_STRSIGNAL''@|$(REPLACE_STRSIGNAL)|g' \
+             -e 's|@''REPLACE_STRTOK_R''@|$(REPLACE_STRTOK_R)|g' \
+             -e 's|@''UNDEFINE_STRTOK_R''@|$(UNDEFINE_STRTOK_R)|g' \
              -e '/definition of GL_LINK_WARNING/r $(LINK_WARNING_H)' \
              < $(srcdir)/string.in.h; \
        } > address@hidden && \