stpncpy on mingw

[Bruno Haible]

On mingw, with warn-on-use.h modified to simulate a gcc >= 4.3, I'm seeing this
error:

  In file included from test-string-c++.cc:22:
  ../gllib/string.h:525: error: `stpncpy' was not declared in this scope

The reason is that the 'stpncpy' module uses
  #define stpncpy rpl_stpncpy
both in the case when the function is missing (like on mingw) and in the case
where the system provide a broken one (like on AIX). Here it becomes necessary
to distinguish the two cases, like we do for many other functions.


2010-04-03  Bruno Haible  <address@hidden>

        stpncpy: Fix C++ test error on mingw.
        * lib/string.in.h (stpncpy): Use modern idiom.
        * m4/stpncpy.m4 (gl_FUNC_STPNCPY): Distinguish the case that the
        function is missing and that it needs to be replaced.
        * m4/string_h.m4 (gl_HEADER_STRING_H_DEFAULTS): Initialize
        REPLACE_STPNCPY.
        * modules/string (Makefile.am): Replace REPLACE_STPNCPY.

--- lib/string.in.h.orig        Sat Apr  3 13:13:03 2010
+++ lib/string.in.h     Sat Apr  3 13:08:01 2010
@@ -222,7 +222,7 @@
 /* Copy no more than N bytes of SRC to DST, returning a pointer past the
    last non-NUL byte written into DST.  */
 #if @GNULIB_STPNCPY@
-# if ! @HAVE_STPNCPY@
+# if @REPLACE_STPNCPY@
 #  if !(defined __cplusplus && defined GNULIB_NAMESPACE)
 #   define stpncpy rpl_stpncpy
 #  endif
@@ -234,6 +234,12 @@
                   (char *restrict __dst, char const *restrict __src,
                    size_t __n));
 # else
+#  if ! @HAVE_STPNCPY@
+_GL_FUNCDECL_SYS (stpncpy, char *,
+                  (char *restrict __dst, char const *restrict __src,
+                   size_t __n)
+                  _GL_ARG_NONNULL ((1, 2)));
+#  endif
 _GL_CXXALIAS_SYS (stpncpy, char *,
                   (char *restrict __dst, char const *restrict __src,
                    size_t __n));
--- m4/stpncpy.m4.orig  Sat Apr  3 13:13:03 2010
+++ m4/stpncpy.m4       Sat Apr  3 13:12:27 2010
@@ -1,4 +1,4 @@
-# stpncpy.m4 serial 10
+# stpncpy.m4 serial 11
 dnl Copyright (C) 2002-2003, 2005-2007, 2009-2010 Free Software Foundation,
 dnl Inc.
 dnl This file is free software; the Free Software Foundation
@@ -25,8 +25,10 @@
   dnl   in AIX:     dest + max(0,n-1)
   dnl Only the glibc return value is useful in practice.
 
-  AC_CACHE_CHECK([for working stpncpy], [gl_cv_func_stpncpy], [
-    AC_TRY_RUN([
+  AC_CHECK_FUNCS_ONCE([stpncpy])
+  if test $ac_cv_func_stpncpy = yes; then
+    AC_CACHE_CHECK([for working stpncpy], [gl_cv_func_stpncpy], [
+      AC_TRY_RUN([
 #include <stdlib.h>
 #include <string.h> /* for strcpy */
 /* The stpncpy prototype is missing in <string.h> on AIX 4.  */
@@ -45,17 +47,23 @@
   if (stpncpy (dest, src, 7) != dest + 5) exit(1);
   exit(0);
 }
-], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no,
-  [AC_EGREP_CPP([Thanks for using GNU], [
+], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no],
+        [AC_EGREP_CPP([Thanks for using GNU], [
 #include <features.h>
 #ifdef __GNU_LIBRARY__
   Thanks for using GNU
 #endif
-], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no)])])
-
-  if test $gl_cv_func_stpncpy = yes; then
-    AC_DEFINE([HAVE_STPNCPY], [1],
-      [Define if you have the stpncpy() function and it works.])
+], [gl_cv_func_stpncpy=yes], [gl_cv_func_stpncpy=no])
+        ])
+    ])
+    if test $gl_cv_func_stpncpy = yes; then
+      AC_DEFINE([HAVE_STPNCPY], [1],
+        [Define if you have the stpncpy() function and it works.])
+    else
+      REPLACE_STPNCPY=1
+      AC_LIBOBJ([stpncpy])
+      gl_PREREQ_STPNCPY
+    fi
   else
     HAVE_STPNCPY=0
     AC_LIBOBJ([stpncpy])
--- m4/string_h.m4.orig Sat Apr  3 13:13:03 2010
+++ m4/string_h.m4      Sat Apr  3 13:08:32 2010
@@ -5,7 +5,7 @@
 # gives unlimited permission to copy and/or distribute it,
 # with or without modifications, as long as this notice is preserved.
 
-# serial 13
+# serial 14
 
 # Written by Paul Eggert.
 
@@ -95,6 +95,7 @@
   HAVE_STRVERSCMP=1;            AC_SUBST([HAVE_STRVERSCMP])
   REPLACE_MEMCHR=0;             AC_SUBST([REPLACE_MEMCHR])
   REPLACE_MEMMEM=0;             AC_SUBST([REPLACE_MEMMEM])
+  REPLACE_STPNCPY=0;            AC_SUBST([REPLACE_STPNCPY])
   REPLACE_STRDUP=0;             AC_SUBST([REPLACE_STRDUP])
   REPLACE_STRSTR=0;             AC_SUBST([REPLACE_STRSTR])
   REPLACE_STRCASESTR=0;         AC_SUBST([REPLACE_STRCASESTR])
--- modules/string.orig Sat Apr  3 13:13:03 2010
+++ modules/string      Sat Apr  3 13:08:51 2010
@@ -79,6 +79,7 @@
              -e 's|@''HAVE_DECL_STRERROR''@|$(HAVE_DECL_STRERROR)|g' \
              -e 's|@''HAVE_DECL_STRSIGNAL''@|$(HAVE_DECL_STRSIGNAL)|g' \
              -e 's|@''HAVE_STRVERSCMP''@|$(HAVE_STRVERSCMP)|g' \
+             -e 's|@''REPLACE_STPNCPY''@|$(REPLACE_STPNCPY)|g' \
              -e 's|@''REPLACE_MEMCHR''@|$(REPLACE_MEMCHR)|g' \
              -e 's|@''REPLACE_MEMMEM''@|$(REPLACE_MEMMEM)|g' \
              -e 's|@''REPLACE_STRCASESTR''@|$(REPLACE_STRCASESTR)|g' \