AC_DECL_SYS_SIGLIST obsolete

[Akim Demaille]

I see Jim is using a plain AC_CHECK_DECLS for siglist, but autoscan
wants AC_DECL_SYS_SIGLIST:

# AC_DECL_SYS_SIGLIST
# -------------------
AC_DEFUN([AC_DECL_SYS_SIGLIST],
[AC_CACHE_CHECK([for sys_siglist declaration in signal.h or unistd.h],
  ac_cv_decl_sys_siglist,
[AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([#include <sys/types.h>
#include <signal.h>
/* NetBSD declares sys_siglist in unistd.h.  */
#if HAVE_UNISTD_H
# include <unistd.h>
#endif
], [char *msg = *(sys_siglist + 1);])],
                   [ac_cv_decl_sys_siglist=yes],
                   [ac_cv_decl_sys_siglist=no])])
if test $ac_cv_decl_sys_siglist = yes; then
  AC_DEFINE(SYS_SIGLIST_DECLARED, 1,
            [Define to 1 if `sys_siglist' is declared by <signal.h>
             or <unistd.h>.])
fi
])# AC_DECL_SYS_SIGLIST


It seems to me that the style of this macro is deprecated: now we look
for headers on the one hand side, and then for available/missing
decls, right?

So, should we deprecate this macro?