Re: Emacs as a translator's tool

[Emanuel Berg]

Marcin Borkowski wrote:

> Check out the function `overlay-buffer'.

You mean like this:

;;; -*- lexical-binding: t -*-
;;;
;;; this file:
;;;   http://user.it.uu.se/~embe8573/emacs-init/incal-ecat.el
;;;   https://dataswamp.org/~incal/emacs-init/incal-ecat.el

(defvar sentence-overlay nil)

(defun remove-highlight ()
  (interactive)
  (when (overlayp sentence-overlay)
    (delete-overlay sentence-overlay) ))

(defun highlight-sentence ()
  (interactive)
  (let ((beg (progn (forward-sentence)    (point)))
        (end (progn (forward-sentence -1) (point))) )
    (if (overlayp sentence-overlay)
        (move-overlay sentence-overlay beg end)
      (let ((overlay (make-overlay beg end)))
        (overlay-put overlay 'face 'font-lock-comment-face)
        (setq sentence-overlay overlay) ))))
(defalias 'hs-init #'highlight-sentence)

(defun highlight-sentence-move (next)
  (if (overlayp sentence-overlay)
      (with-current-buffer (overlay-buffer sentence-overlay)
        (forward-sentence (if next 1 -1))
        (highlight-sentence))
    (highlight-sentence) ))

(defun highlight-sentence-next ()
  (interactive)
  (highlight-sentence-move t) )

(defun highlight-sentence-prev ()
  (interactive)
  (highlight-sentence-move nil) )

-- 
underground experts united
http://user.it.uu.se/~embe8573
https://dataswamp.org/~incal