Re: Some minor suggestions to Tab Bar

[Juri Linkov]

> `tab-bar-switch-to-next-tab` and `tab-bar-switch-to-prev-tab` should have a
> repeat-map property.

Please try these settings.  If they work well, then later they
could be added to tab-bar.el:

#+begin_src emacs-lisp
(defvar tab-bar-switch-repeat-map
  (let ((map (make-sparse-keymap)))
    (define-key map "o" 'tab-next)
    (define-key map "O" 'tab-previous)
    map)
  "Keymap to repeat tab switch key sequences `C-x t o o O'.
Used in `repeat-mode'.")
(put 'tab-next 'repeat-map 'tab-bar-switch-repeat-map)
(put 'tab-previous 'repeat-map 'tab-bar-switch-repeat-map)

(defvar tab-bar-move-repeat-map
  (let ((map (make-sparse-keymap)))
    (define-key map "m" 'tab-move)
    (define-key map "M" (lambda ()
                          (interactive)
                          (tab-move -1)))
    map)
  "Keymap to repeat tab move key sequences `C-x t m m'.
Used in `repeat-mode'.")
(put 'tab-move 'repeat-map 'tab-bar-move-repeat-map)

(defvar tab-bar-undo-repeat-map
  (let ((map (make-sparse-keymap)))
    (define-key map "u" 'tab-undo)
    map)
  "Keymap to repeat tab undo key sequences `C-x t u u'.
Used in `repeat-mode'.")
(put 'tab-undo 'repeat-map 'tab-bar-undo-repeat-map)
#+end_src