emacs-orgmode
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

[O] multicolumn cells in latex export


From: Vikas Rawal
Subject: [O] multicolumn cells in latex export
Date: Sat, 5 Nov 2016 13:27:21 +0530

Two years ago, Eric Schulte had shared some most useful code snippets (https://lists.gnu.org/archive/html/emacs-orgmode/2014-08/msg00113.html). This included an export filter (code pasted below) that provided a very useful way of introducing multicolumn cells in latex export.

I have been using this since then without any trouble. But today I tried using it to centre-align column headings in the top row by using <1colc>. While it works for other columns, it does not work on the last column. 

The last column gets exported as 
\multicolumn{1}{c}{Australia (2015)\\
}\hline

rather than as

\multicolumn{1}{c}{Australia (2015)}\\
\hline

Can anyone help debug what is wrong with this code?

Vikas

---------------

;;; Multi-column Table Cells
;;
;; Export table cells with multiple columns using Latex-like syntax.
;; For example in the following the "<3colc>Backends" cell spans 3
;; columns with it's text centered.
;;
;; |           | <3colc>Backends |       |       |
;; |           |           LaTeX |  HTML |  Text |
;; |-----------+-----------------+-------+-------|
;; | extension |            .tex | .html | .txt  |
;;
;; The `org-export-multicolumn-filter-latex' function is taken from
;; the following.
(defun org-export-multicolumn-filter (row backend info)
  (cond
   ((org-export-derived-backend-p backend 'latex)
    (org-export-multicolumn-filter-latex row backend info))
   ((org-export-derived-backend-p backend 'html)
    (org-export-multicolumn-filter-html row backend info))))

(defun org-export-multicolumn-filter-latex (row backend info)
  (while (string-match
          "\\(<\\([0-9]+\\)col\\([lrc]\\)?>[[:blank:]]*\\([^&]+\\)\\)" row)
    (let ((columns (string-to-number (match-string 2 row)))
          (start (match-end 0))
          (contents (replace-regexp-in-string
                     "\\\\" "\\\\\\\\"
                     (replace-regexp-in-string "[[:blank:]]*$" ""
                                               (match-string 4 row))))
          (algn (or (match-string 3 row) "l")))
      (setq row (replace-match
                 (format "\\\\multicolumn{%d}{%s}{%s}" columns algn contents)
                 nil nil row 1))
      (while (and (> columns 1) (string-match "&" row start))
        (setq row (replace-match "" nil nil row))
        (decf columns))))
  row)

(defun org-export-multicolumn-filter-html (row backend info)
  (while (string-match "class=\".*\" *>&lt;\\([0-9]+\\)col\\([lrc]\\)?&gt;" row)
    (let ((columns (string-to-number (match-string 1 row)))
          (start (match-end 0))
          (algn (case (intern (or (match-string 2 row) "l"))
                  (c "center")
                  (r "right")
                  (l "left"))))
      (setq row (replace-match
                 (format " class=\"%s\" colspan=\"%s\">" algn columns)
                 nil nil row))
      (while (and (> columns 1)
                  (string-match "<th .*>&#xa0;</th>" row start))
        (setq row (replace-match "" nil nil row))
        (decf columns))))
  row)

(add-to-list 'org-export-filter-table-row-functions
             'org-export-multicolumn-filter)


reply via email to

[Prev in Thread] Current Thread [Next in Thread]