[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]
use AC_CACHE_CHECK where possible
|
From: |
Bruno Haible |
|
Subject: |
use AC_CACHE_CHECK where possible |
|
Date: |
Fri, 12 Oct 2018 10:06:06 +0200 |
|
User-agent: |
KMail/5.1.3 (Linux/4.4.0-137-generic; KDE/5.18.0; x86_64; ; ) |
AC_CACHE_CHECK is a nice combination of AC_MSG_CHECKING + AC_CACHE_VAL
+ AC_MSG_RESULT. Already used more than 500 times in gnulib. Make more
use of it.
2018-10-12 Bruno Haible <address@hidden>
Make better use of Autoconf.
* m4/environ.m4: Use AC_CACHE_CHECK where possible.
* m4/manywarnings.m4: Likewise.
* m4/manywarnings-c++.m4: Likewise.
* m4/socklen.m4: Likewise.
* m4/sockpfaf.m4: Likewise.
* m4/stdarg.m4: Likewise.
* m4/visibility.m4: Likewise.
* m4/fsusage.m4: Use AC_CACHE_CHECK where possible. Modernize
indentation.
* m4/ls-mntd-fs.m4: Likewise.
[diff -w]
diff --git a/m4/environ.m4 b/m4/environ.m4
index 68b67ea..acee536 100644
--- a/m4/environ.m4
+++ b/m4/environ.m4
@@ -1,4 +1,4 @@
-# environ.m4 serial 6
+# environ.m4 serial 7
dnl Copyright (C) 2001-2004, 2006-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -29,16 +29,14 @@ AC_DEFUN_ONCE([gl_ENVIRON],
AC_DEFUN([gt_CHECK_VAR_DECL],
[
define([gt_cv_var], [gt_cv_var_]$2[_declaration])
- AC_MSG_CHECKING([if $2 is properly declared])
- AC_CACHE_VAL([gt_cv_var], [
- AC_COMPILE_IFELSE(
+ AC_CACHE_CHECK([if $2 is properly declared], [gt_cv_var],
+ [AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM(
[[$1
extern struct { int foo; } $2;]],
[[$2.foo = 1;]])],
[gt_cv_var=no],
[gt_cv_var=yes])])
- AC_MSG_RESULT([$gt_cv_var])
if test $gt_cv_var = yes; then
AC_DEFINE([HAVE_]m4_translit($2, [a-z], [A-Z])[_DECL], 1,
[Define if you have the declaration of $2.])
diff --git a/m4/fsusage.m4 b/m4/fsusage.m4
index f9dfbcb..aab4024 100644
--- a/m4/fsusage.m4
+++ b/m4/fsusage.m4
@@ -1,4 +1,4 @@
-# serial 32
+# serial 33
# Obtaining file system usage information.
# Copyright (C) 1997-1998, 2000-2001, 2003-2018 Free Software Foundation, Inc.
@@ -48,8 +48,11 @@ ac_fsusage_space=no
if test $ac_fsusage_space = no; then
# glibc/{Hurd,kFreeBSD}, FreeBSD >= 5.0, NetBSD >= 3.0,
# OpenBSD >= 4.4, AIX, HP-UX, IRIX, Solaris, Cygwin, Interix, BeOS.
- AC_CACHE_CHECK([for statvfs function (SVR4)], [fu_cv_sys_stat_statvfs],
- [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
+ AC_CACHE_CHECK([for statvfs function (SVR4)],
+ [fu_cv_sys_stat_statvfs],
+ [AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM([[
+#include <sys/types.h>
#ifdef __osf__
"Do not use Tru64's statvfs implementation"
#endif
@@ -70,7 +73,8 @@ int check_f_blocks_size[sizeof fsd.f_blocks * CHAR_BIT <= 32
? -1 : 1];
]],
[[statvfs (0, &fsd);]])],
[fu_cv_sys_stat_statvfs=yes],
- [fu_cv_sys_stat_statvfs=no])])
+ [fu_cv_sys_stat_statvfs=no])
+ ])
if test $fu_cv_sys_stat_statvfs = yes; then
ac_fsusage_space=yes
# AIX >= 5.2 has statvfs64 that has a wider f_blocks field than statvfs.
@@ -104,9 +108,10 @@ fi
# Check for this unconditionally so we have a
# good fallback on glibc/Linux > 2.6 < 2.6.36
-AC_MSG_CHECKING([for two-argument statfs with statfs.f_frsize member])
-AC_CACHE_VAL([fu_cv_sys_stat_statfs2_frsize],
-[AC_RUN_IFELSE([AC_LANG_SOURCE([[
+ AC_CACHE_CHECK([for two-argument statfs with statfs.f_frsize member],
+ [fu_cv_sys_stat_statfs2_frsize],
+ [AC_RUN_IFELSE(
+ [AC_LANG_SOURCE([[
#ifdef HAVE_SYS_PARAM_H
#include <sys/param.h>
#endif
@@ -125,8 +130,8 @@ AC_CACHE_VAL([fu_cv_sys_stat_statfs2_frsize],
}]])],
[fu_cv_sys_stat_statfs2_frsize=yes],
[fu_cv_sys_stat_statfs2_frsize=no],
- [fu_cv_sys_stat_statfs2_frsize=no])])
-AC_MSG_RESULT([$fu_cv_sys_stat_statfs2_frsize])
+ [fu_cv_sys_stat_statfs2_frsize=no])
+ ])
if test $fu_cv_sys_stat_statfs2_frsize = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS2_FRSIZE], [1],
@@ -136,8 +141,8 @@ fi
if test $ac_fsusage_space = no; then
# DEC Alpha running OSF/1
- AC_MSG_CHECKING([for 3-argument statfs function (DEC OSF/1)])
- AC_CACHE_VAL([fu_cv_sys_stat_statfs3_osf1],
+ AC_CACHE_CHECK([for 3-argument statfs function (DEC OSF/1)],
+ [fu_cv_sys_stat_statfs3_osf1],
[AC_RUN_IFELSE([AC_LANG_SOURCE([[
#include <sys/param.h>
#include <sys/types.h>
@@ -151,8 +156,8 @@ if test $ac_fsusage_space = no; then
}]])],
[fu_cv_sys_stat_statfs3_osf1=yes],
[fu_cv_sys_stat_statfs3_osf1=no],
- [fu_cv_sys_stat_statfs3_osf1=no])])
- AC_MSG_RESULT([$fu_cv_sys_stat_statfs3_osf1])
+ [fu_cv_sys_stat_statfs3_osf1=no])
+ ])
if test $fu_cv_sys_stat_statfs3_osf1 = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS3_OSF1], [1],
@@ -167,9 +172,8 @@ if test $ac_fsusage_space = no; then
# (On IRIX you need to include <sys/statfs.h>, not only <sys/mount.h> and
# <sys/vfs.h>.)
# (On Solaris, statfs has 4 arguments.)
- AC_MSG_CHECKING([for two-argument statfs with statfs.f_bsize dnl
-member (AIX, 4.3BSD)])
- AC_CACHE_VAL([fu_cv_sys_stat_statfs2_bsize],
+ AC_CACHE_CHECK([for two-argument statfs with statfs.f_bsize member (AIX,
4.3BSD)],
+ [fu_cv_sys_stat_statfs2_bsize],
[AC_RUN_IFELSE([AC_LANG_SOURCE([[
#ifdef HAVE_SYS_PARAM_H
#include <sys/param.h>
@@ -189,8 +193,8 @@ member (AIX, 4.3BSD)])
}]])],
[fu_cv_sys_stat_statfs2_bsize=yes],
[fu_cv_sys_stat_statfs2_bsize=no],
- [fu_cv_sys_stat_statfs2_bsize=no])])
- AC_MSG_RESULT([$fu_cv_sys_stat_statfs2_bsize])
+ [fu_cv_sys_stat_statfs2_bsize=no])
+ ])
if test $fu_cv_sys_stat_statfs2_bsize = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS2_BSIZE], [1],
@@ -202,8 +206,8 @@ fi
if test $ac_fsusage_space = no; then
# SVR3
# (Solaris already handled above.)
- AC_MSG_CHECKING([for four-argument statfs (AIX-3.2.5, SVR3)])
- AC_CACHE_VAL([fu_cv_sys_stat_statfs4],
+ AC_CACHE_CHECK([for four-argument statfs (AIX-3.2.5, SVR3)],
+ [fu_cv_sys_stat_statfs4],
[AC_RUN_IFELSE([AC_LANG_SOURCE([[
#include <sys/types.h>
#include <sys/statfs.h>
@@ -215,8 +219,8 @@ if test $ac_fsusage_space = no; then
}]])],
[fu_cv_sys_stat_statfs4=yes],
[fu_cv_sys_stat_statfs4=no],
- [fu_cv_sys_stat_statfs4=no])])
- AC_MSG_RESULT([$fu_cv_sys_stat_statfs4])
+ [fu_cv_sys_stat_statfs4=no])
+ ])
if test $fu_cv_sys_stat_statfs4 = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS4], [1],
@@ -230,9 +234,8 @@ if test $ac_fsusage_space = no; then
# (On AIX, you need to include <sys/statfs.h>, not only <sys/mount.h>.)
# (On Solaris, statfs has 4 arguments and 'struct statfs' is not declared
in
# <sys/mount.h>.)
- AC_MSG_CHECKING([for two-argument statfs with statfs.f_fsize dnl
-member (4.4BSD and NetBSD)])
- AC_CACHE_VAL([fu_cv_sys_stat_statfs2_fsize],
+ AC_CACHE_CHECK([for two-argument statfs with statfs.f_fsize member (4.4BSD
and NetBSD)],
+ [fu_cv_sys_stat_statfs2_fsize],
[AC_RUN_IFELSE([AC_LANG_SOURCE([[
#include <sys/types.h>
#ifdef HAVE_SYS_PARAM_H
@@ -250,8 +253,8 @@ member (4.4BSD and NetBSD)])
}]])],
[fu_cv_sys_stat_statfs2_fsize=yes],
[fu_cv_sys_stat_statfs2_fsize=no],
- [fu_cv_sys_stat_statfs2_fsize=no])])
- AC_MSG_RESULT([$fu_cv_sys_stat_statfs2_fsize])
+ [fu_cv_sys_stat_statfs2_fsize=no])
+ ])
if test $fu_cv_sys_stat_statfs2_fsize = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS2_FSIZE], [1],
@@ -262,8 +265,8 @@ fi
if test $ac_fsusage_space = no; then
# Ultrix
- AC_MSG_CHECKING([for two-argument statfs with struct fs_data (Ultrix)])
- AC_CACHE_VAL([fu_cv_sys_stat_fs_data],
+ AC_CACHE_CHECK([for two-argument statfs with struct fs_data (Ultrix)],
+ [fu_cv_sys_stat_fs_data],
[AC_RUN_IFELSE([AC_LANG_SOURCE([[
#include <sys/types.h>
#ifdef HAVE_SYS_PARAM_H
@@ -285,8 +288,8 @@ if test $ac_fsusage_space = no; then
}]])],
[fu_cv_sys_stat_fs_data=yes],
[fu_cv_sys_stat_fs_data=no],
- [fu_cv_sys_stat_fs_data=no])])
- AC_MSG_RESULT([$fu_cv_sys_stat_fs_data])
+ [fu_cv_sys_stat_fs_data=no])
+ ])
if test $fu_cv_sys_stat_fs_data = yes; then
ac_fsusage_space=yes
AC_DEFINE([STAT_STATFS2_FS_DATA], [1],
@@ -305,18 +308,22 @@ AS_IF([test $ac_fsusage_space = yes], [$1], [$2])
# enable the work-around code in fsusage.c.
AC_DEFUN([gl_STATFS_TRUNCATES],
[
- AC_MSG_CHECKING([for statfs that truncates block counts])
- AC_CACHE_VAL([fu_cv_sys_truncating_statfs],
- [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ AC_CACHE_CHECK([for statfs that truncates block counts],
+ [fu_cv_sys_truncating_statfs],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM([[
#if !defined(sun) && !defined(__sun)
choke -- this is a workaround for a Sun-specific problem
#endif
#include <sys/types.h>
-#include <sys/vfs.h>]],
+#include <sys/vfs.h>
+ ]],
[[struct statfs t; long c = *(t.f_spare);
- if (c) return 0;]])],
+ if (c) return 0;
+ ]])],
[fu_cv_sys_truncating_statfs=yes],
- [fu_cv_sys_truncating_statfs=no])])
+ [fu_cv_sys_truncating_statfs=no])
+ ])
if test $fu_cv_sys_truncating_statfs = yes; then
AC_DEFINE([STATFS_TRUNCATES_BLOCK_COUNTS], [1],
[Define if the block counts reported by statfs may be truncated to 2GB
@@ -324,7 +331,6 @@ choke -- this is a workaround for a Sun-specific problem
(SunOS 4.1.2, 4.1.3, and 4.1.3_U1 are reported to have this problem.
SunOS 4.1.1 seems not to be affected.)])
fi
- AC_MSG_RESULT([$fu_cv_sys_truncating_statfs])
])
diff --git a/m4/ls-mntd-fs.m4 b/m4/ls-mntd-fs.m4
index 6e8d308..6a03fe3 100644
--- a/m4/ls-mntd-fs.m4
+++ b/m4/ls-mntd-fs.m4
@@ -1,4 +1,4 @@
-# serial 33
+# serial 34
# How to list mounted file systems.
# Copyright (C) 1998-2004, 2006, 2009-2018 Free Software Foundation, Inc.
@@ -17,7 +17,8 @@ dnl
# through Autoconf 2.59. We can remove this once we assume Autoconf 2.60
# or later.
AC_DEFUN([AC_FUNC_GETMNTENT],
-[# getmntent is in the standard C library on UNICOS, in -lsun on Irix 4,
+[
+ # getmntent is in the standard C library on UNICOS, in -lsun on Irix 4,
# -lseq on Dynix/PTX, -lgen on Unixware.
AC_SEARCH_LIBS([getmntent], [sun seq gen])
AC_CHECK_FUNCS([getmntent])
@@ -38,7 +39,8 @@ AC_CHECK_HEADERS([sys/mount.h], [], [],
[AC_INCLUDES_DEFAULT
[#if HAVE_SYS_PARAM_H
#include <sys/param.h>
- #endif]])
+ #endif
+ ]])
AC_CHECK_HEADERS([mntent.h sys/fs_types.h])
getfsstat_includes="\
@@ -77,8 +79,8 @@ AC_FUNC_GETMNTENT
if test -z "$ac_list_mounted_fs"; then
# (obsolete) Cray UNICOS 9
- AC_MSG_CHECKING([for listmntent of Cray/Unicos-9])
- AC_CACHE_VAL([fu_cv_sys_mounted_cray_listmntent],
+ AC_CACHE_CHECK([for listmntent of Cray/Unicos-9],
+ [fu_cv_sys_mounted_cray_listmntent],
[fu_cv_sys_mounted_cray_listmntent=no
AC_EGREP_CPP([yes],
[#ifdef _CRAY
@@ -87,9 +89,7 @@ yes
], [test $ac_cv_func_listmntent = yes \
&& fu_cv_sys_mounted_cray_listmntent=yes]
)
- ]
- )
- AC_MSG_RESULT([$fu_cv_sys_mounted_cray_listmntent])
+ ])
if test $fu_cv_sys_mounted_cray_listmntent = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_LISTMNTENT], [1],
@@ -100,12 +100,11 @@ fi
if test -z "$ac_list_mounted_fs"; then
# AIX.
- AC_MSG_CHECKING([for mntctl function and struct vmount])
- AC_CACHE_VAL([fu_cv_sys_mounted_vmount],
+ AC_CACHE_CHECK([for mntctl function and struct vmount],
+ [fu_cv_sys_mounted_vmount],
[AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <fshelp.h>]])],
[fu_cv_sys_mounted_vmount=yes],
[fu_cv_sys_mounted_vmount=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_vmount])
if test $fu_cv_sys_mounted_vmount = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_VMOUNT], [1],
@@ -122,9 +121,10 @@ if test $ac_cv_func_getmntent = yes; then
if test -z "$ac_list_mounted_fs"; then
# glibc, HP-UX, IRIX, Cygwin, Android, also (obsolete) 4.3BSD, SunOS,
Dynix.
- AC_MSG_CHECKING([for one-argument getmntent function])
- AC_CACHE_VAL([fu_cv_sys_mounted_getmntent1],
- [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ AC_CACHE_CHECK([for one-argument getmntent function],
+ [fu_cv_sys_mounted_getmntent1],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM([[
/* SunOS 4.1.x /usr/include/mntent.h needs this for FILE */
#include <stdio.h>
@@ -142,10 +142,11 @@ if test $ac_cv_func_getmntent = yes; then
#endif
]],
[[struct mntent *mnt = 0; char *table = MOUNTED;
- if (sizeof mnt && sizeof table) return 0;]])],
+ if (sizeof mnt && sizeof table) return 0;
+ ]])],
[fu_cv_sys_mounted_getmntent1=yes],
- [fu_cv_sys_mounted_getmntent1=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getmntent1])
+ [fu_cv_sys_mounted_getmntent1=no])
+ ])
if test $fu_cv_sys_mounted_getmntent1 = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_GETMNTENT1], [1],
@@ -158,12 +159,12 @@ if test $ac_cv_func_getmntent = yes; then
if test -z "$ac_list_mounted_fs"; then
# Solaris, also (obsolete) SVR4.
- AC_MSG_CHECKING([for two-argument getmntent function])
- AC_CACHE_VAL([fu_cv_sys_mounted_getmntent2],
+ AC_CACHE_CHECK([for two-argument getmntent function],
+ [fu_cv_sys_mounted_getmntent2],
[AC_EGREP_HEADER([getmntent], [sys/mnttab.h],
- fu_cv_sys_mounted_getmntent2=yes,
- fu_cv_sys_mounted_getmntent2=no)])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getmntent2])
+ [fu_cv_sys_mounted_getmntent2=yes],
+ [fu_cv_sys_mounted_getmntent2=no])
+ ])
if test $fu_cv_sys_mounted_getmntent2 = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_GETMNTENT2], [1],
@@ -179,23 +180,25 @@ if test -z "$ac_list_mounted_fs"; then
# OSF/1, also (obsolete) Apple Darwin 1.3.
# powerpc-apple-darwin1.3.7 needs sys/param.h sys/ucred.h sys/fs_types.h
- AC_MSG_CHECKING([for getfsstat function])
- AC_CACHE_VAL([fu_cv_sys_mounted_getfsstat],
- [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+ AC_CACHE_CHECK([for getfsstat function],
+ [fu_cv_sys_mounted_getfsstat],
+ [AC_LINK_IFELSE(
+ [AC_LANG_PROGRAM([[
#include <sys/types.h>
#if HAVE_STRUCT_FSSTAT_F_FSTYPENAME
# define FS_TYPE(Ent) ((Ent).f_fstypename)
#else
# define FS_TYPE(Ent) mnt_names[(Ent).f_type]
#endif
-$getfsstat_includes]]
-,
+$getfsstat_includes
+ ]],
[[struct statfs *stats;
int numsys = getfsstat ((struct statfs *)0, 0L, MNT_WAIT);
- char *t = FS_TYPE (*stats); ]])],
+ char *t = FS_TYPE (*stats);
+ ]])],
[fu_cv_sys_mounted_getfsstat=yes],
- [fu_cv_sys_mounted_getfsstat=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getfsstat])
+ [fu_cv_sys_mounted_getfsstat=no])
+ ])
if test $fu_cv_sys_mounted_getfsstat = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_GETFSSTAT], [1],
@@ -206,15 +209,16 @@ fi
if test -z "$ac_list_mounted_fs"; then
# (obsolete) SVR3
- AC_MSG_CHECKING([for FIXME existence of three headers])
- AC_CACHE_VAL([fu_cv_sys_mounted_fread_fstyp],
+ AC_CACHE_CHECK([for FIXME existence of three headers],
+ [fu_cv_sys_mounted_fread_fstyp],
[AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
#include <sys/statfs.h>
#include <sys/fstyp.h>
-#include <mnttab.h>]])],
+#include <mnttab.h>
+]])],
[fu_cv_sys_mounted_fread_fstyp=yes],
- [fu_cv_sys_mounted_fread_fstyp=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_fread_fstyp])
+ [fu_cv_sys_mounted_fread_fstyp=no])
+ ])
if test $fu_cv_sys_mounted_fread_fstyp = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_FREAD_FSTYP], [1],
@@ -227,19 +231,18 @@ fi
if test -z "$ac_list_mounted_fs"; then
# Mac OS X, FreeBSD, NetBSD, OpenBSD, also (obsolete) 4.4BSD.
# OSF/1 also has getmntinfo but is already handled above.
- AC_MSG_CHECKING([for getmntinfo function])
- AC_CACHE_VAL([fu_cv_sys_mounted_getmntinfo],
+ AC_CACHE_CHECK([for getmntinfo function],
+ [fu_cv_sys_mounted_getmntinfo],
[
test "$ac_cv_func_getmntinfo" = yes \
&& fu_cv_sys_mounted_getmntinfo=yes \
|| fu_cv_sys_mounted_getmntinfo=no
])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getmntinfo])
if test $fu_cv_sys_mounted_getmntinfo = yes; then
- AC_MSG_CHECKING([whether getmntinfo returns statvfs structures])
- AC_CACHE_VAL([fu_cv_sys_mounted_getmntinfo2],
- [
- AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ AC_CACHE_CHECK([whether getmntinfo returns statvfs structures],
+ [fu_cv_sys_mounted_getmntinfo2],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM([[
#if HAVE_SYS_PARAM_H
# include <sys/param.h>
#endif
@@ -259,7 +262,6 @@ int getmntinfo (struct statfs **, int);
[fu_cv_sys_mounted_getmntinfo2=no],
[fu_cv_sys_mounted_getmntinfo2=yes])
])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getmntinfo2])
if test $fu_cv_sys_mounted_getmntinfo2 = no; then
# Mac OS X, FreeBSD, OpenBSD, also (obsolete) 4.4BSD.
ac_list_mounted_fs=found
@@ -280,14 +282,14 @@ fi
if test -z "$ac_list_mounted_fs"; then
# (obsolete) Ultrix.
- AC_MSG_CHECKING([for getmnt function])
- AC_CACHE_VAL([fu_cv_sys_mounted_getmnt],
+ AC_CACHE_CHECK([for getmnt function],
+ [fu_cv_sys_mounted_getmnt],
[AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
#include <sys/fs_types.h>
#include <sys/mount.h>]])],
[fu_cv_sys_mounted_getmnt=yes],
- [fu_cv_sys_mounted_getmnt=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_getmnt])
+ [fu_cv_sys_mounted_getmnt=no])
+ ])
if test $fu_cv_sys_mounted_getmnt = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_GETMNT], [1],
@@ -300,16 +302,17 @@ if test -z "$ac_list_mounted_fs"; then
# Haiku, also (obsolete) BeOS.
AC_CHECK_FUNCS([next_dev fs_stat_dev])
AC_CHECK_HEADERS([fs_info.h])
- AC_MSG_CHECKING([for BEOS mounted file system support functions])
- if test $ac_cv_header_fs_info_h = yes \
+ AC_CACHE_CHECK([for BEOS mounted file system support functions],
+ [fu_cv_sys_mounted_fs_stat_dev],
+ [if test $ac_cv_header_fs_info_h = yes \
&& test $ac_cv_func_next_dev = yes \
&& test $ac_cv_func_fs_stat_dev = yes; then
- fu_result=yes
+ fu_cv_sys_mounted_fs_stat_dev=yes
else
- fu_result=no
+ fu_cv_sys_mounted_fs_stat_dev=no
fi
- AC_MSG_RESULT([$fu_result])
- if test $fu_result = yes; then
+ ])
+ if test $fu_cv_sys_mounted_fs_stat_dev = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_FS_STAT_DEV], [1],
[Define if there are functions named next_dev and fs_stat_dev for
@@ -319,12 +322,12 @@ fi
if test -z "$ac_list_mounted_fs"; then
# (obsolete) SVR2.
- AC_MSG_CHECKING([whether it is possible to resort to fread on /etc/mnttab])
- AC_CACHE_VAL([fu_cv_sys_mounted_fread],
+ AC_CACHE_CHECK([whether it is possible to resort to fread on /etc/mnttab],
+ [fu_cv_sys_mounted_fread],
[AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <mnttab.h>]])],
[fu_cv_sys_mounted_fread=yes],
- [fu_cv_sys_mounted_fread=no])])
- AC_MSG_RESULT([$fu_cv_sys_mounted_fread])
+ [fu_cv_sys_mounted_fread=no])
+ ])
if test $fu_cv_sys_mounted_fread = yes; then
ac_list_mounted_fs=found
AC_DEFINE([MOUNTED_FREAD], [1],
diff --git a/m4/manywarnings-c++.m4 b/m4/manywarnings-c++.m4
index 28d9aa0..dea8e19 100644
--- a/m4/manywarnings-c++.m4
+++ b/m4/manywarnings-c++.m4
@@ -1,4 +1,4 @@
-# manywarnings-c++.m4 serial 2
+# manywarnings-c++.m4 serial 3
dnl Copyright (C) 2008-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -17,23 +17,23 @@ AC_DEFUN([gl_MANYWARN_ALL_GCC_CXX_IMPL],
dnl Check if -W -Werror -Wno-missing-field-initializers is supported
dnl with the current $CXX $CXXFLAGS $CPPFLAGS.
- AC_MSG_CHECKING([whether -Wno-missing-field-initializers is supported])
- AC_CACHE_VAL([gl_cv_cxx_nomfi_supported], [
- gl_save_CXXFLAGS="$CXXFLAGS"
+ AC_CACHE_CHECK([whether -Wno-missing-field-initializers is supported],
+ [gl_cv_cxx_nomfi_supported],
+ [gl_save_CXXFLAGS="$CXXFLAGS"
CXXFLAGS="$CXXFLAGS -W -Werror -Wno-missing-field-initializers"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([[]], [[]])],
[gl_cv_cxx_nomfi_supported=yes],
[gl_cv_cxx_nomfi_supported=no])
- CXXFLAGS="$gl_save_CXXFLAGS"])
- AC_MSG_RESULT([$gl_cv_cxx_nomfi_supported])
+ CXXFLAGS="$gl_save_CXXFLAGS"
+ ])
if test "$gl_cv_cxx_nomfi_supported" = yes; then
dnl Now check whether -Wno-missing-field-initializers is needed
dnl for the { 0, } construct.
- AC_MSG_CHECKING([whether -Wno-missing-field-initializers is needed])
- AC_CACHE_VAL([gl_cv_cxx_nomfi_needed], [
- gl_save_CXXFLAGS="$CXXFLAGS"
+ AC_CACHE_CHECK([whether -Wno-missing-field-initializers is needed],
+ [gl_cv_cxx_nomfi_needed],
+ [gl_save_CXXFLAGS="$CXXFLAGS"
CXXFLAGS="$CXXFLAGS -W -Werror"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM(
@@ -49,22 +49,21 @@ AC_DEFUN([gl_MANYWARN_ALL_GCC_CXX_IMPL],
[gl_cv_cxx_nomfi_needed=yes])
CXXFLAGS="$gl_save_CXXFLAGS"
])
- AC_MSG_RESULT([$gl_cv_cxx_nomfi_needed])
fi
dnl Next, check if -Werror -Wuninitialized is useful with the
dnl user's choice of $CXXFLAGS; some versions of gcc warn that it
dnl has no effect if -O is not also used
- AC_MSG_CHECKING([whether -Wuninitialized is supported])
- AC_CACHE_VAL([gl_cv_cxx_uninitialized_supported], [
- gl_save_CXXFLAGS="$CXXFLAGS"
+ AC_CACHE_CHECK([whether -Wuninitialized is supported],
+ [gl_cv_cxx_uninitialized_supported],
+ [gl_save_CXXFLAGS="$CXXFLAGS"
CXXFLAGS="$CXXFLAGS -Werror -Wuninitialized"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([[]], [[]])],
[gl_cv_cxx_uninitialized_supported=yes],
[gl_cv_cxx_uninitialized_supported=no])
- CXXFLAGS="$gl_save_CXXFLAGS"])
- AC_MSG_RESULT([$gl_cv_cxx_uninitialized_supported])
+ CXXFLAGS="$gl_save_CXXFLAGS"
+ ])
fi
diff --git a/m4/manywarnings.m4 b/m4/manywarnings.m4
index 516c587..d831ed2 100644
--- a/m4/manywarnings.m4
+++ b/m4/manywarnings.m4
@@ -1,4 +1,4 @@
-# manywarnings.m4 serial 16
+# manywarnings.m4 serial 17
dnl Copyright (C) 2008-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -51,23 +51,23 @@ m4_defun([gl_MANYWARN_ALL_GCC(C)],
dnl Check if -W -Werror -Wno-missing-field-initializers is supported
dnl with the current $CC $CFLAGS $CPPFLAGS.
- AC_MSG_CHECKING([whether -Wno-missing-field-initializers is supported])
- AC_CACHE_VAL([gl_cv_cc_nomfi_supported], [
- gl_save_CFLAGS="$CFLAGS"
+ AC_CACHE_CHECK([whether -Wno-missing-field-initializers is supported],
+ [gl_cv_cc_nomfi_supported],
+ [gl_save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -W -Werror -Wno-missing-field-initializers"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([[]], [[]])],
[gl_cv_cc_nomfi_supported=yes],
[gl_cv_cc_nomfi_supported=no])
- CFLAGS="$gl_save_CFLAGS"])
- AC_MSG_RESULT([$gl_cv_cc_nomfi_supported])
+ CFLAGS="$gl_save_CFLAGS"
+ ])
if test "$gl_cv_cc_nomfi_supported" = yes; then
dnl Now check whether -Wno-missing-field-initializers is needed
dnl for the { 0, } construct.
- AC_MSG_CHECKING([whether -Wno-missing-field-initializers is needed])
- AC_CACHE_VAL([gl_cv_cc_nomfi_needed], [
- gl_save_CFLAGS="$CFLAGS"
+ AC_CACHE_CHECK([whether -Wno-missing-field-initializers is needed],
+ [gl_cv_cc_nomfi_needed],
+ [gl_save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -W -Werror"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM(
@@ -83,22 +83,21 @@ m4_defun([gl_MANYWARN_ALL_GCC(C)],
[gl_cv_cc_nomfi_needed=yes])
CFLAGS="$gl_save_CFLAGS"
])
- AC_MSG_RESULT([$gl_cv_cc_nomfi_needed])
fi
dnl Next, check if -Werror -Wuninitialized is useful with the
dnl user's choice of $CFLAGS; some versions of gcc warn that it
dnl has no effect if -O is not also used
- AC_MSG_CHECKING([whether -Wuninitialized is supported])
- AC_CACHE_VAL([gl_cv_cc_uninitialized_supported], [
- gl_save_CFLAGS="$CFLAGS"
+ AC_CACHE_CHECK([whether -Wuninitialized is supported],
+ [gl_cv_cc_uninitialized_supported],
+ [gl_save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -Werror -Wuninitialized"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([[]], [[]])],
[gl_cv_cc_uninitialized_supported=yes],
[gl_cv_cc_uninitialized_supported=no])
- CFLAGS="$gl_save_CFLAGS"])
- AC_MSG_RESULT([$gl_cv_cc_uninitialized_supported])
+ CFLAGS="$gl_save_CFLAGS"
+ ])
fi
diff --git a/m4/socklen.m4 b/m4/socklen.m4
index f2d996d..fa79b07 100644
--- a/m4/socklen.m4
+++ b/m4/socklen.m4
@@ -1,4 +1,4 @@
-# socklen.m4 serial 10
+# socklen.m4 serial 11
dnl Copyright (C) 2005-2007, 2009-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -15,8 +15,8 @@ dnl So we have to test to find something that will work.
AC_DEFUN([gl_TYPE_SOCKLEN_T],
[AC_REQUIRE([gl_CHECK_SOCKET_HEADERS])dnl
AC_CHECK_TYPE([socklen_t], ,
- [AC_MSG_CHECKING([for socklen_t equivalent])
- AC_CACHE_VAL([gl_cv_socklen_t_equiv],
+ [AC_CACHE_CHECK([for socklen_t equivalent],
+ [gl_cv_socklen_t_equiv],
[# Systems have either "struct sockaddr *" or
# "void *" as the second argument to getpeername
gl_cv_socklen_t_equiv=
@@ -34,11 +34,10 @@ AC_DEFUN([gl_TYPE_SOCKLEN_T],
done
test "$gl_cv_socklen_t_equiv" != "" && break
done
- ])
if test "$gl_cv_socklen_t_equiv" = ""; then
AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
fi
- AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
+ ])
AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
[type to use in place of socklen_t if not defined])],
[gl_SOCKET_HEADERS])])
diff --git a/m4/sockpfaf.m4 b/m4/sockpfaf.m4
index e3fe2c4..cc47b8b 100644
--- a/m4/sockpfaf.m4
+++ b/m4/sockpfaf.m4
@@ -1,4 +1,4 @@
-# sockpfaf.m4 serial 8
+# sockpfaf.m4 serial 9
dnl Copyright (C) 2004, 2006, 2009-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -16,8 +16,8 @@ AC_DEFUN([gl_SOCKET_FAMILIES],
AC_REQUIRE([gl_HEADER_SYS_SOCKET])
AC_CHECK_HEADERS_ONCE([netinet/in.h])
- AC_MSG_CHECKING([for IPv4 sockets])
- AC_CACHE_VAL([gl_cv_socket_ipv4],
+ AC_CACHE_CHECK([for IPv4 sockets],
+ [gl_cv_socket_ipv4],
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#ifdef HAVE_SYS_SOCKET_H
#include <sys/socket.h>
@@ -31,13 +31,12 @@ AC_DEFUN([gl_SOCKET_FAMILIES],
[[int x = AF_INET; struct in_addr y; struct sockaddr_in z;
if (&x && &y && &z) return 0;]])],
gl_cv_socket_ipv4=yes, gl_cv_socket_ipv4=no)])
- AC_MSG_RESULT([$gl_cv_socket_ipv4])
if test $gl_cv_socket_ipv4 = yes; then
AC_DEFINE([HAVE_IPV4], [1], [Define to 1 if <sys/socket.h> defines
AF_INET.])
fi
- AC_MSG_CHECKING([for IPv6 sockets])
- AC_CACHE_VAL([gl_cv_socket_ipv6],
+ AC_CACHE_CHECK([for IPv6 sockets],
+ [gl_cv_socket_ipv6],
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#ifdef HAVE_SYS_SOCKET_H
#include <sys/socket.h>
@@ -54,7 +53,6 @@ AC_DEFUN([gl_SOCKET_FAMILIES],
[[int x = AF_INET6; struct in6_addr y; struct sockaddr_in6 z;
if (&x && &y && &z) return 0;]])],
gl_cv_socket_ipv6=yes, gl_cv_socket_ipv6=no)])
- AC_MSG_RESULT([$gl_cv_socket_ipv6])
if test $gl_cv_socket_ipv6 = yes; then
AC_DEFINE([HAVE_IPV6], [1], [Define to 1 if <sys/socket.h> defines
AF_INET6.])
fi
@@ -65,8 +63,8 @@ AC_DEFUN([gl_SOCKET_FAMILY_UNIX],
AC_REQUIRE([gl_HEADER_SYS_SOCKET])
AC_CHECK_HEADERS_ONCE([sys/un.h])
- AC_MSG_CHECKING([for UNIX domain sockets])
- AC_CACHE_VAL([gl_cv_socket_unix],
+ AC_CACHE_CHECK([for UNIX domain sockets],
+ [gl_cv_socket_unix],
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
#ifdef HAVE_SYS_SOCKET_H
#include <sys/socket.h>
@@ -80,7 +78,6 @@ AC_DEFUN([gl_SOCKET_FAMILY_UNIX],
[[int x = AF_UNIX; struct sockaddr_un y;
if (&x && &y) return 0;]])],
gl_cv_socket_unix=yes, gl_cv_socket_unix=no)])
- AC_MSG_RESULT([$gl_cv_socket_unix])
if test $gl_cv_socket_unix = yes; then
AC_DEFINE([HAVE_UNIXSOCKET], [1], [Define to 1 if <sys/socket.h> defines
AF_UNIX.])
fi
diff --git a/m4/stdarg.m4 b/m4/stdarg.m4
index d6f0508..f89d38b 100644
--- a/m4/stdarg.m4
+++ b/m4/stdarg.m4
@@ -1,4 +1,4 @@
-# stdarg.m4 serial 6
+# stdarg.m4 serial 7
dnl Copyright (C) 2006, 2008-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -11,9 +11,9 @@ AC_DEFUN([gl_STDARG_H],
[
STDARG_H=''
NEXT_STDARG_H='<stdarg.h>'
- AC_MSG_CHECKING([for va_copy])
- AC_CACHE_VAL([gl_cv_func_va_copy], [
- AC_COMPILE_IFELSE(
+ AC_CACHE_CHECK([for va_copy],
+ [gl_cv_func_va_copy],
+ [AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM(
[[#include <stdarg.h>]],
[[
@@ -22,8 +22,8 @@ void (*func) (va_list, va_list) = va_copy;
#endif
]])],
[gl_cv_func_va_copy=yes],
- [gl_cv_func_va_copy=no])])
- AC_MSG_RESULT([$gl_cv_func_va_copy])
+ [gl_cv_func_va_copy=no])
+ ])
if test $gl_cv_func_va_copy = no; then
dnl Provide a substitute.
dnl Usually a simple definition in <config.h> is enough. Not so on AIX 5
diff --git a/m4/visibility.m4 b/m4/visibility.m4
index 7e99764..f53e0d5 100644
--- a/m4/visibility.m4
+++ b/m4/visibility.m4
@@ -1,4 +1,4 @@
-# visibility.m4 serial 5 (gettext-0.18.2)
+# visibility.m4 serial 6
dnl Copyright (C) 2005, 2008, 2010-2018 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
@@ -29,20 +29,20 @@ AC_DEFUN([gl_VISIBILITY],
dnl First, check whether -Werror can be added to the command line, or
dnl whether it leads to an error because of some other option that the
dnl user has put into $CC $CFLAGS $CPPFLAGS.
- AC_MSG_CHECKING([whether the -Werror option is usable])
- AC_CACHE_VAL([gl_cv_cc_vis_werror], [
- gl_save_CFLAGS="$CFLAGS"
+ AC_CACHE_CHECK([whether the -Werror option is usable],
+ [gl_cv_cc_vis_werror],
+ [gl_save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -Werror"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([[]], [[]])],
[gl_cv_cc_vis_werror=yes],
[gl_cv_cc_vis_werror=no])
- CFLAGS="$gl_save_CFLAGS"])
- AC_MSG_RESULT([$gl_cv_cc_vis_werror])
+ CFLAGS="$gl_save_CFLAGS"
+ ])
dnl Now check whether visibility declarations are supported.
- AC_MSG_CHECKING([for simple visibility declarations])
- AC_CACHE_VAL([gl_cv_cc_visibility], [
- gl_save_CFLAGS="$CFLAGS"
+ AC_CACHE_CHECK([for simple visibility declarations],
+ [gl_cv_cc_visibility],
+ [gl_save_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -fvisibility=hidden"
dnl We use the option -Werror and a function dummyfunc, because on some
dnl platforms (Cygwin 1.7) the use of -fvisibility triggers a warning
@@ -63,8 +63,8 @@ AC_DEFUN([gl_VISIBILITY],
[[]])],
[gl_cv_cc_visibility=yes],
[gl_cv_cc_visibility=no])
- CFLAGS="$gl_save_CFLAGS"])
- AC_MSG_RESULT([$gl_cv_cc_visibility])
+ CFLAGS="$gl_save_CFLAGS"
+ ])
if test $gl_cv_cc_visibility = yes; then
CFLAG_VISIBILITY="-fvisibility=hidden"
HAVE_VISIBILITY=1
| [Prev in Thread] |
Current Thread |
[Next in Thread] |
- use AC_CACHE_CHECK where possible,
Bruno Haible <=