emacs-devel
[Top][All Lists]
Advanced

[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: Customizing key bindings


From: Alex Schroeder
Subject: Re: Customizing key bindings
Date: Tue, 10 Sep 2002 00:49:30 +0200
User-agent: Gnus/5.090008 (Oort Gnus v0.08) Emacs/21.2.90 (i686-pc-linux-gnu)

Well, it turns out that my code did have some subtle bugs in it.

        * cus-key.el (key-sequence-field-validate): disallow "" as a
        keybinding.
        (key-sequence-notify): use :key-sequence-keymap, too.
        (custom-add-key): changed handling of shadow bindings so that it
        works even when the command is nil.

Note the example code at the end of the file, which I have been using
this last hour.  It works very nicely.

Things I did:  Customized f10 to a command, removed the customization,
customized f10 to a second command, customized f10 to a third command,
and checking the settings after every step.  I also customized M-TAB
(which is lisp-complete-symbol) to nil, and removed the setting
afterwards, checking after each step.

Removing the binding such that the binding from the global map
(complete-symbol) appeared, worked fine.  Removing the customization
correctly restored lisp-complete-symbol.

Saving and loading customizations (with the setup described in a
previous mail) worked as well.

All changes had immediate effect, so I assume that the few times when
I though this was not so, I had actually forgotten to add a key to the
customization.  This is why I now disallow "" keys when validating.

Except for the handling of nil, this seems "good enough" for me.  :)

Alex.

;;; cus-key.el -- Customize support for changing key bindings.

;; $Id: cus-key.el,v 1.9 2002/09/09 22:42:12 alex Exp $

(require 'wid-edit)

(defun quoted-key-insert (key)
  "Insert a string representation of the next key typed.
The string representation is a representation understood
by `read-kbd-macro'."
  (interactive "KPress a key: ")
  (insert (edmacro-format-keys key)))

(defvar key-sequence-widget-map 
  (let ((map (make-sparse-keymap)))
    (set-keymap-parent map widget-field-keymap)
    (define-key map (kbd "C-q") 'quoted-key-insert)
    map)
    "Keymap for the `key-sequence' widget.")
    
(define-widget 'key-sequence-field 'string
  "Field for entering key bindings."
  :tag "Key sequence"
  :error "Not a well-formed key sequence"
  :validate 'key-sequence-field-validate
  :keymap key-sequence-widget-map)

(defun key-sequence-field-validate (widget)
  (let ((value (widget-apply widget :value-get)))
    (condition-case nil
        (progn 
          (when (string= value "")
            (error widget))
          (read-kbd-macro value)
          nil)
      (error widget))))

(define-widget 'key-sequence-button 'push-button
  "Button for entering key bindings."
  :tag "Key sequence"
  :action 'key-sequence-button-action)

(defun key-sequence-button-action (widget &optional event)
  (let ((key (read-key-sequence "Press key sequence: ")))
    (widget-value-set (widget-get widget :parent)
                      (edmacro-format-keys key))
    (widget-setup)))

(define-widget 'key-sequence 'default
  "Widget for entering key bindings."
  :tag "Read key sequence"
  :match 'key-sequence-match
  :format "%v"
  :value ""
  :value-create 'key-sequence-value-create
  :value-delete 'widget-children-value-delete
  :value-get 'widget-choice-value-get
  :validate 'widget-children-validate
  :notify 'key-sequence-notify)

(defun key-sequence-match (widget value)
  (stringp value))

(defun widget-ancestor-get (widget property)
  "Starting from WIDGET, return the value of PROPERTY.
If PROPERTY is not specified or nil in WIDGET and the :parent property is 
non-nil, call `widget-ancestor-get' recusively with the value of the :parent
property.  Otherwise, return nil."
  (cond ((widget-get widget property))
        ((widget-get widget :parent)
         (widget-ancestor-get (widget-get widget :parent) property))
        (nil)))

(defun key-sequence-describe (widget command)
  "Create a child to WIDGET that describes COMMAND.
The child widget is returned."
  (cond ((functionp command)
         (widget-create-child-value 
          widget '(function-item) command))
        ((null command)
         (widget-create-child-value
          widget '(item) "Undefined"))
        ((numberp command)
         (widget-create-child-value
          widget '(item) "Binding too long"))
        ((keymapp command)
         (widget-create-child-value
          widget '(item) "Prefix key"))
        (t
         (widget-create-child-value
          widget '(item) "Dude, this is too weird"))))

(defun key-sequence-value-create (widget)
  (let ((value (widget-default-get widget))
        (map (or (widget-ancestor-get widget :key-sequence-keymap)
                 (current-global-map)))
        (button (widget-create-child-and-convert
                 widget '(key-sequence-button)))
        (field (widget-create-child-value
                widget '(key-sequence-field :format " %vOld binding: ")
                (widget-get widget :value))))
    (when (symbolp map)
      (setq map (symbol-value map)))
    (let* ((command (condition-case nil
                        (lookup-key map (read-kbd-macro value))
                      (error nil)))
           (binding (key-sequence-describe widget command)))
      (widget-put widget :children (list field))
      (widget-put widget :buttons (list binding button)))))

(defun key-sequence-notify (widget child &optional event)
  "Update the old binding, and notify parent."
  (let* ((buttons (widget-get widget :buttons))
         (binding (car buttons))
         (children (widget-get widget :buttons))
         (field (car children))
         (value (widget-value child))
         (map (or (widget-ancestor-get widget :key-sequence-keymap)
                  (current-global-map)))
         (command (condition-case nil
                      (lookup-key map (read-kbd-macro value))
                    (error nil))))
    (save-excursion
      (goto-char (widget-get binding :from))
      (widget-delete binding)
      (setcar buttons (key-sequence-describe widget command))))
  (widget-default-notify widget child event))

(define-widget 'command 'function
  "An interactive Lisp function."
  :complete-function (lambda ()
                       (interactive)
                       (lisp-complete-symbol 'commandp))
  :prompt-match 'commandp
  :match-alternatives '(commandp)
  :validate (lambda (widget)
              (unless (or (not (widget-value widget))
                          (commandp (widget-value widget)))
                (widget-put widget :error (format "Invalid function: %S"
                                                  (widget-value widget)))
                widget))
  :value 'ignore
  :tag "Command")

(define-widget 'key-binding 'group
  "Bind a key sequence to a command."
  :value '("" ignore)
  :indent 0
  :args '(key-sequence (command :tag "New binding")))

(defmacro defkeymap (symbol map doc &rest args)
  "Define SYMBOL to be a keymap with value MAP.
DOC is the keymap documentation."
  ;; It is better not to use backquote in this file,
  ;; because that makes a bootstrapping problem
  ;; if you need to recompile all the Lisp files using interpreted code.
  (nconc (list 'custom-declare-keymap
               (list 'quote symbol)
               (list 'quote map)
               doc)
         args))

(defun custom-declare-keymap (symbol map doc &rest args)
  "Like `defkeymap', but SYMBOL and MAP are evaluated as normal arguments.
MAP should be an expression to evaluate to compute the default value,
not the default value itself.  The DOC string will be expanded with
some standard instructions for customization."
  ;; Keymaps are variables.  The only difference is that we know lots
  ;; of defcustom properties already.
  (setq doc (concat doc
                    "\n
While entering the name of a key, you can either type keys yourself
just as they appear in the manual, as in C-c a.  You must use angle
brackets for function keys, as in <f7>.  You can also hit C-q and type
the key.  C-q will insert the correct string representation for you.
For longer sequences, you can also invoke the [Key sequence] button, 
and type the entire key sequence directly.

While entering the name of the command, you can use M-TAB to complete
it."))
  (apply 'custom-declare-variable symbol map doc 
         :type `(repeat :key-sequence-keymap ,symbol key-binding)
         :set 'custom-set-keymap
         :get 'custom-get-keymap
         args))

(defun custom-set-keymap (sym bindings)
  "Update keymap SYM with BINDINGS.
This also does the necessary book-keeping to save away shadowed bindings
and restoring them if necessary."
  (let ((standard-bindings (eval (car (get sym 'standard-value))))
        (old-bindings (car (get sym 'custom-bindings))))
    ;; When defkeymap is called for the first time, BINDINGS is the
    ;; standard-value.  When customized, BINDINGS is no longer a
    ;; keymap but an alist of bindings.  In this case, OLD-BINDINGS is
    ;; what the user customized the last time, BINDINGS is what the
    ;; user wants this time.
    (if (equal bindings standard-bindings)
        (set-default sym standard-bindings)
      (mapc (lambda (bind)
              (unless (assoc (car bind) bindings)
                (custom-remove-key sym (read-kbd-macro (car bind)))))
            old-bindings)
      (mapc (lambda (bind)
              (custom-add-key sym (read-kbd-macro (car bind)) (cadr bind)))
            bindings)
      (put sym 'custom-bindings (list bindings)))))

(defun custom-get-keymap (sym)
  "Return the additions to the standard-value of keymap SYM.
These additions are stored in the custom-bindings property by
`custom-set-keymap'."
  (car (get sym 'custom-bindings)))

(defun custom-add-key (sym key def)
  "Add KEY to the keymap stored in SYM with definition DEF.
The shadowed binding is stored, if none has been stored before.  The
shadowed bindings are stored in the custom-bindings-shadow property."
  (let* ((map (symbol-value sym))
         (old-binding (lookup-key map key))
         (shadows (get sym 'custom-bindings-shadow))
         (shadow-binding (assoc key shadows)))
    (when (not shadow-binding)
      (put sym 'custom-bindings-shadow
           (cons (cons key old-binding) shadows)))
    (define-key map key def)))

(defun custom-remove-key (sym key)
  "Remove KEY from the keymap stored in SYM.
The shadowed binding is restored, if there is one."
  (let ((def (cdr (assoc key (get sym 'custom-bindings-shadow))))
        (map (symbol-value sym)))
    ;; when DEF is nil, this is a valid binding
    (define-key map key def)))

;; Example:

;; (eval-buffer)
;; (setq test emacs-lisp-mode-map)
;; (defkeymap emacs-lisp-mode-map test "Elisp mode map for testing.")

;; (customize-option 'emacs-lisp-mode-map)
;; (apropos "emacs-lisp-mode-map")

(provide 'cus-key)

;;; cus-key.el ends here




reply via email to

[Prev in Thread] Current Thread [Next in Thread]