lumina desktop package

[Yoshinori Arai]

Hello,

I'm making lumina-desktop package. I have succeeded to build the package but
failed to execute start-lumina-desktop in xinitrc after login with slim.

The log message is as follows,

Starting the Lumina desktop on current X11 session: ":0.0"
 - Resetting monitor configuration to last-used settings
 - Starting the session...
[Lumina] Checking User Files
 - Old Version: "1.4.0"
 - Current Version: "1.4.0"
 - Made Changes: false
Finished with user files check
Got Desktop Process Finished: 11
Finished Closing Down Lumina

I have installed fluxbox individually so I think it's not needed to include it
in propagated-inputs. However, I tried to include it into propagated-inputs but
I got same result.

Please tell me some idea to resolve it.

Package definition is as follows,

(define-module (lumina)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix utils)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages xorg)
  #:use-module (gnu packages qt)
  #:use-module (gnu packages pdf)  ;; poppler-qt5
  #:use-module (gnu packages wm)
  #:use-module (gnu packages xdisorg))

(define-public lumina-desktop
  (package
    (name "lumina-desktop")
    (version "1.4.0-p1")
    (source (origin
          (method url-fetch)
          (uri (string-append
                "https://github.com/lumina-desktop/lumina/archive/v";
                version ".tar.gz"))
          (sha256
           (base32
            "0bz7jjcvqylizgri3mpn6isq7lgv74d2373i9nrv3jxwni72y83b"))))
    (build-system gnu-build-system)
    (arguments
     `(#:phases
       (modify-phases %standard-phases
         (add-after 'unpack 'fix-all-project-file
           (lambda _
             (for-each (lambda (f)
                         (let ((out (assoc-ref %outputs "out")))
                           (substitute* f
                             (("\\$\\$\\{L_SHAREDIR\\}")
                              (string-append out "/share"))
                             (("\\$\\$\\{L_SESSDIR\\}")
                              (string-append out "/share/xsessions"))
                             (("\\$\\$\\{L_ETCDIR\\}")
                              (string-append out "/etc"))
                             (("\\$\\$\\{L_MANDIR\\}")
                              (string-append out "/share/man"))
                             (("\\$\\$\\{LRELEASE\\}") (which "lrelease")))))
                       (find-files "." ".*\\.pro"))))
         (add-after 'unpack 'fix-lumina-pdf-pro
           (lambda _
             (let ((pqt5 (assoc-ref %build-inputs "poppler-qt5")))
               (substitute* "src-qt5/desktop-utils/lumina-pdf/lumina-pdf.pro"
                 (("\\$\\$\\{L_INCLUDEDIR\\}")
                  (string-append pqt5 "/include"))))
             #t))
         (add-after 'unpack 'fix-lthemeengine-pri
           (lambda _
             (let ((out (assoc-ref %outputs "out")))
               (substitute* "src-qt5/core/lumina-theme-engine/lthemeengine.pri"
                 (("\\$\\$\\{DISTDIR\\}\\$\\$\\[QT_INSTALL_PLUGINS\\]")
                  (string-append out "/lib/qt5/plugins/styles"))))
             #t))
         (replace 'configure
           (lambda* (#:key outputs #:allow-other-keys)
             (let ((out (assoc-ref outputs "out")))
               (invoke "qmake" "CONFIG+=WITH_I18N"
                       (string-append "PREFIX=" out))))))))
    (native-inputs
     `(("pkg-config" ,pkg-config)
       ("qttools" ,qttools)))
    (inputs
     `(("qtbase" ,qtbase)
       ("qtx11extras" ,qtx11extras)
       ("qtmultimedia" ,qtmultimedia)
       ("qtsvg" ,qtsvg)
       ("poppler-qt5" ,poppler-qt5)
       ("libxcb" ,libxcb)
       ("xcb-util" ,xcb-util)
       ("xcb-util-image" ,xcb-util-image)
       ("xcb-util-wm" ,xcb-util-wm)
       ("libxdamage" ,libxdamage)
       ("libxcursor" ,libxcursor)))
    (propagated-inputs
     `(("fluxbox" ,fluxbox)
       ("xscreensaver" ,xscreensaver)))
    (home-page "https://www.lumina-desktop.org/";)
    (synopsis "Lightweight Desktop Environment")
    (description "Lumina Desktop Environment is a lightweight system interface
that is designed for use on any Unix-like operating system.")
    (license license:bsd-3)))
lumina-desktop