Re: [gnugo-devel] gnugo.ps and .pdf

[Thien-Thi Nguyen]

() <address@hidden>
() Mon, 29 Oct 2007 16:55:39 -0800

   The command in question is @verbatim, which I guess
   gets passed to tex as \verbatim. Which is indeed not
   a tex primitive. But I don't understand this since 
   @verbatim appears correct as it appears in
   gtp-commands.texi. This should be allowed.

   The same problem exists with gnugo-3.7.10. It does
   not exist with gnugo-3.6 but the @verbatim commands
   were added to gtp-commands.texi sometime after 3.6.

the following gtp-commands.sed produces @example instead of
@verbatim.  using it, i am able to do "make gnugo.pdf".
unfortunately, "make gnugo.ps" results in another error.

(i seem to recall choosing @verbatim because it looked nicer for
gnugo.info, but a review using @example doesn't seem offensive.)

thi


_________________________________________________________________
# gtp-commands.sed (edit in -*-shell-script-*- mode)
# Author: Thien-Thi Nguyen <address@hidden>

# Look for function headers.
/\* Function: /,/^{/!d

# Remove cruft.
/^static int/d
/^{/d
/^ \*\//d
s/(char.*)//g

# Hold comment lines, deleting them from pattern space for now.
/.\*/{
 s/^..//
 s/^ //
 H
 d
}

# When we see the function name, merge hold space, in the process
# generating proper texinfo @cindex, @item and @example formatting.
# As a bonus, the `Function' field is moved to the @item line.
# We use repeated `x' commands instead of the simpler `i' to avoid
# requiring a `d' (which would render this script non-composable).
/^gtp_/{
 s/\(.*\)/@cindex \1\
@item \1/
 x
 s/^\(.\)Function: *\(.*\)\(Arguments:\)/: address@hidden/
 s/\
 *\(address@hidden)/ \1/g
 s/$/\
@end example/
 H
 s/.*//
 x
 s/\
//2
}

# gtp-commands.sed ends here