Re: [shell-script] Como trocar e inserir texto dentro de um arquivo usando o SED?

[aurelio]

ae thobias,

desculpa os pitacos, teu sed tá 10,
é só pra ser chato mesmo ;)

 --- Thobias Salazar Trevisan <address@hidden> escreveu: 
> Bom, entao vamos quebrar o title e deixa-lo sozinho em 1 linha:
> 
> sed 's/document name=\("[^"]*"\)/& title=\1/;s/title="[^"]\+"/\
> &\
> /' | sed '/\(document name="\|location="\)/y/áéíóú/aeiou/' | \
>  sed '/document name="[^"]\+"/{N;s/\n//;N;s/\n//;}'

esses dois comandos podem virar um só:

  sed 's/document name=\("[^"]*"\)/& title=\1/;s/title="[^"]\+"/\
  &\
  /'

assim:

  sed 's/document name=\("[^"]*"\)/&\
  title=\1\
  /'

ou se for o GNU sed 3.02.80 ou superior (que suporta \n)

  sed 's/document name=\("[^"]*"\)/&\ntitle=\1\n/'

-----------------------------------------------------

e esse aqui dá pra economizar 2 chars Kra!!! :)

  sed '/\(document name="\|location="\)/y/áéíóú/aeiou/'

fica:

  sed '/\(document name\|location\)="/y/áéíóú/aeiou/'

------------------------------------------------------

e esse dá pra economizar um s/// se usar o 'g'

  sed '/document name="[^"]\+"/{N;s/\n//;N;s/\n//;}'

pra:

  sed '/document name="[^"]\+"/{N;N;s/\n//g;}'

------------------------------------------------------

prometo não responder mais msgs hoje
nem eu tou me aguentando de tanta chatice :)


=====
-- 
aurelio

_______________________________________________________________________
Busca Yahoo!
O serviço de busca mais completo da Internet. O que você pensar o Yahoo! 
encontra.
http://br.busca.yahoo.com/