Re: Customizing key bindings (was: Re: [CVS] f7, f8 bound..)

[Alex Schroeder]

Hm, I am a bit confused.  The following is for people who want to help
me fix the code.  Here is what happens:

I have a defkeymap macro now, that seems to do the right thing.  See
the test keymap at the end.  The defkeymap creates a keymap and uses
the value given as the standard-value.  When you use customize,
however, it does not use the variable value of the keymap but the
custom-keymap property, which is nil.  When you add a keybinding, the
custom-keymap property holds a binding such as (("3" buffer-menu)).
The variable-value of the keymap is now a key map that holds the
binding for 3, and inherits from the standard-value.  Cool, so far.
Everything seems to work.  It even saves the correct customization
(only the binding for 3, not the entire keymap).

Here comes the problem, now.  When you customize the variable a second
time, custom detects a mismatch.  And I cannot discover what the
problem is.  I have started playing with the get and set methods to
figure out what is going on, but as far as I can tell, (("3"
buffer-menu)) should be a legal value for customization.

Per, do you know the answer?  I am too tired right now to keep at it.
:)

Alex. 


;;; cus-key.el -- Customize support for changing key bindings.

(require 'wid-edit)

(defvar custom-global-keymap (let ((map (make-sparse-keymap)))
                               (set-keymap-parent map global-map)
                               map)
  "Global keymap for use by Customize.

This is automatically generated from `global-key-bindings', you should 
never change this manually.  Instead, change either `global-map' from Lisp 
or `global-key-bindings' from Customize.")

(defun quoted-key-insert (key)
  "Insert a string representation of the next key typed.
The string representation is a representation understood
by `read-kbd-macro'."
  (interactive "KPress a key: ")
  (insert (edmacro-format-keys key)))

(defvar key-sequence-widget-map 
  (let ((map (make-sparse-keymap)))
    (set-keymap-parent map widget-field-keymap)
    (define-key map (kbd "C-q") 'quoted-key-insert)
    map)
    "Keymap for the `key-sequence' widget.")
    
(define-widget 'key-sequence-field 'string
  "Field for entering key bindings."
  :tag "Key sequence"
  :keymap key-sequence-widget-map)

(define-widget 'key-sequence-button 'push-button
  "Button for entering key bindings."
  :tag "Key sequence"
  :action 'key-sequence-button-action)

(defun key-sequence-button-action (widget &optional event)
  (let ((key (read-key-sequence "Press key sequence: ")))
    (widget-value-set (widget-get widget :parent)
                      (edmacro-format-keys key))
    (widget-setup)))

(define-widget 'key-sequence 'group
  "Widget for entering key bindings."
  :tag "Read key sequence"
  :value ""
  :value-create 'key-sequence-value-create
  :value-delete 'widget-children-value-delete
  :value-get 'widget-choice-value-get)

(defun key-sequence-value-create (widget)
  (let ((button (widget-create-child widget '(key-sequence-button)))
        (field (widget-create-child-value widget 
                                          '(key-sequence-field
                                            :format " %v")
                                          (widget-get widget :value))))
    (widget-put widget :children (list field))
    (widget-put widget :buttons (list button))))

(define-widget 'command 'function
  "An interactive Lisp function."
  :complete-function (lambda ()
                       (interactive)
                       (lisp-complete-symbol 'commandp))
  :prompt-match 'commandp
  :match-alternatives '(commandp)
  :validate (lambda (widget)
              (unless (commandp (widget-value widget))
                (widget-put widget :error (format "Invalid function: %S"
                                                  (widget-value widget)))
                widget))
  :value 'ignore
  :tag "Command")

(defmacro defkeymap (symbol map doc &rest args)
  "Define SYMBOL to be a keymap with value MAP.
DOC is the keymap documentation."
  ;; It is better not to use backquote in this file,
  ;; because that makes a bootstrapping problem
  ;; if you need to recompile all the Lisp files using interpreted code.
  (nconc (list 'custom-declare-keymap
               (list 'quote symbol)
               (list 'quote map)
               doc)
         args))

(defun custom-declare-keymap (symbol map doc &rest args)
  "Like `defkeymap', but SYMBOL and MAP are evaluated as normal arguments.
MAP should be an expression to evaluate to compute the default value,
not the default value itself.  The DOC string will be expanded with
some standard instructions for customization."
  ;; Keymaps are variables.  The only difference is that we know lots
  ;; of defcustom properties already.
  (setq doc (concat doc
                    "\n
While entering the name of a key, you can either type keys yourself
just as they appear in the manual, as in C-c a.  You must use angle
brackets for function keys, as in <f7>.  You can also hit C-q and type
the key.  C-q will insert the correct string representation for you.
For longer sequences, you can also invoke the [Key sequence] button, 
and type the entire key sequence directly.

While entering the name of the command, you can use M-TAB to complete
it."))
  (apply 'custom-declare-variable symbol map doc 
         :type '(repeat (group key-sequence command))
         :set 'custom-set-keymap
         :get 'custom-get-keymap
         args))

(defun custom-set-keymap (sym bindings)
  "Update keymap SYM with BINDINGS.
This creates a new keymap based on BINDINGS, and sets the parent of
that new keymap to the standard-value of SYM.  This is set as the new
variable value of SYM.  At the same time, the additions by themselves
are stored in the custom-keymap property."
  (let ((org (eval (car (get sym 'standard-value))))
        (map (make-sparse-keymap)))
    (set-keymap-parent map org)
    ;; When defkeymap is called for the first time, BINDINGS is the
    ;; standard-value.  When customized, BINDINGS is no longer a
    ;; keymap but an alist of bindings.
    (unless (equal bindings org)
      (mapc (lambda (bind)
              (define-key map (read-kbd-macro (car bind))
                (cadr bind)))
            bindings)
      (put sym 'custom-keymap (list bindings)))
    (set-default sym map)))

(defun custom-get-keymap (sym)
  "Return the additions to the standard-value of keymap SYM.
These additions are stored in the custom-keymap property by
`custom-set-keymap'."
  (car (get sym 'custom-keymap)))

;; Example:

(defkeymap my-keymap
  (let ((map (make-sparse-keymap)))
    (define-key map (read-kbd-macro "<f11>") 'bbdb)
    map)
  "Keymap to demonstrate `defkeymap'.")

;; my-keymap
;; (keymapp my-keymap)
;; (custom-get-keymap 'my-keymap)
;; (put 'my-keymap 'custom-keymap nil)
;; (get 'my-keymap 'standard-value)
;; (customize-option 'my-keymap)
;; (unintern 'my-keymap)

(provide 'cus-key)

;;; cus-key.el ends here