Re: Weird problems on AIX 4.3.3.0 system

[Paul Eggert]

> From: Will Andrews <address@hidden>
> Date: Tue, 31 Jul 2001 03:33:29 -0500
> 
> ./configure[7717]: pwd: cannot access parent directories
> 
> Has anyone seen this before?  A simple shell script with a line
> similar to the above doesn't exhibit this problem.

Perhaps you're running 'configure' as root but the shell-script as
non-root?  That might explain matters if the source is mounted via NFS
without root-over-the-wire privileges.

It does seem to me that 'configure' should exit if this error is
found, as it's a serious one.  Here's a proposed (and untested) patch.

2001-07-31  Paul Eggert  <address@hidden>

        * acgeneral.m4 (_AC_INIT_HELP, _AC_OUTPUT_COMMANDS):
        Report an error and fail if pwd fails.
        * m4/init.m4 (AM_INIT_AUTOMAKE): Likewise.
        * m4/missing.m4 (AM_MISSING_HAS_RUN, AM_AUX_DIR_EXPAND): Likewise.

        The above patch assumes that we are operating on ordinary
        hosts where 'x=`pwd` || echo failure' works as expected.
        Buggy hosts, where x=`pwd` always succeeds, are no worse off
        than before.

===================================================================
RCS file: acgeneral.m4,v
retrieving revision 2.52
retrieving revision 2.52.0.2
diff -pu -r2.52 -r2.52.0.2
--- acgeneral.m4        2001/07/04 15:05:43     2.52
+++ acgeneral.m4        2001/07/31 17:15:40     2.52.0.2
@@ -1169,7 +1169,7 @@ fi
 
 if test "$ac_init_help" = "recursive"; then
   # If there are subdirs, report their specific --help.
-  ac_popdir=`pwd`
+  :; ac_popdir=`pwd` || AC_MSG_ERROR([pwd failed])
   for ac_subdir in : $ac_subdirs_all; do test "x$ac_subdir" = x: && continue
     cd $ac_subdir
     # A "../" for each directory in /$ac_subdir.
@@ -4398,7 +4398,7 @@ if test "$no_recursion" != yes; then
        ;;
     esac
 
-    ac_popdir=`pwd`
+    :; ac_popdir=`pwd` || AC_MSG_ERROR([pwd failed])
     cd $ac_subdir
 
     # A "../" for each directory in /$ac_subdir.
===================================================================
RCS file: m4/init.m4,v
retrieving revision 2.52
retrieving revision 2.52.0.1
diff -pu -r2.52 -r2.52.0.1
--- m4/init.m4  2000/11/14 09:27:54     2.52
+++ m4/init.m4  2001/07/31 16:49:26     2.52.0.1
@@ -23,10 +23,10 @@ AC_DEFINE_UNQUOTED(VERSION, "$VERSION", 
 AC_REQUIRE([AM_SANITY_CHECK])
 AC_REQUIRE([AC_ARG_PROGRAM])
 dnl FIXME This is truly gross.
-missing_dir=`cd $ac_aux_dir && pwd`
-AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
-AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
-AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
-AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
-AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
+AM_AUX_DIR_EXPAND
+AM_MISSING_PROG(ACLOCAL, aclocal, $am_aux_dir)
+AM_MISSING_PROG(AUTOCONF, autoconf, $am_aux_dir)
+AM_MISSING_PROG(AUTOMAKE, automake, $am_aux_dir)
+AM_MISSING_PROG(AUTOHEADER, autoheader, $am_aux_dir)
+AM_MISSING_PROG(MAKEINFO, makeinfo, $am_aux_dir)
 AC_REQUIRE([AC_PROG_MAKE_SET])])
===================================================================
RCS file: m4/missing.m4,v
retrieving revision 2.52
retrieving revision 2.52.0.2
diff -pu -r2.52 -r2.52.0.2
--- m4/missing.m4       2001/06/13 16:23:53     2.52
+++ m4/missing.m4       2001/07/31 17:15:40     2.52.0.2
@@ -36,8 +36,10 @@ AC_SUBST(install_sh)])
 # Define MISSING if not defined so far and test if it supports --run.
 # If it does, set am_missing_run to use it, otherwise, to nothing.
 AC_DEFUN([AM_MISSING_HAS_RUN],
-[test x"${MISSING+set}" = xset ||
-  MISSING="\${SHELL} `CDPATH=:; cd $ac_aux_dir && pwd`/missing"
+[test x"${MISSING+set}" = xset || {
+  AM_AUX_DIR_EXPAND
+  MISSING="\${SHELL} $am_aux_dir/missing"
+}
 # Use eval to expand $SHELL
 if eval "$MISSING --run true"; then
   am_missing_run="$MISSING --run "
@@ -67,7 +69,8 @@ fi
 # Consequently, we define and use $am_aux_dir, the "always absolute"
 # version of $ac_aux_dir.
 
-AC_DEFUN([AM_AUX_DIR_EXPAND], [
+AC_DEFUN([AM_AUX_DIR_EXPAND], [{
 # expand $ac_aux_dir to an absolute path
-am_aux_dir=`CDPATH=:; cd $ac_aux_dir && pwd`
-])
+:; am_aux_dir=`CDPATH=:; cd $ac_aux_dir && pwd` ||
+  AC_MSG_ERROR([$ac_aux_dir: cannot pwd])
+}])