Re: Fwd: Automagic dependency on selinux

[Bruno Haible]

Hi Jim,

Thanks for testing.

> However, HAVE_SELINUX_SELINUX_H *is* defined in config.h.
> 
> That is due to the use of
> gl_CHECK_NEXT_HEADERS([selinux/selinux.h]) in selinux-selinux.m4,
> which ends up invoking AC_CHECK_HEADERS_ONCE([selinux/selinux.h]), which
> performs the check long before this conditional in selinux-selinux.m4:
> 
>   if test "$with_selinux" != no; then

OK, so I'm adding code to explicitly set HAVE_SELINUX_SELINUX_H to 0.
This should work better (still untested on my side).
Committed and pushed this.


2010-08-29  Bruno Haible  <address@hidden>

        selinux-h: Offer a --without-selinux option.
        * m4/selinux-selinux-h.m4 (gl_HEADERS_SELINUX_SELINUX_H): If
        --without-selinux was specified, skip all tests and define
        HAVE_SELINUX_SELINUX_H to 0.
        (gl_LIBSELINUX): Offer --without-selinux option. If it is specified,
        set LIB_SELINUX to empty.
        * m4/selinux-context-h.m4 (gl_HEADERS_SELINUX_CONTEXT_H): Require
        gl_LIBSELINUX. If --without-selinux was specified, replace
        selinux/context.h.
        Reported by Johan Hattne <address@hidden>.

--- m4/selinux-context-h.m4.orig        Sun Aug 29 21:36:35 2010
+++ m4/selinux-context-h.m4     Sun Aug 29 21:36:35 2010
@@ -1,4 +1,4 @@
-# serial 1   -*- Autoconf -*-
+# serial 2   -*- Autoconf -*-
 # Copyright (C) 2006-2007, 2009-2010 Free Software Foundation, Inc.
 # This file is free software; the Free Software Foundation
 # gives unlimited permission to copy and/or distribute it,
@@ -9,8 +9,13 @@
 
 AC_DEFUN([gl_HEADERS_SELINUX_CONTEXT_H],
 [
-  AC_CHECK_HEADERS([selinux/context.h],
-                   [SELINUX_CONTEXT_H=],
-                   [SELINUX_CONTEXT_H=selinux/context.h])
+  AC_REQUIRE([gl_LIBSELINUX])
+  if test "$with_selinux" != no; then
+    AC_CHECK_HEADERS([selinux/context.h],
+                     [SELINUX_CONTEXT_H=],
+                     [SELINUX_CONTEXT_H=selinux/context.h])
+  else
+    SELINUX_CONTEXT_H=selinux/context.h
+  fi
   AC_SUBST([SELINUX_CONTEXT_H])
 ])
--- m4/selinux-selinux-h.m4.orig        Sun Aug 29 21:36:35 2010
+++ m4/selinux-selinux-h.m4     Sun Aug 29 21:36:35 2010
@@ -1,4 +1,4 @@
-# serial 3   -*- Autoconf -*-
+# serial 4   -*- Autoconf -*-
 # Copyright (C) 2006-2007, 2009-2010 Free Software Foundation, Inc.
 # This file is free software; the Free Software Foundation
 # gives unlimited permission to copy and/or distribute it,
@@ -12,41 +12,54 @@
 AC_DEFUN([gl_HEADERS_SELINUX_SELINUX_H],
 [
   AC_REQUIRE([gl_LIBSELINUX])
-  AC_CHECK_HEADERS([selinux/selinux.h])
+  if test "$with_selinux" != no; then
+    AC_CHECK_HEADERS([selinux/selinux.h])
 
-  if test "$ac_cv_header_selinux_selinux_h" = yes; then
-    # We do have <selinux/selinux.h>, so do compile getfilecon.c
-    # and arrange to use its wrappers.
-    AC_LIBOBJ([getfilecon])
-    gl_CHECK_NEXT_HEADERS([selinux/selinux.h])
-    AC_DEFINE([getfilecon], [rpl_getfilecon],
-              [Always use our getfilecon wrapper.])
-    AC_DEFINE([lgetfilecon], [rpl_lgetfilecon],
-              [Always use our lgetfilecon wrapper.])
-    AC_DEFINE([fgetfilecon], [rpl_fgetfilecon],
-              [Always use our fgetfilecon wrapper.])
+    if test "$ac_cv_header_selinux_selinux_h" = yes; then
+      # We do have <selinux/selinux.h>, so do compile getfilecon.c
+      # and arrange to use its wrappers.
+      AC_LIBOBJ([getfilecon])
+      gl_CHECK_NEXT_HEADERS([selinux/selinux.h])
+      AC_DEFINE([getfilecon], [rpl_getfilecon],
+                [Always use our getfilecon wrapper.])
+      AC_DEFINE([lgetfilecon], [rpl_lgetfilecon],
+                [Always use our lgetfilecon wrapper.])
+      AC_DEFINE([fgetfilecon], [rpl_fgetfilecon],
+                [Always use our fgetfilecon wrapper.])
+    fi
+
+    case "$ac_cv_search_setfilecon:$ac_cv_header_selinux_selinux_h" in
+      no:*) # already warned
+        ;;
+      *:no)
+        AC_MSG_WARN([libselinux was found but selinux/selinux.h is missing.])
+        AC_MSG_WARN([AC_PACKAGE_NAME will be compiled without SELinux 
support.])
+    esac
+  else
+    # Do as if <selinux/selinux.h> does not exist, even if
+    # AC_CHECK_HEADERS_ONCE has already determined that it exists.
+    AC_DEFINE([HAVE_SELINUX_SELINUX_H], [0])
   fi
-
-  case "$ac_cv_search_setfilecon:$ac_cv_header_selinux_selinux_h" in
-    no:*) # already warned
-      ;;
-    *:no)
-      AC_MSG_WARN([libselinux was found but selinux/selinux.h is missing.])
-      AC_MSG_WARN([AC_PACKAGE_NAME will be compiled without SELinux support.])
-  esac
 ])
 
 AC_DEFUN([gl_LIBSELINUX],
 [
   AC_REQUIRE([AC_CANONICAL_HOST])
   AC_REQUIRE([AC_CANONICAL_BUILD])
+
+  AC_ARG_WITH([selinux],
+    AS_HELP_STRING([--without-selinux], [do not use SELinux, even on systems 
with SELinux]),
+    [], [with_selinux=maybe])
+
   LIB_SELINUX=
-  gl_save_LIBS=$LIBS
-  AC_SEARCH_LIBS([setfilecon], [selinux],
-                 [test "$ac_cv_search_setfilecon" = "none required" ||
-                  LIB_SELINUX=$ac_cv_search_setfilecon])
+  if test "$with_selinux" != no; then
+    gl_save_LIBS=$LIBS
+    AC_SEARCH_LIBS([setfilecon], [selinux],
+                   [test "$ac_cv_search_setfilecon" = "none required" ||
+                    LIB_SELINUX=$ac_cv_search_setfilecon])
+    LIBS=$gl_save_LIBS
+  fi
   AC_SUBST([LIB_SELINUX])
-  LIBS=$gl_save_LIBS
 
   # Warn if SELinux is found but libselinux is absent;
   if test "$ac_cv_search_setfilecon" = no &&