log1pl: Work around musl libc bug

[Bruno Haible]

log1pl lacks precision on musl libc 1.2.2/arm64, musl libc 1.2.2/s390x.
This patch adds a configure test, that enables a gnulib workaround.


2021-01-31  Bruno Haible  <bruno@clisp.org>

        log1pl: Work around musl libc bug.
        * doc/posix-functions/log1pl.texi: Document musl libc bug.
        * m4/log1pl.m4 (gl_FUNC_LOG1PL_WORKS): New macro.
        (gl_FUNC_LOG1PL): Invoke it.

diff --git a/doc/posix-functions/log1pl.texi b/doc/posix-functions/log1pl.texi
index 802c2e6..be81d60 100644
--- a/doc/posix-functions/log1pl.texi
+++ b/doc/posix-functions/log1pl.texi
@@ -11,6 +11,10 @@ Portability problems fixed by either Gnulib module 
@code{log1pl} or @code{log1pl
 @item
 This function is missing on some platforms:
 FreeBSD 6.0, NetBSD 9.0, OpenBSD 3.8, Minix 3.1.8, AIX 5.1, HP-UX 11, IRIX 
6.5, Solaris 9, Cygwin 1.7.x, MSVC 9, Android 4.4.
+@item
+This function produces results which are accurate to only 16 digits on some
+platforms:
+musl libc 1.2.2/arm64, musl libc 1.2.2/s390x.
 @end itemize
 
 Portability problems fixed by Gnulib module @code{log1pl-ieee}:
diff --git a/m4/log1pl.m4 b/m4/log1pl.m4
index 7d95aac..bd9d63d 100644
--- a/m4/log1pl.m4
+++ b/m4/log1pl.m4
@@ -1,4 +1,4 @@
-# log1pl.m4 serial 8
+# log1pl.m4 serial 9
 dnl Copyright (C) 2012-2021 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
@@ -22,6 +22,16 @@ AC_DEFUN([gl_FUNC_LOG1PL],
   LIBS="$save_LIBS"
   if test $ac_cv_func_log1pl = yes; then
     LOG1PL_LIBM="$LOG1P_LIBM"
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $LOG1PL_LIBM"
+    gl_FUNC_LOG1PL_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_log1pl_works" in
+      *yes) ;;
+      *) REPLACE_LOG1PL=1 ;;
+    esac
+
     m4_ifdef([gl_FUNC_LOG1PL_IEEE], [
       if test $gl_log1pl_required = ieee && test $REPLACE_LOG1PL = 0; then
         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
@@ -99,3 +109,93 @@ int main (int argc, char *argv[])
   fi
   AC_SUBST([LOG1PL_LIBM])
 ])
+
+dnl Test whether log1pl() works.
+dnl On musl 1.2.2/{arm64,s390x}, the result is accurate to only 16 digits.
+AC_DEFUN([gl_FUNC_LOG1PL_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CACHE_CHECK([whether log1pl works], [gl_cv_func_log1pl_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#ifndef __NO_MATH_INLINES
+# define __NO_MATH_INLINES 1 /* for glibc */
+#endif
+#include <float.h>
+#include <math.h>
+/* Override the values of <float.h>, like done in float.in.h.  */
+#if defined __i386__ && (defined __BEOS__ || defined __OpenBSD__)
+# undef LDBL_MANT_DIG
+# define LDBL_MANT_DIG   64
+# undef LDBL_MIN_EXP
+# define LDBL_MIN_EXP    (-16381)
+# undef LDBL_MAX_EXP
+# define LDBL_MAX_EXP    16384
+#endif
+#if defined __i386__ && (defined __FreeBSD__ || defined __DragonFly__)
+# undef LDBL_MANT_DIG
+# define LDBL_MANT_DIG   64
+# undef LDBL_MIN_EXP
+# define LDBL_MIN_EXP    (-16381)
+# undef LDBL_MAX_EXP
+# define LDBL_MAX_EXP    16384
+#endif
+#if (defined _ARCH_PPC || defined _POWER) && defined _AIX && (LDBL_MANT_DIG == 
106) && defined __GNUC__
+# undef LDBL_MIN_EXP
+# define LDBL_MIN_EXP DBL_MIN_EXP
+#endif
+#if defined __sgi && (LDBL_MANT_DIG >= 106)
+# undef LDBL_MANT_DIG
+# define LDBL_MANT_DIG 106
+# if defined __GNUC__
+#  undef LDBL_MIN_EXP
+#  define LDBL_MIN_EXP DBL_MIN_EXP
+# endif
+#endif
+#undef log1pl
+extern
+#ifdef __cplusplus
+"C"
+#endif
+long double log1pl (long double);
+static long double dummy (long double x) { return 0; }
+int main (int argc, char *argv[])
+{
+  long double (* volatile my_log1pl) (long double) = argc ? log1pl : dummy;
+  int result = 0;
+  /* This test fails on musl 1.2.2/arm64, musl 1.2.2/s390x.  */
+  {
+    const long double TWO_LDBL_MANT_DIG = /* 2^LDBL_MANT_DIG */
+      (long double) (1U << ((LDBL_MANT_DIG - 1) / 5))
+      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 1) / 5))
+      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 2) / 5))
+      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 3) / 5))
+      * (long double) (1U << ((LDBL_MANT_DIG - 1 + 4) / 5));
+    long double x = 11.358L;
+    long double y = my_log1pl (x);
+    long double z = my_log1pl (- x / (1.0L + x));
+    long double err = (y + z) * TWO_LDBL_MANT_DIG;
+    if (!(err >= -900.0L && err <= 900.0L))
+      result |= 1;
+  }
+
+  return result;
+}
+]])],
+        [gl_cv_func_log1pl_works=yes],
+        [gl_cv_func_log1pl_works=no],
+        [case "$host_os" in
+                          # Guess yes on glibc systems.
+           *-gnu* | gnu*) gl_cv_func_log1pl_works="guessing yes" ;;
+                          # Guess no on musl systems.
+           *-musl*)       gl_cv_func_log1pl_works="guessing no" ;;
+                          # Guess yes on native Windows.
+           mingw*)        gl_cv_func_log1pl_works="guessing yes" ;;
+                          # If we don't know, obey --enable-cross-guesses.
+           *)             gl_cv_func_log1pl_works="$gl_cross_guess_normal" ;;
+         esac
+        ])
+    ])
+])