bug-texinfo
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: texinfo-4.13.91 - undetected curses


From: John Darrington
Subject: Re: texinfo-4.13.91 - undetected curses
Date: Sun, 2 Dec 2012 09:30:38 +0100
User-agent: Mutt/1.5.20 (2009-06-14)

On Sun, Dec 02, 2012 at 01:05:21AM +0000, Karl Berry wrote:
     Hi Ineiev,
     
         I tried to build it on cygwin; it didn't find ncurses [0],
         but configure exited successfully, and it was make that broke.
     
     Well, that is clearly a problem, but I can't possibly guess what to do
     about it.  If you can provide a patch, either for configure to bail out
     or to make it actually work, then I can include it.
     
     Maybe some other package has some curses-finding configure code that
     could be used? 

In pspp we had exactly this problem some years ago.  Currently our configure.ac 
?looks as follows and we haven't had any complaints recently:


dnl Recent versions of GNU ncurses install the curses header files into
dnl /usr/include/ncurses, and provide a 'ncurses5-config' program which
dnl enables us to discover where they are. Earlier versions don't have
dnl this, so we can't rely on it.  So if ncurses5-config is present,
dnl we'll trust it to find the right information.  Otherwise, we'll
dnl try to discover it ourselves.
dnl To confound things further, Cygwin has decided to rename ncurses5-config
dnl to ncurses8-config !!!
AC_ARG_WITH(
  libncurses, 
  [AS_HELP_STRING([--without-libncurses], [don't compile in ncurses 
functions])])

if test x"$with_libncurses" != x"no" ; then
  if test x"$cross_compiling" != x"yes" ; then
          AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
  fi
  if test x"$NCURSES_CONFIG" = x ; then
          AC_SEARCH_LIBS([tgetent], [ncurses],
              [curses_available=yes; AC_CHECK_HEADERS([term.h 
curses.h],,[curses_available=no])])
  else
          old_cflags=$CFLAGS
          CFLAGS="$CFLAGS `$NCURSES_CONFIG --cflags`"
          AC_CHECK_HEADERS([term.h curses.h],[curses_available=yes])
          CFLAGS=$old_cflags
          if test x"$curses_available" = x"yes" ; then
           NCURSES_LIBS=`$NCURSES_CONFIG --libs`
           NCURSES_CFLAGS=`$NCURSES_CONFIG --cflags`
           AC_SUBST(NCURSES_CFLAGS)
           AC_SUBST(NCURSES_LIBS)
          fi
  fi
  if test x"$curses_available" = x"yes" ; then
          AC_DEFINE([LIBNCURSES_USABLE], 1,
              [Define to 1 if the libncurses is both present and usable.])
  fi
  AC_CHECK_HEADERS([termcap.h])
fi

J'

-- 
PGP Public key ID: 1024D/2DE827B3 
fingerprint = 8797 A26D 0854 2EAB 0285  A290 8A67 719C 2DE8 27B3
See http://keys.gnupg.net or any PGP keyserver for public key.

Attachment: signature.asc
Description: Digital signature


reply via email to

[Prev in Thread] Current Thread [Next in Thread]